[gentoo-commits] repo/gentoo:master commit in: sys-fs/udiskie/

["Ben Kohler" <bkohler@gentoo.org>]

commit:     7810ae331275b752a2ac6f81153a5b87eaab0190
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 14 18:18:53 2021 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Wed Jul 14 18:22:46 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7810ae33

sys-fs/udiskie: enable tests, bump to EAPI=8

Closes: https://bugs.gentoo.org/802063
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 sys-fs/udiskie/udiskie-2.3.3-r1.ebuild | 50 ++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/sys-fs/udiskie/udiskie-2.3.3-r1.ebuild b/sys-fs/udiskie/udiskie-2.3.3-r1.ebuild
new file mode 100644
index 00000000000..b03588a5d91
--- /dev/null
+++ b/sys-fs/udiskie/udiskie-2.3.3-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{7..10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="An automatic disk mounting service using udisks"
+HOMEPAGE="https://pypi.org/project/udiskie/ https://github.com/coldfix/udiskie"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE=""
+
+RDEPEND="dev-python/docopt[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	sys-fs/udisks:2"
+DEPEND="app-text/asciidoc
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:gtk-update-icon-cache:true:' setup.py || die
+	default
+
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	distutils-r1_src_compile
+	emake -C doc
+}
+
+src_install() {
+	distutils-r1_src_install
+	doman doc/${PN}.8
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}