[gentoo-commits] repo/gentoo:master commit in: media-gfx/imv/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     f5a7eef430292f3d6295b474539e4bb7ebbfa78c
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Fri Aug  6 01:28:36 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Fri Aug  6 01:30:27 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f5a7eef4

media-gfx/imv: add 4.3.0

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 media-gfx/imv/Manifest         |  1 +
 media-gfx/imv/imv-4.3.0.ebuild | 80 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/media-gfx/imv/Manifest b/media-gfx/imv/Manifest
index 36326fb8ca4..fc84ad70362 100644
--- a/media-gfx/imv/Manifest
+++ b/media-gfx/imv/Manifest
@@ -1 +1,2 @@
 DIST imv-4.2.0.tar.gz 77809 BLAKE2B a0c8aeb4d50d252818f4a4bedc145a8e2ffffa3ae14d888ef4623fe17a714bd17397399064019b32a48e6ebe3613f592428b075988ed533166c06c2b885d245b SHA512 7b64c6d4e5e484fd2ef4e28e2ba5cc74e4d28f8e2fa329ae7c744bd77ce8a345123f9cc3c77e015ff780938d5add97cfe9ed4e5a3a52b03a91b7bb6bb50e7115
+DIST imv-4.3.0.tar.gz 79031 BLAKE2B f620e1d05827f93eae03a01f62cbb1426a623b4ef2e758a5fea2539193292fada0b8bf34276443d787b5a1537e92cd66e94b574a646319c3c37fbf2557bda4eb SHA512 1735c03c48888004b11b3aaf0215a9530c035468a8efdb210d856551ebb75030c906eee2b6ab80e5d3646206e6051a73a8c5e15c010dd09bca7f9e90f9b0e34b

diff --git a/media-gfx/imv/imv-4.3.0.ebuild b/media-gfx/imv/imv-4.3.0.ebuild
new file mode 100644
index 00000000000..73b075d4566
--- /dev/null
+++ b/media-gfx/imv/imv-4.3.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/eXeC64/imv.git"
+else
+	SRC_URI="https://github.com/eXeC64/imv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Minimal image viewer designed for tiling window manager users"
+HOMEPAGE="https://github.com/eXeC64/imv/"
+
+LICENSE="MIT-with-advertising"
+SLOT="0"
+IUSE="+X +freeimage gif heif jpeg png svg test tiff wayland"
+REQUIRED_USE="|| ( X wayland )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/icu:=
+	dev-libs/inih
+	media-libs/libglvnd[X?]
+	x11-libs/cairo
+	x11-libs/libxkbcommon[X?]
+	x11-libs/pango
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb:=
+	)
+	freeimage? ( media-libs/freeimage )
+	gif? ( media-libs/libnsgif )
+	heif? ( media-libs/libheif:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	png? ( media-libs/libpng:= )
+	svg? ( >=gnome-base/librsvg-2.44 )
+	tiff? ( media-libs/tiff )
+	wayland? ( dev-libs/wayland )
+	!sys-apps/renameutils"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	test? ( dev-util/cmocka )"
+BDEPEND="
+	app-text/asciidoc
+	wayland? ( dev-util/wayland-scanner )"
+
+src_prepare() {
+	default
+
+	# if wayland-only, don't automagic on libGL and force libOpenGL
+	if ! use X; then
+		sed -i "/dependency('gl'/{s/'gl'/'opengl'/;s/false/true/}" meson.build || die
+	fi
+
+	# glu isn't used by anything
+	sed -i "/dependency('glu')/d" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature freeimage)
+		$(meson_feature gif libnsgif)
+		$(meson_feature heif libheif)
+		$(meson_feature jpeg libjpeg)
+		$(meson_feature png libpng)
+		$(meson_feature svg librsvg)
+		$(meson_feature test)
+		$(meson_feature tiff libtiff)
+		-Dwindows=$(usex X $(usex wayland all x11) wayland)
+	)
+
+	meson_src_configure
+}