[gentoo-commits] repo/gentoo:master commit in: www-misc/buku/

["John Helmert III" <ajak@gentoo.org>]

commit:     079f435563a6c7560f67b1110548d968c280b0c9
Author:     John Helmert III <ajak <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 17 22:34:43 2021 +0000
Commit:     John Helmert III <ajak <AT> gentoo <DOT> org>
CommitDate: Thu Jun 17 22:35:09 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=079f4355

www-misc/buku: add 4.6

Signed-off-by: John Helmert III <ajak <AT> gentoo.org>

 www-misc/buku/Manifest        |  1 +
 www-misc/buku/buku-4.6.ebuild | 95 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)

diff --git a/www-misc/buku/Manifest b/www-misc/buku/Manifest
index ea27579d575..128a7832af2 100644
--- a/www-misc/buku/Manifest
+++ b/www-misc/buku/Manifest
@@ -1 +1,2 @@
 DIST buku-4.5.tar.gz 488913 BLAKE2B 29ed93fa9af4503f72a711889fbf17d86bcde1bc1abbfc88242c4ebd18f1c1a57077781eebdd79d9d993078d2f5b5883c9a0ec4fee94e37c0e7bfb727c5154d0 SHA512 7bbb598d5c970e8e594d58c0a18f9b85245d4a214c01d64b537a5ccaadab32c964521046b90754c2f2c721bf816dc7f4438cfeff3a7e7eec75ce958cc41dfa7d
+DIST buku-4.6.tar.gz 491809 BLAKE2B 82597b845c56dadf1cc6973d1f3ce6cc4970230d08ac700cf286a8c41420144fb1f42817ab808041600ab8414d96f3a3883c1bd8fbe89f29570d877a495dcd96 SHA512 1c46006d8c950811493a8c11453d51557cac3f6346ea28d66dcb2ae3e4c52727af7349b4b6ea088f9c08a7e9d09e3a4d80679b41497b6cd0844d811f81c9811a

diff --git a/www-misc/buku/buku-4.6.ebuild b/www-misc/buku/buku-4.6.ebuild
new file mode 100644
index 00000000000..d7dd628bd78
--- /dev/null
+++ b/www-misc/buku/buku-4.6.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Powerful command-line bookmark manager"
+HOMEPAGE="https://github.com/jarun/buku"
+SRC_URI="https://github.com/jarun/${PN}/archive/v$(ver_cut 1-2).tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/beautifulsoup-4.6.0[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.0.1[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		>=dev-python/click-7.0[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/py-1.5.0[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-4.2[${PYTHON_USEDEP}]
+		>=dev-python/vcrpy-4.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	#"${FILESDIR}/${P}-hypothesis-fix.patch"
+)
+
+python_prepare_all() {
+	# Remove support for bukuserver - complex depgraph which isn't all
+	# sufficiently packaged in Gentoo
+	sed -ie '/console_scripts/s/,.*/]/' setup.py || die
+	sed -ie 's/.*bukuserver.*//' tests/test_views.py || die
+	sed -ie 's/.*flask.*//' tests/test_views.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /usr/share/zsh/site-functions
+	doins auto-completion/zsh/_*
+
+	newbashcomp auto-completion/bash/buku-completion.bash "${PN}"
+
+	doman buku.1
+}
+
+python_test() {
+	local skipped_tests=(
+		# Disable tests related to bukuserver
+		tests/test_setup.py::test_bukuserver_requirement
+		tests/test_views.py::test_bmv_create_form
+		tests/test_views.py::test_bookmark_model_view
+		tests/test_views.py::test_load_firefox_database
+		tests/test_views.py::test_tag_model_view_get_list
+		tests/test_views.py::test_tag_model_view_get_list_empty_db
+
+		# Broken with network-sandbox
+		tests/test_buku.py::test_network_handler_with_url
+		tests/test_bukuDb.py::TestBukuDb::test_tnyfy_url
+		tests/test_bukuDb.py::test_add_rec_exec_arg
+		tests/test_bukuDb.py::test_load_firefox
+		tests/test_bukuDb.py::test_print_db
+		tests/test_bukuDb.py::test_print_rec
+		tests/test_bukuDb.py::test_refreshdb
+
+		# Hard to debug sandbox issue - these pass when run outside portage
+		# There also appears to be some state issue between these, because
+		# skipping one can result in a later one failing.
+		tests/test_bukuDb.py::test_delete_rec_index_and_delay_commit[1-True-False]
+		tests/test_bukuDb.py::test_delete_rec_index_and_delay_commit[1-False-True]
+		tests/test_bukuDb.py::test_delete_rec_index_and_delay_commit[1-False-False]
+		tests/test_bukuDb.py::test_delete_rec_index_and_delay_commit[1-True-True]
+	)
+
+	# tests/test_server.py is bukuserver tests, ignore it
+	pytest -v --ignore tests/test_server.py ${skipped_tests[@]/#/--deselect } || die "Tests failed with ${EPYTHON}"
+}