[gentoo-commits] repo/gentoo:master commit in: games-puzzle/arrows/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     f8be8b23f82a15e5fa44556cf5455da3de0a4ee1
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Fri Sep  3 19:17:46 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Tue Sep  7 12:08:20 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f8be8b23

games-puzzle/arrows: EAPI8 bump, ebuild improvements

Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-puzzle/arrows/arrows-0.6-r2.ebuild | 54 ++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

diff --git a/games-puzzle/arrows/arrows-0.6-r2.ebuild b/games-puzzle/arrows/arrows-0.6-r2.ebuild
new file mode 100644
index 00000000000..cb91302342e
--- /dev/null
+++ b/games-puzzle/arrows/arrows-0.6-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Simple maze-like game where you navigate around and destroy arrows"
+HOMEPAGE="http://noreason.ca/?file=software"
+SRC_URI="http://noreason.ca/data/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-libs/atk
+	dev-libs/glib:2
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:2
+	x11-libs/pango"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# Modify path to data
+	sed -i \
+		-e "s|arrfl|${EPREFIX}/usr/share/${PN}/arrfl|" \
+		-e 's|nm\[9|nm[35|' \
+		-e 's|nm\[6|nm[30|' \
+		-e 's|nm\[7|nm[31|' \
+		game.c || die
+}
+
+src_compile() {
+	emake clean
+	emake CC="$(tc-getCC)" CCOPTS="${CFLAGS}" LINKOPTS="${LDFLAGS}"
+}
+
+src_install() {
+	dobin arrows
+
+	insinto /usr/share/${PN}
+	doins arrfl.[1-5]
+	einstalldocs
+
+	make_desktop_entry ${PN} ${PN^} applications-games
+}