From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1304436-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 733AB13933E
for <garchives@archives.gentoo.org>; Tue, 20 Jul 2021 19:03:51 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id A88A0E0AD3;
Tue, 20 Jul 2021 19:03:49 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 82844E0AD3
for <gentoo-commits@lists.gentoo.org>; Tue, 20 Jul 2021 19:03:49 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id C0986340824
for <gentoo-commits@lists.gentoo.org>; Tue, 20 Jul 2021 19:03:47 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 7673B846
for <gentoo-commits@lists.gentoo.org>; Tue, 20 Jul 2021 19:03:43 +0000 (UTC)
From: "Conrad Kostecki" <conikost@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Conrad Kostecki" <conikost@gentoo.org>
Message-ID: <1626807793.5a0a6995723b4bdacd0794c6b95131e8e88561af.conikost@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: games-simulation/openrct2/
X-VCS-Repository: repo/gentoo
X-VCS-Files: games-simulation/openrct2/Manifest games-simulation/openrct2/openrct2-0.3.4.ebuild
X-VCS-Directories: games-simulation/openrct2/
X-VCS-Committer: conikost
X-VCS-Committer-Name: Conrad Kostecki
X-VCS-Revision: 5a0a6995723b4bdacd0794c6b95131e8e88561af
X-VCS-Branch: master
Date: Tue, 20 Jul 2021 19:03:43 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: cc194a58-9198-439a-bab6-216e0344aa51
X-Archives-Hash: 72712b4f492452c4035ac91aa2f4a13b
commit: 5a0a6995723b4bdacd0794c6b95131e8e88561af
Author: Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 20 18:17:28 2021 +0000
Commit: Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Tue Jul 20 19:03:13 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5a0a6995
games-simulation/openrct2: bump to version 0.3.4
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>
games-simulation/openrct2/Manifest | 1 +
games-simulation/openrct2/openrct2-0.3.4.ebuild | 166 ++++++++++++++++++++++++
2 files changed, 167 insertions(+)
diff --git a/games-simulation/openrct2/Manifest b/games-simulation/openrct2/Manifest
index 384963e01fc..bc5d218bb3b 100644
--- a/games-simulation/openrct2/Manifest
+++ b/games-simulation/openrct2/Manifest
@@ -1,4 +1,5 @@
DIST openrct2-0.3.3.tar.gz 14107179 BLAKE2B 9c19bf8f88ef7aa33c345ec46c3dc70ae1221fcad075880a86bd3a577835640002126018d2a5251e063d6259cdd3cd4bde58097feb9095b793538b363b827c5d SHA512 de270f043aa9c0c8955eda060c52e430556f212443f4ebb01d2a19012ad84ae81547b65a906bbcf4f04e7a816477abbd05866ddd635903194f6444e8c3cc58f8
+DIST openrct2-0.3.4.tar.gz 14186428 BLAKE2B f30ee821e0993fc30cbb19f72ffefc47006582c79832a6041d93382278c1a5e8d366a0fba2bf8d81c1b58ce720f680e947885eb11322329bd63edd7f2bafa4d6 SHA512 13014f4e43b04ee34af713cdddf6b5fdcb8b928f9ff0d54bd7c4476074113a5b48ebb9942b5da6b1712a8f9033919c426948d771907b9a725821778e080413bc
DIST openrct2-objects-1.0.21.zip 3159059 BLAKE2B 9a42cddb02a0b5c476d5e84c5943d08190957567ea9cff44b0d4496f6a9ee9a548dd0a359e4a4dac21eacac9a074e25f7fc4ce1c37f4002dd5d35c61660e68c2 SHA512 b267db6542562c0c46c9964c865d33abff57d3d3c9a1f4073366f34cc229af2483a51538e56597d0e17ffdcd5bb1ba52ddc8198f8a0afaf0a30fdc2e00e6b3c0
DIST openrct2-objects-1.2.1.zip 3381089 BLAKE2B d7b26e45dad74e5c2b30669bb9bfa96e6a9c8e0cf9dfc9b6205f0cd9f24075555267585d2132472eaf412ffc95eea668dfb0c6297ad17a52d02e998dfdee7cd8 SHA512 86d44325037184adcb59397f4d68c5248b0efbfaf1ac9416155fa46886a4784c2a1bf1ab4922fa75a3c6182f1025d1d41314ebafa8ae878b8a8d85670d16d3c9
DIST openrct2-replays-0.0.31.zip 1783829 BLAKE2B 70ef5a5ad89b531baefecfa4c673a4d41e18c4ef5586f045a2174bf39d61bc59ebd5deee23abbba138bd9b943f056134845c8710397b84fc388a5e268025b7d2 SHA512 cb26543ad44a9d2c5d4a22e666c9efce605b0de34ac7cc8f42853792f50b8eda9eb551d2e6d0724fc4d282c83043718fa074cdd5081a9f12aebdc62efd2c082c
diff --git a/games-simulation/openrct2/openrct2-0.3.4.ebuild b/games-simulation/openrct2/openrct2-0.3.4.ebuild
new file mode 100644
index 00000000000..b734ade37c7
--- /dev/null
+++ b/games-simulation/openrct2/openrct2-0.3.4.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake readme.gentoo-r1 xdg-utils
+
+MY_PN="OpenRCT2"
+MY_PN_OBJ="objects"
+MY_PN_RPL="replays"
+MY_PN_TS="title-sequences"
+MY_PV_OBJ="1.0.21"
+MY_PV_RPL="0.0.43"
+MY_PV_TS="0.1.2c"
+
+DESCRIPTION="An open source re-implementation of Chris Sawyer's RollerCoaster Tycoon 2"
+HOMEPAGE="https://openrct2.org/"
+SRC_URI="
+ https://github.com/${MY_PN}/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+ https://github.com/${MY_PN}/${MY_PN_OBJ}/releases/download/v${MY_PV_OBJ}/${MY_PN_OBJ}.zip -> ${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}.zip
+ https://github.com/${MY_PN}/${MY_PN_TS}/releases/download/v${MY_PV_TS}/${MY_PN_TS}.zip -> ${PN}-${MY_PN_TS}-${MY_PV_TS}.zip
+ test? ( https://github.com/${MY_PN}/${MY_PN_RPL}/releases/download/v${MY_PV_RPL}/${MY_PN_RPL}.zip -> ${PN}-${MY_PN_RPL}-${MY_PV_RPL}.zip )
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 x86"
+IUSE="dedicated +lightfx +opengl scripting test +truetype"
+
+COMMON_DEPEND="
+ dev-libs/icu:=
+ dev-libs/jansson
+ dev-libs/libzip:=
+ media-libs/libpng:0=
+ net-misc/curl[ssl]
+ sys-libs/zlib
+ !dedicated? (
+ media-libs/libsdl2
+ media-libs/speexdsp
+ opengl? ( virtual/opengl )
+ )
+ dev-libs/openssl:0=
+ scripting? ( dev-lang/duktape:= )
+ truetype? (
+ media-libs/fontconfig:1.0
+ media-libs/freetype:2
+ )
+"
+
+RDEPEND="
+ ${COMMON_DEPEND}
+ dedicated? (
+ acct-group/openrct2
+ acct-user/openrct2
+ )
+"
+
+DEPEND="
+ ${COMMON_DEPEND}
+ dev-cpp/nlohmann_json
+ test? ( dev-cpp/gtest )
+"
+
+BDEPEND="
+ app-arch/unzip
+ virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-0.2.4-include-additional-paths.patch"
+ "${FILESDIR}/${PN}-0.2.6-gtest-1.10.patch"
+)
+
+src_unpack() {
+ unpack "${P}".tar.gz
+
+ mkdir -p "${S}"/data/sequence || die
+ cd "${S}"/data/sequence || die
+ unpack "${PN}-${MY_PN_TS}-${MY_PV_TS}".zip
+
+ mkdir -p "${S}"/data/object || die
+ cd "${S}"/data/object || die
+ unpack "${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}".zip
+
+ if use test; then
+ mkdir -p "${S}"/testdata/replays || die
+ cd "${S}"/testdata/replays || die
+ unpack "${PN}-${MY_PN_RPL}-${MY_PV_RPL}".zip
+ fi
+}
+
+src_prepare() {
+ cmake_src_prepare
+
+ # Don't treat warnings as errors.
+ sed -e 's/-Werror//' -i CMakeLists.txt || die
+}
+
+src_configure() {
+ # Note: There is currently no support for Disord-RPC and Google Benchmark,
+ # as both packages do not exist in Gentoo, so support for them has been disabled.
+ local mycmakeargs=(
+ -DDISABLE_DISCORD_RPC=ON
+ -DDISABLE_GOOGLE_BENCHMARK=ON
+ -DDISABLE_GUI=$(usex dedicated)
+ -DDISABLE_HTTP=OFF
+ -DDISABLE_NETWORK=OFF
+ $(usex !dedicated "-DDISABLE_OPENGL=$(usex !opengl)" "")
+ -DDISABLE_TTF=$(usex !truetype)
+ -DDOWNLOAD_OBJECTS=OFF
+ -DDOWNLOAD_REPLAYS=OFF
+ -DDOWNLOAD_TITLE_SEQUENCES=OFF
+ -DENABLE_LIGHTFX=$(usex lightfx)
+ -DENABLE_SCRIPTING=$(usex scripting)
+ -DOPENRCT2_USE_CCACHE=OFF
+ -DPORTABLE=OFF
+ -DSTATIC=OFF
+ $(usex test "-DSYSTEM_GTEST=ON" "")
+ -DWITH_TESTS=$(usex test)
+ -DUSE_MMAP=ON
+ )
+
+ cmake_src_configure
+}
+
+src_test() {
+ # Since the tests need the OpenRCT2 data,
+ # we need to symlink them into the build directory,
+ # otherwise some tests will fail, as they don't find the OpenRCT2 data.
+ # It is currently not possible to override that path.
+ # See: https://github.com/OpenRCT2/OpenRCT2/issues/6473
+ ln -s "${S}"/data "${BUILD_DIR}" || die
+
+ cmake_src_test
+}
+
+src_install() {
+ use scripting && DOCS+=( "distribution/scripting.md" "distribution/openrct2.d.ts" )
+
+ cmake_src_install
+
+ if use dedicated; then
+ newinitd "${FILESDIR}"/openrct2.initd openrct2
+ newconfd "${FILESDIR}"/openrct2.confd openrct2
+ fi
+
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ readme.gentoo_print_elog
+
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+ xdg_icon_cache_update
+ xdg_mimeinfo_database_update
+}