From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1302992-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 23D46139345
for <garchives@archives.gentoo.org>; Fri, 16 Jul 2021 01:35:00 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id E500CE0C35;
Fri, 16 Jul 2021 01:34:58 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id B50BAE0B5E
for <gentoo-commits@lists.gentoo.org>; Fri, 16 Jul 2021 01:34:58 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 8C850342D54
for <gentoo-commits@lists.gentoo.org>; Fri, 16 Jul 2021 01:34:57 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 2C8237D8
for <gentoo-commits@lists.gentoo.org>; Fri, 16 Jul 2021 01:34:56 +0000 (UTC)
From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Sam James" <sam@gentoo.org>
Message-ID: <1626399199.fa409ed342713271b505116594c59ca32e7e12d0.sam@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-gfx/hydrus/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-gfx/hydrus/Manifest media-gfx/hydrus/hydrus-447.ebuild
X-VCS-Directories: media-gfx/hydrus/
X-VCS-Committer: sam
X-VCS-Committer-Name: Sam James
X-VCS-Revision: fa409ed342713271b505116594c59ca32e7e12d0
X-VCS-Branch: master
Date: Fri, 16 Jul 2021 01:34:56 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: d687c4e9-4309-4468-addd-6f06cf753ac3
X-Archives-Hash: 02429b2b83e6ce2e426aa2f1bc413371
commit: fa409ed342713271b505116594c59ca32e7e12d0
Author: Ekaterina Vaartis <vaartis <AT> kotobank <DOT> ch>
AuthorDate: Thu Jul 15 14:17:37 2021 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Jul 16 01:33:19 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fa409ed3
media-gfx/hydrus: Add 447
Signed-off-by: Ekaterina Vaartis <vaartis <AT> kotobank.ch>
Signed-off-by: Sam James <sam <AT> gentoo.org>
media-gfx/hydrus/Manifest | 1 +
media-gfx/hydrus/hydrus-447.ebuild | 141 +++++++++++++++++++++++++++++++++++++
2 files changed, 142 insertions(+)
diff --git a/media-gfx/hydrus/Manifest b/media-gfx/hydrus/Manifest
index 771a7ab241b..bd108a8a44d 100644
--- a/media-gfx/hydrus/Manifest
+++ b/media-gfx/hydrus/Manifest
@@ -2,3 +2,4 @@ DIST hydrus-443.tar.gz 38823767 BLAKE2B 100b2c0650d3230b1c18e58417b731bd661fecde
DIST hydrus-444.tar.gz 38817103 BLAKE2B f9eb3dc346a1a7b8d45558ee69b0b9d2a7dbbb7018734680e9953f20ebd56209cc1874213ecf5515835f1022bf571a99543154843f7dc2b9375116db8ba080a0 SHA512 f5bc28e43a5218fce15bc9d197ebcc1f4eb47856a741ad79f59d1da2413a3e7e220381a4d8208fe880fa507e023f9c03050e46ab5214ef310d105df0d85a9682
DIST hydrus-445.tar.gz 38823389 BLAKE2B 3cd07a3e30e60bd8507fd58c027e5c5a96745163bd5982198448a65b957ff8f4308c9bc0ee73b883fa275689c900dff07f497634c07f4b2f7fe579e1e3d6f378 SHA512 6735468bd531786fef9a861a81ee1e34595c362450027a0c011593465ed77dc85a304a314dcb7031e30b2e90548b2497bb4f01932dc1f04e814b7dd5ae70617c
DIST hydrus-446.tar.gz 38830223 BLAKE2B 5ab44f9cfbd15eb10144135eb4cc1d8493c20f2a931db4332a61aa186fddff96cb3a3b29eb2b210f070bb4be8210d552beb2578a7287a169a7364f02363e05f4 SHA512 bdbcd1177c3bf6ee85089e1a653587bae41c524bc2313bb5d481dee074c7da1c533a91957dc3b03d1c0b515e705809887e290ac71b866a51664f2a9a34bbfb6b
+DIST hydrus-447.tar.gz 38833157 BLAKE2B 8d7cf37a1419ef40fa7816958a01421ecc335d2a8c975fcf16d3ea5dfbdb76d872e4e597bdbade28eff7727914de5de7fb6ffcc7ecc27a712410031efa8433fe SHA512 85eaab40f192f2414be828545464811af2590b55e1a2fea7bbf64f27e4bb9a8b6c6c86cb25c1f7e9f48449173f079dcd749ea25ed22559bebb11adddce62da94
diff --git a/media-gfx/hydrus/hydrus-447.ebuild b/media-gfx/hydrus/hydrus-447.ebuild
new file mode 100644
index 00000000000..abe83ba3872
--- /dev/null
+++ b/media-gfx/hydrus/hydrus-447.ebuild
@@ -0,0 +1,141 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE="sqlite"
+
+inherit python-single-r1 desktop optfeature
+
+DESCRIPTION="A booru-like media organizer for the desktop"
+HOMEPAGE="https://hydrusnetwork.github.io/hydrus/ https://github.com/hydrusnetwork/hydrus"
+
+if [[ "${PV}" == "9999" ]]; then
+ inherit git-r3
+
+ EGIT_REPO_URI="https://github.com/hydrusnetwork/hydrus.git"
+else
+ SRC_URI="https://github.com/hydrusnetwork/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+ KEYWORDS="~amd64"
+fi
+
+# hydrus itself is WTFPL
+# icons included are CC-BY-2.5
+LICENSE="WTFPL-2 CC-BY-2.5"
+SLOT="0"
+IUSE="+mpv +ffmpeg +lz4 socks +cloudscraper charts test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ ${PYTHON_DEPS}
+ $(python_gen_cond_dep '
+ dev-python/chardet[${PYTHON_MULTI_USEDEP}]
+ dev-python/html5lib[${PYTHON_MULTI_USEDEP}]
+ dev-python/lxml[${PYTHON_MULTI_USEDEP}]
+ dev-python/numpy[${PYTHON_MULTI_USEDEP}]
+ dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+ dev-python/psutil[${PYTHON_MULTI_USEDEP}]
+ dev-python/pyopenssl[${PYTHON_MULTI_USEDEP}]
+ dev-python/pyside2[widgets,gui,charts?,${PYTHON_MULTI_USEDEP}]
+ dev-python/pyyaml[${PYTHON_MULTI_USEDEP}]
+ dev-python/requests[${PYTHON_MULTI_USEDEP}]
+ dev-python/send2trash[${PYTHON_MULTI_USEDEP}]
+ dev-python/service_identity[${PYTHON_MULTI_USEDEP}]
+ dev-python/six[${PYTHON_MULTI_USEDEP}]
+ dev-python/twisted[${PYTHON_MULTI_USEDEP}]
+ media-libs/opencv[python,png,jpeg,${PYTHON_MULTI_USEDEP}]
+
+ >=dev-python/QtPy-1.9.0-r4[pyside2,${PYTHON_MULTI_USEDEP}]
+ dev-python/beautifulsoup:4[${PYTHON_MULTI_USEDEP}]
+
+ cloudscraper? ( dev-python/cloudscraper[${PYTHON_MULTI_USEDEP}] )
+ ffmpeg? ( media-video/ffmpeg )
+ lz4? ( dev-python/lz4[${PYTHON_MULTI_USEDEP}] )
+ mpv? (
+ media-video/mpv[libmpv,${PYTHON_MULTI_USEDEP}]
+ dev-python/python-mpv[${PYTHON_MULTI_USEDEP}]
+ )
+ socks? (
+ || ( dev-python/requests[socks5,${PYTHON_MULTI_USEDEP}]
+ dev-python/PySocks[${PYTHON_MULTI_USEDEP}] )
+ )
+ ')
+"
+BDEPEND="
+ ${RDEPEND}
+ $(python_gen_cond_dep '
+ test? (
+ dev-python/httmock[${PYTHON_MULTI_USEDEP}]
+ dev-python/mock[${PYTHON_MULTI_USEDEP}]
+ dev-python/nose[${PYTHON_MULTI_USEDEP}]
+ )
+ ')
+"
+
+PATCHES=(
+ "${FILESDIR}/userpath-in-local-share.patch"
+)
+
+src_prepare() {
+ default
+
+ # Contains pre-built binaries for other systems and a broken swf renderer for linux
+ rm -r bin/ || die
+ # Build files used for CI, not actually needed
+ rm -r static/build_files || die
+ # Duplicate license file, not needed
+ rm license.txt || die
+ # Python requirements files, not needed
+ rm requirements_*.txt || die
+}
+
+src_compile() {
+ python_optimize "${S}"
+}
+
+src_test() {
+ # The tests use unittest, but are run with a custom runner script.
+ # QT_QPA_PLATFORM is required to make them run without X
+ local -x QT_QPA_PLATFORM=offscreen
+ "${EPYTHON}" "${S}/test.py" || die "Tests failed"
+}
+
+src_install() {
+ local doc="${EPREFIX}/usr/share/doc/${PF}"
+ elog "Hydrus includes an excellent manual, that can either be viewed at"
+ elog "${doc}/html/help/index.html"
+ elog "or accessed through the hydrus help menu."
+
+ mv "help my client will not boot.txt" "help_my_client_will_not_boot.txt" || die
+
+ local DOCS=(COPYING README.md Readme.txt help_my_client_will_not_boot.txt db/)
+ local HTML_DOCS=("${S}"/help/)
+ einstalldocs
+
+ # Files only needed for testing
+ rm test.py hydrus/hydrus_test.py || die
+ rm -r hydrus/test/ static/testing/ || die
+
+ # These files are copied into doc
+ rm -r "${DOCS[@]}" "${HTML_DOCS[@]}" || die
+ # The program expects to find documentation here, so add a symlink to doc
+ ln -s "${doc}/html/help" help || die
+
+ insinto /opt/hydrus
+ doins -r "${S}"/.
+
+ exeinto /usr/bin
+ python_newexe - hydrus-server < <(sed "s/python/${EPYTHON}/" "${FILESDIR}/hydrus-server")
+ python_newexe - hydrus-client < <(sed "s/python/${EPYTHON}/" "${FILESDIR}/hydrus-client")
+
+ make_desktop_entry "hydrus-client" "Hydrus Client" "/opt/hydrus/static/hydrus_non-transparent.png" \
+ "AudioVideo;FileTools;Graphics;Network;"
+}
+
+pkg_postinst() {
+ optfeature "support for automatic port forwarding" "net-libs/miniupnpc"
+}