From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1303069-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 12145139347
for <garchives@archives.gentoo.org>; Fri, 16 Jul 2021 08:17:36 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 346EAE09C6;
Fri, 16 Jul 2021 08:17:35 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 0A407E09C6
for <gentoo-commits@lists.gentoo.org>; Fri, 16 Jul 2021 08:17:35 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id A7D60342C38
for <gentoo-commits@lists.gentoo.org>; Fri, 16 Jul 2021 08:17:33 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 141407D6
for <gentoo-commits@lists.gentoo.org>; Fri, 16 Jul 2021 08:17:32 +0000 (UTC)
From: "Pacho Ramos" <pacho@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Pacho Ramos" <pacho@gentoo.org>
Message-ID: <1626423445.b686966f52afe43847c3756516c8577b38ddc2ca.pacho@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-fonts/noto-emoji/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-fonts/noto-emoji/Manifest media-fonts/noto-emoji/noto-emoji-20210715.ebuild
X-VCS-Directories: media-fonts/noto-emoji/
X-VCS-Committer: pacho
X-VCS-Committer-Name: Pacho Ramos
X-VCS-Revision: b686966f52afe43847c3756516c8577b38ddc2ca
X-VCS-Branch: master
Date: Fri, 16 Jul 2021 08:17:32 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 6d302eb3-20f3-4077-88b4-c51aa9afb5a7
X-Archives-Hash: 4a430ce6247e5795f073adeaa1fde971
commit: b686966f52afe43847c3756516c8577b38ddc2ca
Author: Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Fri Jul 16 08:17:25 2021 +0000
Commit: Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Fri Jul 16 08:17:25 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b686966f
media-fonts/noto-emoji: New snapshot
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>
media-fonts/noto-emoji/Manifest | 1 +
media-fonts/noto-emoji/noto-emoji-20210715.ebuild | 111 ++++++++++++++++++++++
2 files changed, 112 insertions(+)
diff --git a/media-fonts/noto-emoji/Manifest b/media-fonts/noto-emoji/Manifest
index 71a5074554f..82b5b1d989c 100644
--- a/media-fonts/noto-emoji/Manifest
+++ b/media-fonts/noto-emoji/Manifest
@@ -1 +1,2 @@
DIST noto-emoji-20201214.tar.gz 69885567 BLAKE2B 21d251a25740bf474e4c7e138c33d90f35cfea93ff2c72904e38a8bead0124408c67a731ed142fe96da07bbf8afb7d929293518a366157fd1393dacc560bf12b SHA512 b3ad1f31bbb48bd5de2fbddcac5c3f27891a805ae4ac8d0b69b07c1d7259c6a5317eca9ac7e3b068d24ed5d3acd3523cfb2036f2e9f08179b85fd81dd5c9b570
+DIST noto-emoji-20210715.tar.gz 166643705 BLAKE2B 355e993aee720e634d174fceb4d0d6b16ebce91cf948657428861fa63283120eef7fb706a5e6139f0ff7c13f0d72dc1c906ab30bc9b7509644ae6a56f4156e16 SHA512 2b1071c39d85f834baf4c9b6c59f9b06f1622bf972bac6087e0f44bd034025933b9a85a9a63a307f2e4b6337f8fbf7b11ba14838cd4bc13c8075b7ffae65ae78
diff --git a/media-fonts/noto-emoji/noto-emoji-20210715.ebuild b/media-fonts/noto-emoji/noto-emoji-20210715.ebuild
new file mode 100644
index 00000000000..309ca420b06
--- /dev/null
+++ b/media-fonts/noto-emoji/noto-emoji-20210715.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit font python-any-r1
+
+DESCRIPTION="Google Noto Emoji fonts"
+HOMEPAGE="https://www.google.com/get/noto/ https://github.com/googlefonts/noto-emoji"
+
+COMMIT="c05b4b47c8250ccd232780cae46d66a8179e77ab"
+SRC_URI="https://github.com/googlefonts/noto-emoji/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0 OFL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="buildfont"
+
+BDEPEND="
+ buildfont? (
+ ${PYTHON_DEPS}
+ app-arch/zopfli
+ $(python_gen_any_dep '
+ >=dev-python/fonttools-4.7.0[${PYTHON_USEDEP}]
+ >=dev-python/nototools-0.2.13[${PYTHON_USEDEP}]
+ ')
+ media-gfx/pngquant
+ x11-libs/cairo
+ || ( media-gfx/imagemagick[png] media-gfx/graphicsmagick[png] )
+ )
+"
+
+RESTRICT="binchecks strip"
+
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+python_check_deps() {
+ has_version -b "dev-python/fonttools[${PYTHON_USEDEP}]" &&
+ has_version -b "dev-python/nototools[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ font_pkg_setup
+}
+
+src_prepare() {
+ default
+
+ # Drop font for Windows 10
+ rm fonts/NotoColorEmoji_WindowsCompatible.ttf || die
+
+ if use buildfont; then
+ # From Fedora
+ eapply "${FILESDIR}/${PN}-build-all-flags.patch"
+
+ # https://github.com/googlei18n/noto-emoji/issues/240
+ eapply "${FILESDIR}/${PN}-20180823-build-path.patch"
+
+ # Be more verbose, bug #717654
+ eapply "${FILESDIR}"/${PN}-pngquant-verbose.patch
+ sed -i -e 's:@$(ZOPFLIPNG) -y "$<" "$@" 1> /dev/null 2>&1:@$(ZOPFLIPNG) -y "$<" "$@":g' Makefile || die
+
+ # Based on Fedora patch to allow graphicsmagick usage
+ if has_version -b media-gfx/graphicsmagick; then
+ eapply "${FILESDIR}/${PN}-20190328-use-gm.patch"
+ fi
+ fi
+}
+
+src_compile() {
+ if ! use buildfont; then
+ einfo "Installing pre-built fonts provided by upstream."
+ einfo "They could be not fully updated or miss some items."
+ einfo "To build fonts based on latest images enable 'buildfont'"
+ einfo "USE (that will require more time and resources too)."
+ else
+ python_setup
+ einfo "Building fonts..."
+
+ # From Debian:
+ # The build requires a VIRTUAL_ENV variable and sequence check isn't working
+ VIRTUAL_ENV=true \
+ BYPASS_SEQUENCE_CHECK=true \
+ default
+ fi
+}
+
+src_install() {
+ if ! use buildfont; then
+ FONT_S="${S}/fonts"
+ else
+ mv -i fonts/NotoEmoji-Regular.ttf "${S}" || die
+ # Built font and Regular font
+ FONT_S="${S}"
+
+ # Don't lose fancy emoji icons
+ for i in 32 72 128 512; do
+ insinto "/usr/share/icons/${PN}/${i}/emotes/"
+ doins png/"${i}"/*.png
+ done
+
+ insinto /usr/share/icons/"${PN}"/scalable/emotes/
+ doins svg/*.svg
+ fi
+
+ FONT_SUFFIX="ttf"
+ font_src_install
+
+ dodoc README.md
+}