[gentoo-commits] repo/gentoo:master commit in: dev-util/diffoscope/

["Sam James" <sam@gentoo.org>]

commit:     6f2480292e93efd3d04bb288b4a6ae667b368125
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Fri Aug  6 20:59:09 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Aug  6 20:59:43 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6f248029

dev-util/diffoscope: add 180

Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-util/diffoscope/Manifest              |   1 +
 dev-util/diffoscope/diffoscope-180.ebuild | 113 ++++++++++++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/dev-util/diffoscope/Manifest b/dev-util/diffoscope/Manifest
index 833b2088227..e069192f5f0 100644
--- a/dev-util/diffoscope/Manifest
+++ b/dev-util/diffoscope/Manifest
@@ -1,3 +1,4 @@
 DIST diffoscope-177.tar.gz 1590984 BLAKE2B 94daf9528c8fd0ad6ed89bdbee7b21352bf33dcef2ae7e526ea3b1036d92b6fecefcb0da46b7eedf7af1c8bd7995e73b8f0a5104c02f4db534f7bcc465c803aa SHA512 674a5cc364927437a79420b0965eb6958bd09df58a1238ea4d953bb2bc0fbdde75e42817370dd3cdab0bcc59551e1cff70db72298087af551d5dfaee57995811
 DIST diffoscope-178.tar.gz 1600094 BLAKE2B b40e45748be56e49736a826decfb3a8c3ebd91983755719f2665733ceb6ec4e860265c33b5a3c15bc501abe4efdbecbdf177431bbbc79f1ad758c7deef83e1ae SHA512 706c95f5c04cfe081fed7e3e5ed73579949c948b15eaf0f984fc7d406b74007859f7946c44e4ca13e1210b105ed65ea68fd1f03452a50f161ed27f996f4f2540
 DIST diffoscope-179.tar.gz 1600145 BLAKE2B 64b7db8ad53980b80b3c563797736032a235d82b57dfb31496cfbd19978734759919482855ac7dadb62573f950294f02987fd9525b00886e56060450df390915 SHA512 7c3a73097bda2fd55414e52f557707afd08728c73305b55dc9482aff092a65c9bef33913c5e715ff6257aec6cc67095abfec3e8e23f002d43bf9e77e0d565154
+DIST diffoscope-180.tar.gz 1600542 BLAKE2B 0cc34106f039e0682b32de284b3ce1be90e8629fb4ba18cffa31d7c970a9d18392060f37b201d4ee9ab3f4f65401684c72edf2d00d56827cbaacbfde0ce81d11 SHA512 abf2c514b9f3b074a5b9a6e19f09a474a8ba58e00974a48ebd860cc31547204fb4690224cb752b4248a0674d979bd20c6d4c77ffb912f2b85499d48d90affeb4

diff --git a/dev-util/diffoscope/diffoscope-180.ebuild b/dev-util/diffoscope/diffoscope-180.ebuild
new file mode 100644
index 00000000000..ee2bed80f61
--- /dev/null
+++ b/dev-util/diffoscope/diffoscope-180.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="ncurses"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Will try to get to the bottom of what makes files or directories different"
+HOMEPAGE="https://diffoscope.org/ https://pypi.org/project/diffoscope/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="acl binutils bzip2 libcaca colord cpio +diff docx dtc e2fsprogs file
+find gettext gif gpg haskell hdf5 hex imagemagick iso java llvm lzma
+mono opendocument pascal pdf postscript R rpm sqlite squashfs
+ssh tar test tcpdump zip zlib zstd"
+
+RESTRICT="!test? ( test )"
+
+# pull in optional tools for tests:
+# img2txt: bug #797688
+# docx2txt: bug #797688
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		app-text/docx2txt
+		media-libs/libcaca
+	)
+"
+RDEPEND="dev-python/python-magic[${PYTHON_USEDEP}]
+	dev-python/libarchive-c[${PYTHON_USEDEP}]
+	dev-python/distro[${PYTHON_USEDEP}]
+	acl? ( sys-apps/acl )
+	binutils? ( sys-devel/binutils )
+	bzip2? ( app-arch/bzip2 )
+	libcaca? ( media-libs/libcaca )
+	colord? ( x11-misc/colord )
+	cpio? ( app-arch/cpio )
+	diff? ( sys-apps/diffutils )
+	docx? ( app-text/docx2txt )
+	dtc? ( sys-apps/dtc )
+	e2fsprogs? ( sys-fs/e2fsprogs )
+	file? ( sys-apps/file )
+	find? ( sys-apps/findutils )
+	gettext? ( sys-devel/gettext )
+	gif? ( media-libs/giflib )
+	gpg? ( app-crypt/gnupg )
+	haskell? ( dev-lang/ghc )
+	hdf5? ( sci-libs/hdf5 )
+	hex? ( app-editors/vim-core )
+	imagemagick? ( media-gfx/imagemagick )
+	iso? ( app-cdr/cdrtools )
+	java? ( virtual/jdk )
+	llvm? ( sys-devel/llvm )
+	lzma? ( app-arch/xz-utils )
+	mono? ( dev-lang/mono )
+	opendocument? ( app-text/odt2txt )
+	pascal? ( dev-lang/fpc )
+	pdf? (
+		app-text/pdftk
+		app-text/poppler
+		dev-python/PyPDF2[${PYTHON_USEDEP}]
+	)
+	postscript? ( app-text/ghostscript-gpl )
+	R? ( dev-lang/R )
+	rpm? ( app-arch/rpm )
+	sqlite? ( dev-db/sqlite:3 )
+	squashfs? ( sys-fs/squashfs-tools )
+	ssh? ( net-misc/openssh )
+	tar? ( app-arch/tar )
+	tcpdump? ( net-analyzer/tcpdump )
+	zip? ( app-arch/unzip )
+	zlib? ( app-arch/gzip )
+	zstd? ( app-arch/zstd )
+"
+# Presence if filemagic's magic.py breaks imports
+# of dev-python/python-magic: https://bugs.gentoo.org/716482
+RDEPEND+=" !dev-python/filemagic"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local exclude=(
+		# test seems to use different tarball
+		tests/test_presenters.py::test_text_proper_indentation
+
+		# needs triage
+		tests/comparators/test_binary.py::test_with_compare_details_and_tool_not_found
+
+		# needs triage
+		tests/comparators/test_rlib.py::test_item3_deflate_llvm_bitcode
+
+		# img2txt based failures, bug #797688
+		tests/comparators/test_ico_image.py::test_diff
+		tests/comparators/test_ico_image.py::test_diff_meta
+		tests/comparators/test_ico_image.py::test_diff_meta2
+		tests/comparators/test_ico_image.py::test_has_visuals
+		tests/comparators/test_jpeg_image.py::test_diff
+		tests/comparators/test_jpeg_image.py::test_compare_non_existing
+		tests/comparators/test_jpeg_image.py::test_diff_meta
+		tests/comparators/test_jpeg_image.py::test_has_visuals
+
+		# docx2txt based falures, bug #797688
+		tests/comparators/test_docx.py::test_diff
+	)
+	epytest ${exclude[@]/#/--deselect }
+}