[gentoo-commits] repo/gentoo:master commit in: media-sound/csound/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     3b485c3fb240a3277e620ec9c868c9c0034e9a98
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 18 07:04:43 2021 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Sun Jul 18 07:04:54 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3b485c3f

media-sound/csound: bump to 6.16.2

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/csound/Manifest             |   1 +
 media-sound/csound/csound-6.16.2.ebuild | 262 ++++++++++++++++++++++++++++++++
 2 files changed, 263 insertions(+)

diff --git a/media-sound/csound/Manifest b/media-sound/csound/Manifest
index d8a94873890..b1c0a022a4e 100644
--- a/media-sound/csound/Manifest
+++ b/media-sound/csound/Manifest
@@ -5,3 +5,4 @@ DIST Csound6.16.0_manual_pdf.zip 9640644 BLAKE2B 7bb35f806568a80abbd84a4f4988217
 DIST csound-6.15.0-distributable.tar.xz 25156784 BLAKE2B f944385256b423d95da2df8da7dc2bcf164ffc469f55650396827bc9da49ef1778039772e149bcbde77c71a363e8ea253ec3103c753cc3916d63d450f571c2a8 SHA512 a0a65805507ac7afd6bcb0fe988cb1bdba0a95a591ac6837a2c31cf3a7aeef56fee44eed7bca14409ccf600412782098a8c2ffb1aecb5eefd703bc270a0ee308
 DIST csound-6.16.0-distributable.tar.xz 25129496 BLAKE2B cecfe82e9d584ac9e453659b617d54d2f899efd3e65243ba38770e5174baec6f12b0fa6c06c8ef2154f7c80faee8b9992bbe0957892a4ba86e142066aea85578 SHA512 243b23fc7cde3f0348953e88856117355b5b7185314045aad1b6dac236e227c558afd3fd8a73d9d760f3e5a30ee50d02cc7fe3d8b4b84fb63fa82c64972ca1ca
 DIST csound-6.16.1-distributable.tar.xz 25142436 BLAKE2B fe29208afe2cfc9740e68da213f269ca909facd452ffdd595e14a6dc14526bd497e8a2bc1832da28b0bbd6c8b9ac8891f79d819abf64cba0a9e1002c42f8e5dd SHA512 2535f16dab6a682e38b8352cb7bb87a65aedf0550c1705cde8a64b3c0112d7fd97e6c366dad18ef9ef5e1baaf7123f2c0032d9a2ab6979c202692c3a4069117e
+DIST csound-6.16.2-distributable.tar.xz 25169396 BLAKE2B f51c27606f53571d998a62667c55c60a831c076ced993c4eaa8fa24a7e0a8d4872055dc59455b70124f51e2c419018345e2d0e9a33b95d4362f8c6bdecb8310d SHA512 b72c89b2935d92840f5cb7f6d5696e74a3528f5d37858218691f0f6331a69f63b261937a8a8d346d6e182cf8f4a40af85167a4e42fd005cfcf5b4c9daa822f75

diff --git a/media-sound/csound/csound-6.16.2.ebuild b/media-sound/csound/csound-6.16.2.ebuild
new file mode 100644
index 00000000000..b8549ffc9aa
--- /dev/null
+++ b/media-sound/csound/csound-6.16.2.ebuild
@@ -0,0 +1,262 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# As upstream (and we aswell) are not allowed to redistribute scansyn,
+# we have to repackage the tarball. For that purpose use `bash files/repackage.sh version`
+# Reference: https://github.com/csound/csound/issues/1148
+
+EAPI=7
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit cmake lua-single python-single-r1 toolchain-funcs
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/csound/csound.git"
+	inherit git-r3
+else
+	DOC_P="Csound$(ver_cut 1-2).0"
+	SRC_URI="https://dev.gentoo.org/~fordfrog/distfiles/${P}-distributable.tar.xz
+		doc? (
+			https://github.com/csound/csound/releases/download/${PV}/${DOC_P}_manual_pdf.zip
+			https://github.com/csound/csound/releases/download/${PV}/${DOC_P}_manual_html.zip
+		)"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Sound design and signal processing system for composition and performance"
+HOMEPAGE="https://csound.github.io/"
+
+LICENSE="LGPL-2.1 doc? ( FDL-1.2+ )"
+SLOT="0"
+IUSE="+alsa beats chua curl +cxx debug doc double-precision dssi examples
+fltk +fluidsynth hdf5 jack java keyboard linear lua mp3 nls osc portaudio
+portaudio portmidi pulseaudio python samples static-libs stk test +threads +utils
+vim-syntax websocket"
+
+REQUIRED_USE="
+	alsa? ( threads )
+	java? ( cxx )
+	linear? ( double-precision )
+	lua? ( ${LUA_REQUIRED_USE} cxx )
+	python? ( ${PYTHON_REQUIRED_USE} cxx )
+"
+
+BDEPEND="
+	sys-devel/flex
+	virtual/yacc
+	chua? ( dev-libs/boost )
+	lua? ( dev-lang/swig )
+	python? ( dev-lang/swig )
+	nls? ( sys-devel/gettext )
+	test? (
+		dev-util/cunit
+		${PYTHON_DEPS}
+	)
+"
+# linear currently works only with sci-mathematics-gmm-5.1
+#   https://github.com/csound/csound/issues/920
+CDEPEND="
+	dev-cpp/eigen:3
+	>=media-libs/libsndfile-1.0.16
+	media-libs/libsamplerate
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	curl? ( net-misc/curl )
+	dssi? (
+		media-libs/dssi
+		media-libs/ladspa-sdk
+	)
+	fluidsynth? ( media-sound/fluidsynth:= )
+	fltk? ( x11-libs/fltk:1[threads?] )
+	hdf5? ( sci-libs/hdf5 )
+	jack? ( virtual/jack )
+	java? ( >=virtual/jdk-1.8:* )
+	keyboard? ( x11-libs/fltk:1[threads?] )
+	linear? ( =sci-mathematics/gmm-5.1* )
+	lua? ( ${LUA_DEPS} )
+	mp3? ( >=media-sound/lame-3.100-r3 )
+	osc? ( media-libs/liblo )
+	portaudio? ( media-libs/portaudio )
+	portmidi? ( media-libs/portmidi )
+	pulseaudio? ( media-sound/pulseaudio )
+	python? ( ${PYTHON_DEPS} )
+	stk? ( media-libs/stk )
+	utils? ( !media-sound/snd )
+	websocket? ( net-libs/libwebsockets:= )
+"
+RDEPEND="${CDEPEND}"
+DEPEND="
+	${CDEPEND}
+	dev-libs/boost
+"
+
+if [[ ${PV} != "9999" ]]; then
+	DEPEND+="doc? ( app-arch/unzip )"
+fi
+
+# requires specific alsa settings
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-6.13.0-xdg-open.patch"
+	"${FILESDIR}/${PN}-6.15.0-lame.patch"
+)
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+
+	if use python || use test ; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -e '/set(PLUGIN_INSTALL_DIR/s/-${APIVERSION}//' \
+		-e '/-O3/d' \
+		-i CMakeLists.txt || die
+
+	if use doc; then
+		local png="${WORKDIR}/html/images/delayk.png"
+		pngfix -q --out=${png/.png/fixed.png} ${png} # see pngfix help for exit codes
+		[[ $? -gt 15 ]] && die "Failed to fix ${png}"
+		mv -f ${png/.png/fixed.png} ${png} || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_BELA=OFF
+		-DBUILD_BUCHLA_OPCODES=ON
+		-DBUILD_CHUA_OPCODES=$(usex chua)
+		-DBUILD_COUNTER_OPCODES=ON
+		-DBUILD_CSBEATS=$(usex beats)
+		-DBUILD_CUDA_OPCODES=OFF
+		-DBUILD_CXX_INTERFACE=$(usex cxx)
+		-DBUILD_DSSI_OPCODES=$(usex dssi)
+		-DBUILD_EMUGENS_OPCODES=ON
+		-DBUILD_EXCITER_OPCODES=ON
+		-DBUILD_FLUID_OPCODES=$(usex fluidsynth)
+		-DBUILD_FRAMEBUFFER_OPCODES=ON
+		-DBUILD_HDF5_OPCODES=$(usex hdf5)
+		-DBUILD_INSTALLER=OFF
+		-DBUILD_JACK_OPCODES=$(usex jack)
+		-DBUILD_JAVA_INTERFACE=$(usex java)
+		-DBUILD_LINEAR_ALGEBRA_OPCODES=$(usex linear)
+		-DBUILD_LUA_INTERFACE=$(usex lua)
+		-DBUILD_MP3OUT_OPCODE=$(usex mp3)
+		-DBUILD_MULTI_CORE=$(usex threads)
+		-DBUILD_OPENCL_OPCODES=OFF
+		-DBUILD_OSC_OPCODES=$(usex osc)
+		-DBUILD_P5GLOVE_OPCODES=OFF
+		-DBUILD_PADSYNTH_OPCODES=ON
+		-DBUILD_PLATEREV_OPCODES=ON
+		-DBUILD_PVSGENDY_OPCODE=OFF
+		-DBUILD_PYTHON_INTERFACE=$(usex python)
+		-DBUILD_RELEASE=ON
+		-DBUILD_SCANSYN_OPCODES=OFF # this is not allowed to be redistributed: https://github.com/csound/csound/issues/1148
+		-DBUILD_SELECT_OPCODE=ON
+		-DBUILD_SERIAL_OPCODES=ON
+		-DBUILD_SHARED_LIBS=ON
+		-DBUILD_STACK_OPCODES=ON
+		-DBUILD_STATIC_LIBRARY=$(usex static-libs "ON" $(usex test))
+		-DBUILD_STK_OPCODES=$(usex stk)
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_UTILITIES=$(usex utils)
+		-DBUILD_VIRTUAL_KEYBOARD=$(usex keyboard)
+		-DBUILD_VST4CS_OPCODES=OFF
+		-DBUILD_WEBSOCKET_OPCODE=$(usex websocket)
+		-DBUILD_WIIMOTE_OPCODES=OFF
+		-DBUILD_WINSOUND=OFF
+
+		-DFAIL_MISSING=ON
+		-DNEW_PARSER_DEBUG=$(usex debug)
+		-DREQUIRE_PTHREADS=$(usex threads)
+
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_ATOMIC_BUILTIN=ON
+		-DUSE_AUDIOUNIT=OFF # Apple specific
+		-DUSE_COMPILER_OPTIMIZATIONS=ON
+		-DUSE_COREMIDI=OFF # Apple specific
+		-DUSE_CURL=$(usex curl)
+		-DUSE_DOUBLE=$(usex double-precision)
+		-DUSE_FLTK=$(usex fltk)
+		-DUSE_GETTEXT=$(usex nls)
+		-DUSE_GIT_COMMIT=ON
+		-DUSE_IPMIDI=ON
+		-DUSE_JACK=$(usex jack)
+		-DUSE_LIB64=$([[ $(get_libdir) == "lib64" ]] && echo "ON" || echo "OFF")
+		-DUSE_LRINT=ON
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PORTMIDI=$(usex portmidi)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+
+	)
+
+	use java && mycmakeargs+=(
+		-DJAVA_HOME="$(java-config -g JAVA_HOME)"
+	)
+
+	use lua && mycmakeargs+=(
+		-DLUA_H_PATH="$(lua_get_include_dir)"
+		-DLUA_LIBRARY="$(lua_get_shared_lib)"
+		# LUA_MODULE_INSTALL_DIR omitted on purpose, csound Lua module links against liblua
+		# so it must NOT be installed into cmod_dir.
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	dodoc -r Release_Notes/.
+
+	# generate env.d file
+	cat > "${T}"/62${PN} <<-_EOF_ || die
+		OPCODEDIR$(usex double-precision 64 '')="${EPREFIX}/usr/$(get_libdir)/${PN}/plugins$(usex double-precision 64 '')"
+		CSSTRNGS="${EPREFIX}/usr/share/locale"
+	_EOF_
+	if use stk ; then
+		echo RAWWAVE_PATH=\"${EPREFIX}/usr/share/csound/rawwaves\" >> "${T}"/62${PN} || die
+	fi
+	doenvd "${T}"/62${PN}
+
+	if use examples ; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	use samples && dodoc -r samples
+
+	if use vim-syntax ; then
+		insinto /usr/share/vim/vimfiles/syntax
+		doins installer/misc/vim/csound_{csd,orc,sco}.vim
+		insinto /usr/share/vim/vimfiles/plugin
+		doins installer/misc/vim/csound.vim
+	fi
+
+	# rename extract to csound_extract (bug #247394)
+	mv "${ED}"/usr/bin/{,csound_}extract || die
+
+	use python && python_optimize
+
+	use java && (dosym lib_jcsound6.so usr/lib64/lib_jcsound.so.1 || die "Failed to create java lib symlink")
+
+	# install docs
+	if [[ ${PV} != "9999" ]] && use doc ; then
+		dodoc "${WORKDIR}"/*.pdf
+		dodoc -r "${WORKDIR}"/html
+	fi
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		elog
+		elog "The extract tool is now installed as csound_extract"
+		elog "due to collisions with many other packages (bug #247394)."
+		elog
+	fi
+}