* [gentoo-commits] repo/gentoo:master commit in: games-action/battalion/
@ 2017-11-19 15:51 David Seifert
0 siblings, 0 replies; 4+ messages in thread
From: David Seifert @ 2017-11-19 15:51 UTC (permalink / raw
To: gentoo-commits
commit: 7ea0d7d4006465528f1945491be783a022beddd6
Author: David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 19 15:50:33 2017 +0000
Commit: David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Sun Nov 19 15:51:21 2017 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7ea0d7d4
games-action/battalion: Remove old
Package-Manager: Portage-2.3.14, Repoman-2.3.6
games-action/battalion/battalion-1.4b.ebuild | 69 ----------------------------
1 file changed, 69 deletions(-)
diff --git a/games-action/battalion/battalion-1.4b.ebuild b/games-action/battalion/battalion-1.4b.ebuild
deleted file mode 100644
index 0ded9a00d39..00000000000
--- a/games-action/battalion/battalion-1.4b.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit eutils games
-
-DESCRIPTION="Be a rampaging monster and destroy the city"
-HOMEPAGE="http://evlweb.eecs.uic.edu/aej/AndyBattalion.html"
-SRC_URI="http://evlweb.eecs.uic.edu/aej/BATTALION/${PN}${PV}.tar.bz2"
-
-LICENSE="battalion HPND"
-SLOT="0"
-KEYWORDS="~x86"
-IUSE=""
-
-DEPEND="virtual/opengl
- virtual/glu
- x11-libs/libX11"
-RDEPEND=${DEPEND}
-
-S=${WORKDIR}/${PN}${PV}
-
-src_prepare() {
- epatch "${FILESDIR}"/${P}-warning.patch
- # Modify data paths
- sed -i \
- -e "s:SOUNDS/:${GAMES_DATADIR}/${PN}/SOUNDS/:" \
- -e "s:MUSIC/:${GAMES_DATADIR}/${PN}/MUSIC/:" \
- audio.c || die
- sed -i \
- -e "s:DATA/:${GAMES_DATADIR}/${PN}/DATA/:" \
- -e "s:/usr/tmp:${GAMES_STATEDIR}:" \
- battalion.c || die
- sed -i \
- -e "s:TEXTURES/:${GAMES_DATADIR}/${PN}/TEXTURES/:" \
- graphics.c || die
-
- # Modify Makefile and add CFLAGS
- sed -i \
- -e "s:-O2:${CFLAGS}:" \
- -e "/^CC/d" \
- Makefile || die
- # Only .raw sound files are used on Linux. The .au files are not needed.
- rm -f {SOUNDS,MUSIC}/*.au
-}
-
-src_compile() {
- emake LIBFLAGS="${LDFLAGS}"
-}
-
-src_install() {
- dogamesbin battalion
- insinto "${GAMES_DATADIR}"/${PN}
- doins -r DATA MUSIC SOUNDS TEXTURES
- dodoc README
-
- dodir "${GAMES_STATEDIR}"
- touch "${D}${GAMES_STATEDIR}"/battalion_hiscore
- fperms 660 "${GAMES_STATEDIR}"/battalion_hiscore
-
- prepgamesdirs
-}
-
-pkg_postinst() {
- games_pkg_postinst
- elog "Sound and music are not enabled by default."
- elog "Use the S and M keys to enable them in-game, or start the game with"
- elog "the -s and -m switches: battalion -s -m"
-}
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: games-action/battalion/
@ 2021-09-13 1:39 Ionen Wolkens
0 siblings, 0 replies; 4+ messages in thread
From: Ionen Wolkens @ 2021-09-13 1:39 UTC (permalink / raw
To: gentoo-commits
commit: 49d5fab6297f9dc2b76446ec58cc2ffe710809d2
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 13 01:24:13 2021 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Sep 13 01:38:39 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=49d5fab6
games-action/battalion: EAPI6->8, fix and keyword for ~amd64
Upstream subtly fixed this game for amd64 in the same tarball
without releasing a new version (thus -r1 tarball).
Also fix highscore file (gamestat), and add missing man page
plus .sho data file.
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
games-action/battalion/Manifest | 2 +
games-action/battalion/battalion-1.4b-r2.ebuild | 73 +++++++++++++++++++++++++
2 files changed, 75 insertions(+)
diff --git a/games-action/battalion/Manifest b/games-action/battalion/Manifest
index 5714ea24368..148db2f77c1 100644
--- a/games-action/battalion/Manifest
+++ b/games-action/battalion/Manifest
@@ -1 +1,3 @@
+DIST battalion1.4b-r1.tar.bz2 1103031 BLAKE2B 393561b879813244c90cba1fe1186a65920bf383926c06c28f1ce3a04afa66eab08f3b35925495bf4ca9b0d37eb1925bad5cbace602a8cb575cc4d6c5410fd01 SHA512 5c2acf7941cfd4ae4c7f46b3df7c7e6090dfd099276c67b0de83a4e6e14de00b099814980a12bddf1349407e7e1e62f91da5d0da842fd26f240b9a6cb37ecb04
DIST battalion1.4b.tar.bz2 942342 BLAKE2B 6a4bd9afc7202d68c2cf62fbfe5b3b8377069263d71adaad006d2b4803d5989b130e0ef7fd5b1479a7698d79c819bc463ab19f2fa1493d4caf616708091e2c83 SHA512 c3c615772012c63a709aaeaf4f23246760bf577b82eeec7cf5b2a479c6240fe4a2f839aca50540299ed4bee9b297f61fb8b7e1f5af74ea357f0d7e749d86f84b
+DIST battalionSUN4.tar.gz 1593265 BLAKE2B 239dff49c4d2c33a440594c113f45d347e598935257e30a04a18bd0f6b440b7790436000213fcbacfa862187f4760b9927539977f144ff5e92d7dfddbb7f3d7e SHA512 1e1ea7c7232b99b01a85fdf0660877944d64172b751df1dcd63a6cbeb4179078e80879aca77d84bb37b68fcf082680243987d5b65c77e5ea48e8f5645f9b2ef0
diff --git a/games-action/battalion/battalion-1.4b-r2.ebuild b/games-action/battalion/battalion-1.4b-r2.ebuild
new file mode 100644
index 00000000000..4d03d116cfb
--- /dev/null
+++ b/games-action/battalion/battalion-1.4b-r2.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Be a rampaging monster and destroy the city"
+HOMEPAGE="https://www.evl.uic.edu/aej/AndyBattalion.html"
+SRC_URI="
+ https://www.evl.uic.edu/aej/BATTALION/${PN}${PV}.tar.bz2 -> ${PN}${PV}-r1.tar.bz2
+ https://www.evl.uic.edu/aej/BATTALION/${PN}SUN4.tar.gz"
+S="${WORKDIR}/${PN}${PV}"
+
+LICENSE="battalion HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+ acct-group/gamestat
+ virtual/glu
+ virtual/opengl
+ x11-libs/libX11"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+ "${FILESDIR}"/${P}-warning.patch
+ "${FILESDIR}"/${P}-fix-build-system.patch
+)
+
+src_prepare() {
+ default
+
+ sed -e "/getenv.*DATADIR/s|= .*|= \"${EPREFIX}/usr/share/${PN}\";|" \
+ -e "/getenv.*SCOREDIR/s|= .*|= \"${EPREFIX}/var/games\";|" \
+ -i battalion.c || die
+
+ sed '1s/1/6/' ../${PN}SUN4/${PN}.man > "${T}"/${PN}.6
+
+ # Only .raw sound files are used on Linux. The .au files are not needed.
+ rm {SOUNDS,MUSIC}/*.au || die
+}
+
+src_compile() {
+ tc-export CC PKG_CONFIG
+
+ emake clean
+ emake
+}
+
+src_install() {
+ dobin ${PN}
+ doman "${T}"/${PN}.6
+ einstalldocs
+
+ insinto /usr/share/${PN}
+ doins -r DATA MUSIC SOUNDS TEXTURES ../${PN}SUN4/${PN}.data/${PN}.sho
+
+ dodir /var/games
+ > "${ED}"/var/games/${PN}_hiscore || die
+
+ fowners :gamestat /usr/bin/${PN} /var/games/${PN}_hiscore
+ fperms g+s /usr/bin/${PN}
+ fperms 660 /var/games/${PN}_hiscore
+}
+
+pkg_postinst() {
+ if [[ ! ${REPLACING_VERSIONS} ]]; then
+ elog "Note that sound and music are not enabled by default,"
+ elog "and require OSS support (/dev/dsp) to function."
+ fi
+}
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: games-action/battalion/
@ 2021-09-13 1:39 Ionen Wolkens
0 siblings, 0 replies; 4+ messages in thread
From: Ionen Wolkens @ 2021-09-13 1:39 UTC (permalink / raw
To: gentoo-commits
commit: 8e7ac2adb6decb75238175d90a138ee2d6bce595
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 13 01:32:44 2021 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Sep 13 01:38:39 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8e7ac2ad
games-action/battalion: drop 1.4b-r1
x86-only, not worth keeping
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
games-action/battalion/Manifest | 1 -
games-action/battalion/battalion-1.4b-r1.ebuild | 70 -------------------------
2 files changed, 71 deletions(-)
diff --git a/games-action/battalion/Manifest b/games-action/battalion/Manifest
index 148db2f77c1..b4d48a78dd5 100644
--- a/games-action/battalion/Manifest
+++ b/games-action/battalion/Manifest
@@ -1,3 +1,2 @@
DIST battalion1.4b-r1.tar.bz2 1103031 BLAKE2B 393561b879813244c90cba1fe1186a65920bf383926c06c28f1ce3a04afa66eab08f3b35925495bf4ca9b0d37eb1925bad5cbace602a8cb575cc4d6c5410fd01 SHA512 5c2acf7941cfd4ae4c7f46b3df7c7e6090dfd099276c67b0de83a4e6e14de00b099814980a12bddf1349407e7e1e62f91da5d0da842fd26f240b9a6cb37ecb04
-DIST battalion1.4b.tar.bz2 942342 BLAKE2B 6a4bd9afc7202d68c2cf62fbfe5b3b8377069263d71adaad006d2b4803d5989b130e0ef7fd5b1479a7698d79c819bc463ab19f2fa1493d4caf616708091e2c83 SHA512 c3c615772012c63a709aaeaf4f23246760bf577b82eeec7cf5b2a479c6240fe4a2f839aca50540299ed4bee9b297f61fb8b7e1f5af74ea357f0d7e749d86f84b
DIST battalionSUN4.tar.gz 1593265 BLAKE2B 239dff49c4d2c33a440594c113f45d347e598935257e30a04a18bd0f6b440b7790436000213fcbacfa862187f4760b9927539977f144ff5e92d7dfddbb7f3d7e SHA512 1e1ea7c7232b99b01a85fdf0660877944d64172b751df1dcd63a6cbeb4179078e80879aca77d84bb37b68fcf082680243987d5b65c77e5ea48e8f5645f9b2ef0
diff --git a/games-action/battalion/battalion-1.4b-r1.ebuild b/games-action/battalion/battalion-1.4b-r1.ebuild
deleted file mode 100644
index ae310183dfe..00000000000
--- a/games-action/battalion/battalion-1.4b-r1.ebuild
+++ /dev/null
@@ -1,70 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit toolchain-funcs
-
-DESCRIPTION="Be a rampaging monster and destroy the city"
-HOMEPAGE="http://evlweb.eecs.uic.edu/aej/AndyBattalion.html"
-SRC_URI="http://evlweb.eecs.uic.edu/aej/BATTALION/${PN}${PV}.tar.bz2"
-S="${WORKDIR}"/${PN}${PV}
-
-LICENSE="battalion HPND"
-SLOT="0"
-KEYWORDS="~x86"
-
-DEPEND="
- virtual/glu
- virtual/opengl
- x11-libs/libX11"
-RDEPEND="${DEPEND}"
-
-DEPEND+=" virtual/pkgconfig"
-
-PATCHES=(
- "${FILESDIR}"/${P}-warning.patch
- "${FILESDIR}"/${PN}-1.4b-fix-build-system.patch
-)
-
-src_prepare() {
- default
-
- # Modify data paths
- sed -i \
- -e "s:SOUNDS/:${EPREFIX}/usr/share/${PN}/SOUNDS/:" \
- -e "s:MUSIC/:${EPREFIX}/usr/share/${PN}/MUSIC/:" \
- audio.c || die
- sed -i \
- -e "s:DATA/:${EPREFIX}/usr/share/${PN}/DATA/:" \
- -e "s:/usr/tmp:${EPREFIX}/var/${PN}:" \
- battalion.c || die
- sed -i \
- -e "s:TEXTURES/:${EPREFIX}/usr/share/${PN}/TEXTURES/:" \
- graphics.c || die
-
- # Only .raw sound files are used on Linux. The .au files are not needed.
- rm {SOUNDS,MUSIC}/*.au || die
-}
-
-src_configure() {
- tc-export CC PKG_CONFIG
-}
-
-src_install() {
- dobin battalion
- einstalldocs
-
- insinto /usr/share/${PN}
- doins -r DATA MUSIC SOUNDS TEXTURES
-
- dodir /var/${PN}
- touch "${ED%/}"/var/${PN}/battalion_hiscore || die
- fperms 660 /var/${PN}/battalion_hiscore
-}
-
-pkg_postinst() {
- elog "Sound and music are not enabled by default."
- elog "Use the S and M keys to enable them in-game, or start the game with"
- elog "the -s and -m switches: battalion -s -m"
-}
^ permalink raw reply related [flat|nested] 4+ messages in thread
* [gentoo-commits] repo/gentoo:master commit in: games-action/battalion/
@ 2021-09-13 1:51 Ionen Wolkens
0 siblings, 0 replies; 4+ messages in thread
From: Ionen Wolkens @ 2021-09-13 1:51 UTC (permalink / raw
To: gentoo-commits
commit: f224f73f549c91c94eff6ba77973b08ccb28fa62
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 13 01:46:23 2021 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Sep 13 01:47:39 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f224f73f
games-action/battalion: add desktop entry and missing || die
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
games-action/battalion/battalion-1.4b-r2.ebuild | 6 ++++--
1 file changed, 4 insertions(+), 2 deletions(-)
diff --git a/games-action/battalion/battalion-1.4b-r2.ebuild b/games-action/battalion/battalion-1.4b-r2.ebuild
index 4d03d116cfb..cf5a5613754 100644
--- a/games-action/battalion/battalion-1.4b-r2.ebuild
+++ b/games-action/battalion/battalion-1.4b-r2.ebuild
@@ -3,7 +3,7 @@
EAPI=8
-inherit toolchain-funcs
+inherit desktop toolchain-funcs
DESCRIPTION="Be a rampaging monster and destroy the city"
HOMEPAGE="https://www.evl.uic.edu/aej/AndyBattalion.html"
@@ -36,7 +36,7 @@ src_prepare() {
-e "/getenv.*SCOREDIR/s|= .*|= \"${EPREFIX}/var/games\";|" \
-i battalion.c || die
- sed '1s/1/6/' ../${PN}SUN4/${PN}.man > "${T}"/${PN}.6
+ sed '1s/1/6/' ../${PN}SUN4/${PN}.man > "${T}"/${PN}.6 || die
# Only .raw sound files are used on Linux. The .au files are not needed.
rm {SOUNDS,MUSIC}/*.au || die
@@ -63,6 +63,8 @@ src_install() {
fowners :gamestat /usr/bin/${PN} /var/games/${PN}_hiscore
fperms g+s /usr/bin/${PN}
fperms 660 /var/games/${PN}_hiscore
+
+ make_desktop_entry ${PN} ${PN^} applications-games
}
pkg_postinst() {
^ permalink raw reply related [flat|nested] 4+ messages in thread
end of thread, other threads:[~2021-09-13 1:51 UTC | newest]
Thread overview: 4+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2021-09-13 1:39 [gentoo-commits] repo/gentoo:master commit in: games-action/battalion/ Ionen Wolkens
-- strict thread matches above, loose matches on Subject: below --
2021-09-13 1:51 Ionen Wolkens
2021-09-13 1:39 Ionen Wolkens
2017-11-19 15:51 David Seifert
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox