From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1317502-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id F0D471580B2
for <garchives@archives.gentoo.org>; Thu, 2 Sep 2021 07:10:04 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 1E851E083D;
Thu, 2 Sep 2021 07:10:04 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 1AB79E083D
for <gentoo-commits@lists.gentoo.org>; Thu, 2 Sep 2021 07:10:02 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 43C1C335C0F
for <gentoo-commits@lists.gentoo.org>; Thu, 2 Sep 2021 07:10:01 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 909723B
for <gentoo-commits@lists.gentoo.org>; Thu, 2 Sep 2021 07:09:59 +0000 (UTC)
From: "Yixun Lan" <dlan@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Yixun Lan" <dlan@gentoo.org>
Message-ID: <1630566267.fe2411ab19e1a300efcf1e4b7157da77939a7673.dlan@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-i18n/ibus/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-i18n/ibus/Manifest app-i18n/ibus/ibus-1.5.25.ebuild
X-VCS-Directories: app-i18n/ibus/
X-VCS-Committer: dlan
X-VCS-Committer-Name: Yixun Lan
X-VCS-Revision: fe2411ab19e1a300efcf1e4b7157da77939a7673
X-VCS-Branch: master
Date: Thu, 2 Sep 2021 07:09:59 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 90445f8c-8d98-41d7-8028-5514a5507647
X-Archives-Hash: dfba5d2120730ebec23d6d8d060945e5
commit: fe2411ab19e1a300efcf1e4b7157da77939a7673
Author: Yixun Lan <dlan <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 2 07:03:48 2021 +0000
Commit: Yixun Lan <dlan <AT> gentoo <DOT> org>
CommitDate: Thu Sep 2 07:04:27 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fe2411ab
app-i18n/ibus: version bump, 1.5.25
Closes: https://bugs.gentoo.org/810331
Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Yixun Lan <dlan <AT> gentoo.org>
app-i18n/ibus/Manifest | 1 +
app-i18n/ibus/ibus-1.5.25.ebuild | 191 +++++++++++++++++++++++++++++++++++++++
2 files changed, 192 insertions(+)
diff --git a/app-i18n/ibus/Manifest b/app-i18n/ibus/Manifest
index d855d77a1a0..f7c93136993 100644
--- a/app-i18n/ibus/Manifest
+++ b/app-i18n/ibus/Manifest
@@ -2,3 +2,4 @@ DIST ibus-1.5.22.tar.gz 3578251 BLAKE2B 08ad72bd455d2841700b11a4ade88e2b9768433f
DIST ibus-1.5.23-gentoo-patches-1.tar.xz 1596 BLAKE2B 5a2c084cb25cb35d16eba8e6953c1ffc249875ab11485a675497f04a4366ea3fe216bab3407f390a0330f4f17cf5a70a43547160cc9c29a6b14890fcb7867456 SHA512 a1c2a77dbc4185c3658c36b998c9d925fff2bbeb9bc5fde5c74c62081056f134875d557ba0b4af7b06d56f004975889f453adea623541d3bfff2c391912efa05
DIST ibus-1.5.23.tar.gz 3557661 BLAKE2B 4cfb3287c80d46e55090d4f361dd977f4be5988a8b7ffc24755954090dc25021ea6cbb6798769494e6cd70267aac6daa238fdc7cf4156296d93f79f325a18ac4 SHA512 4ea66d0a7203d665fb5c90e59ddf294614feeafc4f06b10e35989671a9bf39d5977e9061b9be224cd5a9439ac2f697a4326ff221ae868f5ebed46cbb09e9a205
DIST ibus-1.5.24.tar.gz 3614372 BLAKE2B 4b851ed9dc8283bf58957adfd5dd4bf7da8b019f95055dbbf7fa157502b3dcc11d561881ff6afa5db0b83b4e7d82f3bd228cd0e21ff77cb81b1eaca246deb135 SHA512 25f34a51a5c85352e61699ca36bf7ddb9b486b28d71e15ce3a52b78bc9db2f8cb558049e0652fdc5431215a5f826fcb5a7d5e44f0de9a2ff746aaf60672e2f22
+DIST ibus-1.5.25.tar.gz 3669787 BLAKE2B 0a568c77d29dfbe0c2c8cdbe8c8ae86b69c7a1a5fa692cf05e9ce13894fcee200c41de91ec0ad88ae9e745e3061b9c92b7fd18641bd297f5bf4a9bc308ace983 SHA512 4b8955a20a1e5a0daf61213817a9697874439866e235e6a7905f5994b145cd5a143e6cfc41f17204a828756baeb8edab70698596731ecebf7f1eea7cc5f36aa6
diff --git a/app-i18n/ibus/ibus-1.5.25.ebuild b/app-i18n/ibus/ibus-1.5.25.ebuild
new file mode 100644
index 00000000000..9dc461da301
--- /dev/null
+++ b/app-i18n/ibus/ibus-1.5.25.ebuild
@@ -0,0 +1,191 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{3_7,3_8,3_9} )
+VALA_MIN_API_VERSION="0.34"
+VALA_MAX_API_VERSION="0.50"
+VALA_USE_DEPEND="vapigen"
+
+inherit autotools bash-completion-r1 gnome2-utils python-r1 vala virtualx xdg-utils
+
+GENTOO_VER=
+DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
+HOMEPAGE="https://github.com/ibus/ibus/wiki"
+
+[[ -n ${GENTOO_VER} ]] && \
+ GENTOO_PATCHSET_URI="https://dev.gentoo.org/~dlan/distfiles/${P}-gentoo-patches-${GENTOO_VER}.tar.xz"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.gz
+ ${GENTOO_PATCHSET_URI}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="+X +emoji +gtk +gtk2 +introspection kde nls +python test +unicode vala wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="emoji? ( gtk )
+ gtk2? ( gtk )
+ kde? ( gtk )
+ python? (
+ ${PYTHON_REQUIRED_USE}
+ introspection
+ )
+ test? ( gtk )
+ vala? ( introspection )"
+
+CDEPEND="app-text/iso-codes
+ dev-libs/glib:2
+ gnome-base/dconf
+ gnome-base/librsvg:2
+ sys-apps/dbus[X?]
+ X? (
+ x11-libs/libX11
+ >=x11-libs/libXfixes-6.0.0
+ !gtk? ( x11-libs/gtk+:2 )
+ )
+ gtk? (
+ x11-libs/gtk+:3
+ x11-libs/libX11
+ x11-libs/libXi
+ gtk2? ( x11-libs/gtk+:2 )
+ )
+ introspection? ( dev-libs/gobject-introspection )
+ kde? ( dev-qt/qtgui:5 )
+ nls? ( virtual/libintl )
+ python? (
+ ${PYTHON_DEPS}
+ dev-python/pygobject:3[${PYTHON_USEDEP}]
+ )
+ wayland? (
+ dev-libs/wayland
+ x11-libs/libxkbcommon
+ )"
+RDEPEND="${CDEPEND}
+ python? (
+ gtk? (
+ x11-libs/gtk+:3[introspection]
+ )
+ )"
+DEPEND="${CDEPEND}
+ $(vala_depend)
+ dev-util/glib-utils
+ virtual/pkgconfig
+ x11-misc/xkeyboard-config
+ emoji? (
+ app-i18n/unicode-cldr
+ app-i18n/unicode-emoji
+ )
+ nls? ( sys-devel/gettext )
+ unicode? ( app-i18n/unicode-data )"
+
+src_prepare() {
+ vala_src_prepare --ignore-use
+ sed -i "/UCD_DIR=/s/\$with_emoji_annotation_dir/\$with_ucd_dir/" configure.ac
+ if ! has_version 'x11-libs/gtk+:3[wayland]'; then
+ touch ui/gtk3/panelbinding.vala
+ fi
+ if ! use emoji; then
+ touch \
+ tools/main.vala \
+ ui/gtk3/panel.vala
+ fi
+ if ! use kde; then
+ touch ui/gtk3/panel.vala
+ fi
+ if [[ -n ${GENTOO_VER} ]]; then
+ einfo "Try to apply Gentoo specific patch set"
+ eapply "${WORKDIR}"/patches-gentoo/*.patch
+ fi
+
+ # for multiple Python implementations
+ sed -i "s/^\(PYGOBJECT_DIR =\).*/\1/" bindings/Makefile.am
+ # fix for parallel install
+ sed -i "/^if ENABLE_PYTHON2/,/^endif/d" bindings/pygobject/Makefile.am
+ # require user interaction
+ sed -i "/^TESTS += ibus-\(compose\|keypress\)/d" src/tests/Makefile.am
+
+ sed -i "/^bash_completion/d" tools/Makefile.am
+
+ default
+ eautoreconf
+ xdg_environment_reset
+}
+
+src_configure() {
+ local unicodedir="${EPREFIX}"/usr/share/unicode
+ local python_conf=()
+ if use python; then
+ python_setup
+ python_conf+=(
+ $(use_enable gtk setup)
+ --with-python=${EPYTHON}
+ )
+ else
+ python_conf+=( --disable-setup )
+ fi
+
+ econf \
+ $(use_enable X xim) \
+ $(use_enable emoji emoji-dict) \
+ $(use_with emoji unicode-emoji-dir "${unicodedir}"/emoji) \
+ $(use_with emoji emoji-annotation-dir "${unicodedir}"/cldr/common/annotations) \
+ $(use_enable gtk gtk3) \
+ $(use_enable gtk ui) \
+ $(use_enable gtk2) \
+ $(use_enable introspection) \
+ $(use_enable kde appindicator) \
+ $(use_enable nls) \
+ $(use_enable test tests) \
+ $(use_enable unicode unicode-dict) \
+ $(use_with unicode ucd-dir "${EPREFIX}/usr/share/unicode-data") \
+ $(use_enable vala) \
+ $(use_enable wayland) \
+ "${python_conf[@]}"
+}
+
+src_test() {
+ unset DBUS_SESSION_BUS_ADDRESS
+ virtx emake -j1 check
+}
+
+src_install() {
+ default
+ find "${ED}" -name '*.la' -delete || die
+
+ if use python; then
+ python_install() {
+ emake -C bindings/pygobject \
+ pyoverridesdir="$(${EPYTHON} -c 'import gi; print(gi._overridesdir)')" \
+ DESTDIR="${D}" \
+ install
+
+ python_optimize
+ }
+ python_foreach_impl python_install
+ fi
+
+ keepdir /usr/share/ibus/engine
+
+ newbashcomp tools/${PN}.bash ${PN}
+
+ insinto /etc/X11/xinit/xinput.d
+ newins xinput-${PN} ${PN}.conf
+
+ # Undo compression of man page
+ find "${ED}"/usr/share/man -type f -name '*.gz' -exec gzip -d {} \; || die
+}
+
+pkg_postinst() {
+ use gtk && gnome2_query_immodules_gtk3
+ use gtk2 && gnome2_query_immodules_gtk2
+ xdg_icon_cache_update
+ gnome2_schemas_update
+ dconf update
+}
+
+pkg_postrm() {
+ use gtk && gnome2_query_immodules_gtk3
+ use gtk2 && gnome2_query_immodules_gtk2
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}