From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1325737-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 258D8158018
for <garchives@archives.gentoo.org>; Fri, 1 Oct 2021 06:44:29 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 56773E08F0;
Fri, 1 Oct 2021 06:44:27 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-CHACHA20-POLY1305 (256/256 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 22466E08F0
for <gentoo-commits@lists.gentoo.org>; Fri, 1 Oct 2021 06:44:27 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-CHACHA20-POLY1305 (256/256 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id A5BE6342C9D
for <gentoo-commits@lists.gentoo.org>; Fri, 1 Oct 2021 06:44:25 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 8A4BC12F
for <gentoo-commits@lists.gentoo.org>; Fri, 1 Oct 2021 06:44:22 +0000 (UTC)
From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Andreas Sturmlechner" <asturm@gentoo.org>
Message-ID: <1633070628.dacb72e5558990a7350e26840e1dd5f4cddcfc09.asturm@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-nm/
X-VCS-Repository: repo/gentoo
X-VCS-Files: kde-plasma/plasma-nm/Manifest kde-plasma/plasma-nm/plasma-nm-5.22.90.ebuild
X-VCS-Directories: kde-plasma/plasma-nm/
X-VCS-Committer: asturm
X-VCS-Committer-Name: Andreas Sturmlechner
X-VCS-Revision: dacb72e5558990a7350e26840e1dd5f4cddcfc09
X-VCS-Branch: master
Date: Fri, 1 Oct 2021 06:44:22 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 78ae0d0c-79da-4f24-bc29-ed1b3e128131
X-Archives-Hash: 7b63d94a7a11e1ebceb0e08d7a583857
commit: dacb72e5558990a7350e26840e1dd5f4cddcfc09
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 1 06:28:15 2021 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Oct 1 06:43:48 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dacb72e5
kde-plasma/plasma-nm: 5.22.90 version bump
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
kde-plasma/plasma-nm/Manifest | 1 +
kde-plasma/plasma-nm/plasma-nm-5.22.90.ebuild | 90 +++++++++++++++++++++++++++
2 files changed, 91 insertions(+)
diff --git a/kde-plasma/plasma-nm/Manifest b/kde-plasma/plasma-nm/Manifest
index 5f15f28ce70..3bd592c461c 100644
--- a/kde-plasma/plasma-nm/Manifest
+++ b/kde-plasma/plasma-nm/Manifest
@@ -1 +1,2 @@
DIST plasma-nm-5.22.5.tar.xz 898960 BLAKE2B 0285425f4ed474c38e3a72b8b6654ba17e957921db0372bc24a9ce4fe226186cb687e5ec91836f7bbb1cb2fb9f4da1287efca41cd7b11673e2086477024f4578 SHA512 802b908c61214e77162f09289d9e9c1d3c9d39b77799d71b3c4802245f2920c29065b793a83a483a9e9df004e113bcb06fa864c456b6950ba3a4d8eaf4ec4b94
+DIST plasma-nm-5.22.90.tar.xz 918272 BLAKE2B 081c4478e5e91fc21a5607a67fa0f94a6b8fe22ff9f02ff06a324e6aab9ce556fce82f1232eb9fec8fea6680519281ae10b4758b13ee74dfb5bef443168d5898 SHA512 51dad2ecc4af9fda99cc85fc1169a1f2d9476b8a54dc6a22b7a38a51d3bfa1997d110ab957b7b18f6863373b770df7951fc90f81695961b5ff378e60006e3157
diff --git a/kde-plasma/plasma-nm/plasma-nm-5.22.90.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.22.90.ebuild
new file mode 100644
index 00000000000..0ac6235da15
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.22.90.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.86.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="modemmanager openconnect teamd"
+
+DEPEND="
+ >=app-crypt/qca-2.3.0:2
+ >=dev-qt/qtdbus-${QTMIN}:5
+ >=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+ >=dev-qt/qtgui-${QTMIN}:5
+ >=dev-qt/qtnetwork-${QTMIN}:5
+ >=dev-qt/qtwidgets-${QTMIN}:5
+ >=kde-frameworks/kcompletion-${KFMIN}:5
+ >=kde-frameworks/kconfig-${KFMIN}:5
+ >=kde-frameworks/kconfigwidgets-${KFMIN}:5
+ >=kde-frameworks/kcoreaddons-${KFMIN}:5
+ >=kde-frameworks/kdbusaddons-${KFMIN}:5
+ >=kde-frameworks/kdeclarative-${KFMIN}:5
+ >=kde-frameworks/ki18n-${KFMIN}:5
+ >=kde-frameworks/kio-${KFMIN}:5
+ >=kde-frameworks/kitemviews-${KFMIN}:5
+ >=kde-frameworks/knotifications-${KFMIN}:5
+ >=kde-frameworks/kservice-${KFMIN}:5
+ >=kde-frameworks/kwallet-${KFMIN}:5
+ >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+ >=kde-frameworks/kwindowsystem-${KFMIN}:5
+ >=kde-frameworks/kxmlgui-${KFMIN}:5
+ >=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
+ >=kde-frameworks/plasma-${KFMIN}:5
+ >=kde-frameworks/solid-${KFMIN}:5
+ net-misc/networkmanager[teamd=]
+ modemmanager? (
+ >=dev-qt/qtxml-${QTMIN}:5
+ >=kde-frameworks/modemmanager-qt-${KFMIN}:5
+ net-misc/mobile-broadband-provider-info
+ )
+ openconnect? (
+ >=dev-qt/qtxml-${QTMIN}:5
+ net-vpn/networkmanager-openconnect
+ net-vpn/openconnect:=
+ )
+"
+RDEPEND="${DEPEND}
+ >=dev-qt/qtquickcontrols-${QTMIN}:5
+ >=dev-qt/qtquickcontrols2-${QTMIN}:5
+ >=kde-frameworks/kirigami-${KFMIN}:5
+ >=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+ ecm_src_prepare
+
+ # TODO: try to get a build switch upstreamed
+ if ! use openconnect; then
+ sed -e "s/^pkg_check_modules.*openconnect/#&/" -i CMakeLists.txt || die
+ fi
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
+ $(cmake_use_find_package modemmanager KF5ModemManagerQt)
+ )
+
+ ecm_src_configure
+}
+
+pkg_postinst() {
+ ecm_pkg_postinst
+
+ if ! has_version "kde-plasma/plasma-workspace:5"; then
+ elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+ elog "However, the networkmanagement KCM can be called from either systemsettings"
+ elog "or manually: $ kcmshell5 kcm_networkmanagement"
+ fi
+}