From: "Mart Raudsepp" <leio@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/
Date: Sat, 10 Jul 2021 16:24:16 +0000 (UTC) [thread overview]
Message-ID: <1625934228.ad6708eeffaefd9555149e3223ecac8670df6ca0.leio@gentoo> (raw)
commit: ad6708eeffaefd9555149e3223ecac8670df6ca0
Author: Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 10 16:23:39 2021 +0000
Commit: Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Jul 10 16:23:48 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ad6708ee
gnome-extra/gnome-software: bump to 40.3
Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>
| 1 +
.../gnome-software/gnome-software-40.3.ebuild | 103 +++++++++++++++++++++
2 files changed, 104 insertions(+)
--git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index d0411c60091..18ff67cd362 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -1 +1,2 @@
DIST gnome-software-40.2.tar.xz 3093012 BLAKE2B 0d51e7e752b9399f79c2fc16ea12b99bb58a486fe050e38a8fd606a2afd9db32d67d14b4ed50d21da163238b30fac20f93f8947b165d8ae611c27057dd572d34 SHA512 ded29be4c59130a4016d43d3e18a67c8cf3fec4761a7a57c067bf075a6f1da5b7726000172e2303ba129b3b5cb8bd22ebfad8fbf0e3248285a4864350f3a1679
+DIST gnome-software-40.3.tar.xz 3108332 BLAKE2B 2b271db8994a252fcaf784452231585dd430b5e8363e6f2fed8e5bc0e7d1287e0cb5b22fa323a99a6f448cb23b0995ecef55b5a7675960f5dfb891cc5cb9aeae SHA512 6070f8f59fa9872282a081b6ba4f740616a799cffae43a8a541ebf4e0d7b189710dbdce679b1e5136a3fff5f8da29ec8e1ed9df7289c0a6ed697eb0ad693271f
diff --git a/gnome-extra/gnome-software/gnome-software-40.3.ebuild b/gnome-extra/gnome-software/gnome-software-40.3.ebuild
new file mode 100644
index 00000000000..b3b1497a808
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-40.3.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc packagekit spell sysprof udev"
+RESTRICT="test" # writes to and deletes files in /var/tmp/self-test/
+
+RDEPEND="
+ >=dev-libs/appstream-0.14.0:0=
+ >=x11-libs/gdk-pixbuf-2.32.0:2
+ >=dev-libs/libxmlb-0.1.7:=
+ net-libs/gnome-online-accounts:=
+ >=x11-libs/gtk+-3.22.4:3
+ >=dev-libs/glib-2.56:2
+ >=dev-libs/json-glib-1.2.0
+ >=net-libs/libsoup-2.52.0:2.4
+ >=gui-libs/libhandy-1.0.2:1=
+ sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
+ gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+ spell? ( app-text/gspell:= )
+ sys-auth/polkit
+ packagekit? ( >=app-admin/packagekit-base-1.1.0 )
+ firmware? ( >=sys-apps/fwupd-1.0.3 )
+ flatpak? (
+ >=sys-apps/flatpak-1.0.4
+ dev-util/ostree
+ )
+ udev? ( dev-libs/libgudev )
+ >=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+ dev-libs/libxml2:2
+ dev-util/gdbus-codegen
+ >=sys-devel/gettext-0.19.8
+ virtual/pkgconfig
+ gtk-doc? (
+ dev-util/gtk-doc
+ app-text/docbook-xml-dtd:4.3 )
+"
+# test? ( dev-util/valgrind )
+
+src_prepare() {
+ xdg_src_prepare
+ sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+ # We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+ sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+ # Trouble talking to spawned gnome-keyring socket for some reason, even if wrapped in dbus-run-session
+ # TODO: Investigate; seems to work outside ebuild .. test/emerge
+ sed -i -e '/g_test_add_func.*gs_auth_secret_func/d' lib/gs-self-test.c || die
+}
+
+src_configure() {
+ local emesonargs=(
+ -Dtests=false #$(meson_use test tests)
+ $(meson_use spell gspell)
+ $(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+ -Dman=true
+ $(meson_use packagekit)
+ # -Dpackagekit_autoremove
+ -Dpolkit=true
+ -Deos_updater=false # Endless OS updater
+ $(meson_use firmware fwupd)
+ $(meson_use flatpak)
+ -Dmalcontent=false
+ -Drpm_ostree=false
+ -Dodrs=false
+ $(meson_use udev gudev)
+ -Dapt=false
+ -Dsnap=false
+ -Dexternal_appstream=false
+ -Dvalgrind=false
+ $(meson_use gtk-doc gtk_doc)
+ -Dhardcoded_popular=true
+ -Ddefault_featured_apps=false # TODO: Will this be beneficial to us with flatpak at least? If enabled, it shows some apps under installed (probably merely due to /usr/share/app-info presence), but launching and removal of them is broken
+ -Dmogwai=false #TODO?
+ $(meson_feature sysprof)
+ )
+ meson_src_configure
+}
+
+#src_test() {
+# virtx meson_src_test
+#}
+
+pkg_postinst() {
+ xdg_pkg_postinst
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_pkg_postrm
+ gnome2_schemas_update
+}
next reply other threads:[~2021-07-10 16:24 UTC|newest]
Thread overview: 65+ messages / expand[flat|nested] mbox.gz Atom feed top
2021-07-10 16:24 Mart Raudsepp [this message]
-- strict thread matches above, loose matches on Subject: below --
2024-08-06 9:21 [gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-software/ Pacho Ramos
2024-08-06 9:21 Pacho Ramos
2024-06-16 7:18 Pacho Ramos
2024-06-16 7:18 Pacho Ramos
2024-06-16 7:18 Pacho Ramos
2024-01-06 15:32 Mart Raudsepp
2024-01-05 18:55 Mart Raudsepp
2024-01-05 18:55 Mart Raudsepp
2023-12-16 9:58 Pacho Ramos
2023-10-21 21:52 Mart Raudsepp
2023-09-22 2:33 Matt Turner
2023-09-15 16:52 Matt Turner
2023-09-01 15:13 Matt Turner
2023-08-08 15:25 Matt Turner
2023-08-02 14:51 Matt Turner
2023-07-07 22:03 Matt Turner
2023-06-19 15:30 Matt Turner
2023-05-26 1:44 Matt Turner
2023-05-17 7:49 Sam James
2023-04-22 3:08 Matt Turner
2023-03-16 17:42 Matt Turner
2023-03-04 1:15 Matt Turner
2023-02-20 17:32 Matt Turner
2023-02-10 19:18 Matt Turner
2023-01-18 20:22 Mart Raudsepp
2023-01-07 17:42 Matt Turner
2022-12-02 14:35 Matt Turner
2022-10-30 22:29 Matt Turner
2022-10-25 15:25 Matt Turner
2022-08-05 20:49 Matt Turner
2022-07-02 2:53 Matt Turner
2022-05-30 18:22 Matt Turner
2022-04-28 15:31 Matt Turner
2022-04-24 22:45 Matt Turner
2022-02-19 23:55 Matt Turner
2021-08-13 16:34 Mart Raudsepp
2021-06-13 20:25 Sam James
2021-06-06 21:49 Matt Turner
2021-06-06 21:49 Matt Turner
2021-05-01 2:59 Matt Turner
2021-04-18 4:21 Matt Turner
2020-11-27 12:19 David Seifert
2020-07-12 21:32 Mart Raudsepp
2020-04-18 7:37 Mart Raudsepp
2020-04-04 20:48 Mart Raudsepp
2020-02-19 22:01 Mart Raudsepp
2019-07-28 17:41 Mart Raudsepp
2019-03-30 22:50 Mart Raudsepp
2019-03-22 12:20 Mart Raudsepp
2019-03-22 12:20 Mart Raudsepp
2018-12-11 13:07 Gilles Dartiguelongue
2017-08-26 10:07 Gilles Dartiguelongue
2017-08-12 9:42 Gilles Dartiguelongue
2017-03-23 6:54 Mart Raudsepp
2017-01-04 22:37 Gilles Dartiguelongue
2017-01-04 22:37 Gilles Dartiguelongue
2016-11-12 12:23 Gilles Dartiguelongue
2016-10-24 7:22 Gilles Dartiguelongue
2016-10-24 7:22 Gilles Dartiguelongue
2016-10-08 9:51 Pacho Ramos
2016-10-08 9:51 Pacho Ramos
2016-10-08 9:51 Pacho Ramos
2016-09-06 22:10 Gilles Dartiguelongue
2016-01-03 13:32 Gilles Dartiguelongue
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1625934228.ad6708eeffaefd9555149e3223ecac8670df6ca0.leio@gentoo \
--to=leio@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox