[gentoo-commits] repo/gentoo:master commit in: app-editors/pluma/

["Adam Feldman" <np-hardass@gentoo.org>]

commit:     e468cb3c256ea2431f74a20d093364893350778e
Author:     Adam Feldman <NP-Hardass <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 10 15:21:23 2021 +0000
Commit:     Adam Feldman <np-hardass <AT> gentoo <DOT> org>
CommitDate: Wed Jun 30 22:41:51 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e468cb3c

app-editors/pluma: Bump to 1.24.2

Bug: https://bugs.gentoo.org/778857
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Adam Feldman <NP-Hardass <AT> gentoo.org>

 app-editors/pluma/Manifest            |  1 +
 app-editors/pluma/pluma-1.24.2.ebuild | 81 +++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)

diff --git a/app-editors/pluma/Manifest b/app-editors/pluma/Manifest
index 106b02fab9a..6a160fe74bb 100644
--- a/app-editors/pluma/Manifest
+++ b/app-editors/pluma/Manifest
@@ -1 +1,2 @@
 DIST pluma-1.24.1.tar.xz 3679636 BLAKE2B e792433b93862c8b0c47145255311c3a3386c1b99ec1ac87ed91608d839ece4430205f83fcc3c0f5145f986105d4c5d8803393035fcaaea08155197bbcf15d03 SHA512 0cfd6a035fc95993dce3e556c49641e799888f20159b29f2c0712c54ee772aa6df1ce755f329414c94efdb2cb3819ce633b92e6559b0c8cb064dab3c74729ab3
+DIST pluma-1.24.2.tar.xz 3745160 BLAKE2B ed855b19f1ab80cb6ef9bc175eea3c2af386b1e45123bc0e3ad93d1964efb4822fe1b3d7490308357fcff96557bb6189f081a467f41a6907e76a1961de8f23d3 SHA512 588640744f8a0bec08d0c51c0309380a57cb6319c98124885e30d05e7dd8488ba7bd5acec1bf21fb0d6832626ae8925b24cd241202265af1a631a91313cdad2b

diff --git a/app-editors/pluma/pluma-1.24.2.ebuild b/app-editors/pluma/pluma-1.24.2.ebuild
new file mode 100644
index 00000000000..061436117e9
--- /dev/null
+++ b/app-editors/pluma/pluma-1.24.2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+MATE_LA_PUNT="yes"
+
+PYTHON_COMPAT=( python{3_6,3_7,3_8} )
+
+inherit mate python-single-r1 virtualx
+
+if [[ ${PV} != 9999 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Pluma text editor for the MATE desktop"
+LICENSE="FDL-1.1+ GPL-2+ LGPL-2+"
+SLOT="0"
+
+IUSE="+introspection spell test"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Tests require gvfs sftp fs mounted and schema's installed. Disable tests.
+# https://github.com/mate-desktop/mate-text-editor/issues/33
+RESTRICT="test"
+
+COMMON_DEPEND="dev-libs/atk
+	>=dev-libs/glib-2.50:2
+	>=dev-libs/libpeas-1.2.0[gtk]
+	>=dev-libs/libxml2-2.5:2
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	>=x11-libs/gtksourceview-3.0.0:3.0
+	x11-libs/libICE
+	x11-libs/libX11
+	>=x11-libs/libSM-1.0
+	x11-libs/pango
+	introspection? ( >=dev-libs/gobject-introspection-0.9.3:= )
+	spell? (
+		>=app-text/enchant-1.6:=
+		>=app-text/iso-codes-0.35
+	)
+	!!app-editors/mate-text-editor
+"
+
+RDEPEND="${PYTHON_DEPS}
+	${COMMON_DEPEND}
+	>=mate-base/mate-desktop-1.9[introspection?]
+	virtual/libintl
+"
+
+DEPEND="${COMMON_DEPEND}
+	~app-text/docbook-xml-dtd-4.1.2
+	app-text/rarian
+	>=app-text/scrollkeeper-dtd-1:1.0
+	app-text/yelp-tools
+	dev-util/glib-utils
+	dev-util/gtk-doc
+	dev-util/gtk-doc-am
+	>=sys-devel/libtool-2.2.6:2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	mate_src_configure \
+		$(use_enable introspection) \
+		$(use_enable spell) \
+		$(use_enable test tests)
+}
+
+src_test() {
+	# FIXME: This should be handled at eclass level.
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+
+	unset DBUS_SESSION_BUS_ADDRESS
+
+	GSETTINGS_SCHEMA_DIR="${S}/data" Xemake check
+}