[gentoo-commits] repo/gentoo:master commit in: games-arcade/tuxanci/, games-arcade/tuxanci/files/

[gentoo-commits] repo/gentoo:master commit in: games-arcade/tuxanci/, games-arcade/tuxanci/files/

[Ionen Wolkens]

commit:     c4ed27dd4826f929a4e19fb4cc1f60f5bb63d230
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Thu Jul 29 07:34:30 2021 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Thu Jul 29 08:33:01 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c4ed27dd

games-arcade/tuxanci: fix install paths and opengl, tidy

bug #804642: ebuild itself been passing /usr/{pixmaps,applications}
since games.eclass removal and this went unnoticed for 4 years.

bug #798651: As a "fix" to bug #715132, it was made to search for
GLU instead of GL and unsurprisingly failing to find GL symbols.
This does not use GLU at all, so only remove version check.

Removed ipv6,nls,sound IUSE, enable by default.
USE=-sound was also installing ogg files either way.

Also removed debug IUSE because all it does is override user CFLAGS.

Closes: https://bugs.gentoo.org/798651
Closes: https://bugs.gentoo.org/804642
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 .../tuxanci/files/tuxanci-20110429-no-glver.patch  |  9 +++++
 games-arcade/tuxanci/tuxanci-20110429-r2.ebuild    | 45 ++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/games-arcade/tuxanci/files/tuxanci-20110429-no-glver.patch b/games-arcade/tuxanci/files/tuxanci-20110429-no-glver.patch
new file mode 100644
index 00000000000..210e55d1199
--- /dev/null
+++ b/games-arcade/tuxanci/files/tuxanci-20110429-no-glver.patch
@@ -0,0 +1,9 @@
+https://bugs.gentoo.org/715132
+https://bugs.gentoo.org/798651
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -189,3 +189,3 @@
+ 	IF ( WITH_OPENGL )
+-		pkg_check_modules(OPENGL REQUIRED gl>=7.5)
++		pkg_check_modules(OPENGL REQUIRED gl)
+ 		INCLUDE_DIRECTORIES ( ${OPENGL_INCLUDE_DIRS} )

diff --git a/games-arcade/tuxanci/tuxanci-20110429-r2.ebuild b/games-arcade/tuxanci/tuxanci-20110429-r2.ebuild
new file mode 100644
index 00000000000..4428d33da87
--- /dev/null
+++ b/games-arcade/tuxanci/tuxanci-20110429-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="First Tux shooter multi-player network game inspired by Bulanci"
+HOMEPAGE="https://repo.or.cz/w/tuxanci.git"
+SRC_URI="mirror://gentoo/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="dedicated opengl physfs"
+
+RDEPEND="
+	!dedicated? (
+		media-libs/fontconfig
+		media-libs/libsdl[opengl?,sound,video]
+		media-libs/sdl-image[png]
+		media-libs/sdl-mixer[vorbis]
+		media-libs/sdl-ttf
+		opengl? ( virtual/opengl )
+	)
+	physfs? ( dev-games/physfs[zip] )
+	!physfs? ( dev-libs/libzip:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="sys-devel/gettext"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-no-glver.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SERVER=$(usex dedicated)
+		-DCMAKE_CONF_PATH="${EPREFIX}"/etc
+		-DCMAKE_DOC_PATH="${EPREFIX}"/usr/share/doc/${PF}
+		-DENABLE_DEBUG=no
+		-DWITH_OPENGL=$(usex opengl)
+		-DWITH_PHYSFS=$(usex physfs)
+	)
+	cmake_src_configure
+}