From: "Dennis Lamm" <expeditioneer@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-libs/libcharon/
Date: Fri, 23 Jul 2021 12:46:42 +0000 (UTC) [thread overview]
Message-ID: <1627044395.e171a99080a7b92c70f43396fba36cdb0ee66e45.expeditioneer@gentoo> (raw)
commit: e171a99080a7b92c70f43396fba36cdb0ee66e45
Author: Dennis Lamm <expeditioneer <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 23 04:38:48 2021 +0000
Commit: Dennis Lamm <expeditioneer <AT> gentoo <DOT> org>
CommitDate: Fri Jul 23 12:46:35 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e171a990
dev-libs/libcharon: byte-compile missing modules
Bug: https://bugs.gentoo.org/802006
Signed-off-by: Dennis Lamm <expeditioneer <AT> gentoo.org>
Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Dennis Lamm <expeditioneer <AT> gentoo.org>
dev-libs/libcharon/libcharon-4.9.1-r1.ebuild | 72 ++++++++++++++++++++++++++++
dev-libs/libcharon/metadata.xml | 3 --
2 files changed, 72 insertions(+), 3 deletions(-)
diff --git a/dev-libs/libcharon/libcharon-4.9.1-r1.ebuild b/dev-libs/libcharon/libcharon-4.9.1-r1.ebuild
new file mode 100644
index 00000000000..8bb7404534a
--- /dev/null
+++ b/dev-libs/libcharon/libcharon-4.9.1-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit cmake python-single-r1
+
+MY_PN="libCharon"
+
+DESCRIPTION="This library facilitates communication between Cura and its backend"
+HOMEPAGE="https://github.com/Ultimaker/libCharon"
+SRC_URI="https://github.com/Ultimaker/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+IUSE="+client +dbus test"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RDEPEND="
+ ${PYTHON_DEPS}
+ dbus? (
+ acct-group/ultimaker
+ acct-user/ultimaker
+ sys-apps/dbus
+ )"
+
+DEPEND="${PYTHON_DEPS}
+ test? (
+ $(python_gen_cond_dep 'dev-python/pytest[${PYTHON_USEDEP}]')
+ )"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+ # use current python version, not the latest installed
+ # fix python install location
+ sed -i \
+ -e "s:find_package(Python3 3.4 REQUIRED:find_package(Python3 ${EPYTHON##python} EXACT REQUIRED:g" \
+ -e "s:lib\${LIB_SUFFIX}/python\${Python3_VERSION_MAJOR}\.\${Python3_VERSION_MINOR}/site-packages:$(python_get_sitedir):g" \
+ CMakeLists.txt || die
+
+ sed -i -e "s:/usr/lib/python3/dist-packages/Charon/Service/main.py:$(python_get_sitedir)/Charon/Service/main.py:g" service/charon.service || die
+
+ cmake_src_prepare
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DINSTALL_CLIENT=$(usex client ON OFF)
+ -DINSTALL_SERVICE=$(usex dbus ON OFF)
+ -DPython3_EXECUTABLE="${PYTHON}"
+ )
+
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+ python_optimize
+}
+
+pkg_postinst() {
+ if use dbus ; then
+ elog "To start the Charon File Metadata service at boot, add it to the default runlevel with:"
+ elog " systemctl enable charon"
+ fi
+}
diff --git a/dev-libs/libcharon/metadata.xml b/dev-libs/libcharon/metadata.xml
index f522947e90f..572a52741db 100644
--- a/dev-libs/libcharon/metadata.xml
+++ b/dev-libs/libcharon/metadata.xml
@@ -21,9 +21,6 @@
<email>perlovka@gmail.com</email>
<name>Michael Perlov</name>
</maintainer>
- <slots>
- <subslots>soname major version number</subslots>
- </slots>
<longdescription>
Library to read and write several 3D-printing related file formats including G-Code and Ultimaker File Package (UFP).
</longdescription>
next reply other threads:[~2021-07-23 12:46 UTC|newest]
Thread overview: 26+ messages / expand[flat|nested] mbox.gz Atom feed top
2021-07-23 12:46 Dennis Lamm [this message]
-- strict thread matches above, loose matches on Subject: below --
2022-07-09 10:52 [gentoo-commits] repo/gentoo:master commit in: dev-libs/libcharon/ Matthew Smith
2022-05-09 7:00 Michał Górny
2022-05-08 19:59 Sam James
2022-03-10 21:21 Jakov Smolić
2022-02-28 19:43 Matthew Smith
2022-02-10 17:35 Marek Szuba
2021-11-02 8:38 Arthur Zamarin
2021-07-23 12:46 Dennis Lamm
2021-06-10 17:41 Dennis Lamm
2021-02-07 21:30 Dennis Lamm
2020-11-30 18:37 Dennis Lamm
2020-10-11 11:25 Dennis Lamm
2020-09-19 16:34 Sam James
2020-05-25 19:42 Alexey Shvetsov
2019-10-16 5:22 Joonas Niilola
2019-10-16 5:22 Joonas Niilola
2019-08-25 17:59 Joonas Niilola
2019-08-12 19:47 Michał Górny
2019-01-02 22:05 Amy Liffey
2019-01-02 21:52 Amy Liffey
2018-11-18 17:05 Amy Liffey
2018-07-16 16:36 Amy Liffey
2018-06-14 20:14 Alexey Shvetsov
2018-06-14 18:19 Jonas Stein
2018-06-14 13:11 Alexey Shvetsov
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1627044395.e171a99080a7b92c70f43396fba36cdb0ee66e45.expeditioneer@gentoo \
--to=expeditioneer@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox