From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1291043-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id BA0AE1382C5
for <garchives@archives.gentoo.org>; Sun, 6 Jun 2021 21:49:30 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id B79C5E0869;
Sun, 6 Jun 2021 21:49:29 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 89DBBE0869
for <gentoo-commits@lists.gentoo.org>; Sun, 6 Jun 2021 21:49:29 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 6C1F0340CDF
for <gentoo-commits@lists.gentoo.org>; Sun, 6 Jun 2021 21:49:28 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id BEF487A4
for <gentoo-commits@lists.gentoo.org>; Sun, 6 Jun 2021 21:49:26 +0000 (UTC)
From: "Matt Turner" <mattst88@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Matt Turner" <mattst88@gentoo.org>
Message-ID: <1623016149.eb38eb83aee373d7f01afa74dda08c2c68c59744.mattst88@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: gnome-extra/evolution-data-server/
X-VCS-Repository: repo/gentoo
X-VCS-Files: gnome-extra/evolution-data-server/Manifest gnome-extra/evolution-data-server/evolution-data-server-3.40.2.ebuild
X-VCS-Directories: gnome-extra/evolution-data-server/
X-VCS-Committer: mattst88
X-VCS-Committer-Name: Matt Turner
X-VCS-Revision: eb38eb83aee373d7f01afa74dda08c2c68c59744
X-VCS-Branch: master
Date: Sun, 6 Jun 2021 21:49:26 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 24543eb7-ff0a-4743-a15f-7bc9f30b8a21
X-Archives-Hash: 229bb02befb5f45745be9d995de8d1f9
commit: eb38eb83aee373d7f01afa74dda08c2c68c59744
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Jun 6 21:12:46 2021 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Jun 6 21:49:09 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=eb38eb83
gnome-extra/evolution-data-server: Version bump to 3.40.2
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
gnome-extra/evolution-data-server/Manifest | 1 +
.../evolution-data-server-3.40.2.ebuild | 152 +++++++++++++++++++++
2 files changed, 153 insertions(+)
diff --git a/gnome-extra/evolution-data-server/Manifest b/gnome-extra/evolution-data-server/Manifest
index 1a82aca1079..8c6e27ed8af 100644
--- a/gnome-extra/evolution-data-server/Manifest
+++ b/gnome-extra/evolution-data-server/Manifest
@@ -1 +1,2 @@
DIST evolution-data-server-3.40.1.tar.xz 4625316 BLAKE2B d795183d07bc7b58a00e3c6f60d3704cf7e0cc6237b079c49f2e21dd7c22098c2b7b3fd2ca50fd3d9268aff8e5eaeea2e0e6c65d09c8bd68b7364445eb926c7c SHA512 47964a0965d412c329743423483c6694d078835b375d457aabe7e45a2b1b3406e4e0d4c1b855460f3c9b327d4d9320e659b0e43243816ec1e9bc49d0fea90f7d
+DIST evolution-data-server-3.40.2.tar.xz 4625240 BLAKE2B f7c966e0e092ce46157e55d1a096e5ce69ae5103c0d777f262b62cac4185bec88c4cf84b9da4927cd8e008310f09bedcc017cb4ec39e4c90b3a36c1444b3507c SHA512 495e264cc92b31e6bb76b205641f4c030e82a010f0cf58f712d5c05b5a06f0a60c5b83b31f95ececf9e553f2e816bb9bab2df54cd9982a81eb2bb7f936016639
diff --git a/gnome-extra/evolution-data-server/evolution-data-server-3.40.2.ebuild b/gnome-extra/evolution-data-server/evolution-data-server-3.40.2.ebuild
new file mode 100644
index 00000000000..02f51c3698c
--- /dev/null
+++ b/gnome-extra/evolution-data-server/evolution-data-server-3.40.2.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit cmake db-use flag-o-matic gnome2 systemd vala virtualx
+
+DESCRIPTION="Evolution groupware backend"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
+
+# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
+LICENSE="|| ( LGPL-2 LGPL-3 ) BSD Sleepycat"
+SLOT="0/62-26-20" # subslot = libcamel-1.2/libedataserver-1.2/libebook-1.2.so soname version
+
+IUSE="berkdb +gnome-online-accounts +gtk gtk-doc +introspection ipv6 ldap kerberos oauth vala +weather"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+# gdata-0.17.7 soft required for new gdata_feed_get_next_page_token API to handle more than 100 google tasks
+# berkdb needed only for migrating old addressbook data from <3.13 versions, bug #519512
+gdata_depend=">=dev-libs/libgdata-0.17.7:=[vala?]"
+RDEPEND="
+ >=app-crypt/gcr-3.4
+ >=app-crypt/libsecret-0.5[crypt]
+ >=dev-db/sqlite-3.7.17:=
+ >=dev-libs/glib-2.46:2
+ >=dev-libs/libical-3.0.8:=[glib,introspection?]
+ >=dev-libs/libxml2-2
+ >=dev-libs/nspr-4.4:=
+ >=dev-libs/nss-3.9:=
+ >=net-libs/libsoup-2.58:2.4
+
+ dev-libs/icu:=
+ sys-libs/zlib:=
+ virtual/libiconv
+
+ berkdb? ( >=sys-libs/db-4:= )
+ gtk? (
+ >=app-crypt/gcr-3.4[gtk]
+ >=x11-libs/gtk+-3.16:3
+ >=media-libs/libcanberra-0.25[gtk3]
+ )
+ oauth? (
+ >=dev-libs/json-glib-1.0.4
+ >=net-libs/webkit-gtk-2.28.0:4
+ ${gdata_depend}
+ )
+ gnome-online-accounts? (
+ >=net-libs/gnome-online-accounts-3.8:=
+ ${gdata_depend} )
+ introspection? ( >=dev-libs/gobject-introspection-0.9.12:= )
+ kerberos? ( virtual/krb5:= )
+ ldap? ( >=net-nds/openldap-2:= )
+ weather? ( >=dev-libs/libgweather-3.10:2= )
+"
+DEPEND="${RDEPEND}
+ vala? ( $(vala_depend)
+ net-libs/libsoup:2.4[vala]
+ dev-libs/libical[vala]
+ )
+"
+BDEPEND="
+ dev-util/gdbus-codegen
+ dev-util/glib-utils
+ dev-util/gperf
+ gtk-doc? ( >=dev-util/gtk-doc-1.14
+ app-text/docbook-xml-dtd:4.1.2 )
+ >=dev-util/intltool-0.35.5
+ >=sys-devel/gettext-0.18.3
+ virtual/pkgconfig
+"
+
+# Some tests fail due to missing locales.
+# Also, dbus tests are flaky, bugs #397975 #501834
+# It looks like a nightmare to disable those for now.
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare call
+src_prepare() {
+ use vala && vala_src_prepare
+ cmake_src_prepare
+ gnome2_src_prepare
+
+ eapply "${FILESDIR}"/3.36.5-gtk-doc-1.32-compat.patch
+
+ # Make CMakeLists versioned vala enabled
+ sed -e "s;\(find_program(VALAC\) valac);\1 ${VALAC});" \
+ -e "s;\(find_program(VAPIGEN\) vapigen);\1 ${VAPIGEN});" \
+ -i "${S}"/CMakeLists.txt || die
+}
+
+src_configure() {
+ # /usr/include/db.h is always db-1 on FreeBSD
+ # so include the right dir in CPPFLAGS
+ use berkdb && append-cppflags "-I$(db_includedir)"
+
+ local google_enable
+ if use oauth || use gnome-online-accounts; then
+ google_enable="ON"
+ else
+ google_enable="OFF"
+ fi
+
+ # phonenumber does not exist in tree
+ local mycmakeargs=(
+ -DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+ -DENABLE_GTK_DOC=$(usex gtk-doc)
+ -DWITH_PRIVATE_DOCS=$(usex gtk-doc)
+ -DENABLE_SCHEMAS_COMPILE=OFF
+ -DENABLE_INTROSPECTION=$(usex introspection)
+ -DWITH_KRB5=$(usex kerberos)
+ -DWITH_KRB5_INCLUDES=$(usex kerberos "${EPREFIX}"/usr "")
+ -DWITH_KRB5_LIBS=$(usex kerberos "${EPREFIX}"/usr/$(get_libdir) "")
+ -DWITH_OPENLDAP=$(usex ldap)
+ -DWITH_PHONENUMBER=OFF
+ -DENABLE_SMIME=ON
+ -DENABLE_GTK=$(usex gtk)
+ -DENABLE_CANBERRA=$(usex gtk)
+ -DENABLE_OAUTH2=$(usex oauth)
+ -DENABLE_EXAMPLES=OFF
+ -DENABLE_GOA=$(usex gnome-online-accounts)
+ -DWITH_LIBDB=$(usex berkdb "${EPREFIX}"/usr OFF)
+ # ENABLE_BACKTRACES requires libdwarf ?
+ -DENABLE_IPV6=$(usex ipv6)
+ -DENABLE_WEATHER=$(usex weather)
+ -DENABLE_GOOGLE=${google_enable}
+ -DENABLE_LARGEFILE=ON
+ -DENABLE_VALA_BINDINGS=$(usex vala)
+ )
+
+ cmake_src_configure
+}
+
+src_compile() {
+ cmake_src_compile
+}
+
+src_test() {
+ virtx cmake_src_test
+}
+
+src_install() {
+ cmake_src_install
+
+ if use ldap; then
+ insinto /etc/openldap/schema
+ doins "${FILESDIR}"/calentry.schema
+ dosym ../../../usr/share/${PN}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
+ fi
+}