[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

["Michał Górny" <mgorny@gentoo.org>]

commit:     ceb29fadc2088e434c3a8cbc62ffc7275d763543
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jun  2 22:41:58 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jun  2 23:14:05 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ceb29fad

dev-python/django: Bump to 3.1.12

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest             |  2 +
 dev-python/django/django-3.1.12.ebuild | 95 ++++++++++++++++++++++++++++++++++
 2 files changed, 97 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 8b2555adb9f..89bd424103d 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -6,6 +6,8 @@ DIST Django-3.1.10.checksum.txt 2551 BLAKE2B 811e820ef036301ee1a6aafb2f74e5809ba
 DIST Django-3.1.10.tar.gz 9654073 BLAKE2B c3729b7007b0b8309fda111f7bd988c861fb1002da3683e972a01bcd2aecfc6b42e896f91297239cba2061106096226552c26eb50325ea5b50f5a5df3a191bfd SHA512 6dd3c7a5cd1b5cbeb6e62f72fa56fce260bd407a3ac659ddee893489efae7a6bea862ecc113da342a2ed4cffa39e564c55dd20792b5435f9f00fef5488579aad
 DIST Django-3.1.11.checksum.txt 2552 BLAKE2B 11c8f9c26491dce2897e302e2ff92cfb8e481dcf93c46e91f1005a9ad92bfdc60e4e69682c94999f2e1fe37cf57ba452e03748862919d2f6afdb9c77c9ae1049 SHA512 8cee919d2a4d6b55dd1c6d91ad999caff0e7efe9a0d8c2a92e70d1fb51a534d924ac47fffd1a28b92e8060225c1fd7fda2bd693b977b29bed8f4ffe8a7f18041
 DIST Django-3.1.11.tar.gz 9654094 BLAKE2B 00e4ba95127d49b410cf0811e54fee5e5d17647a782ac6ffd30339ec81455479d913f62a29d83e7c87773cc81635393202a3065d3d0262cd17a033c7637fda76 SHA512 8da05ea46e4fdf20a90aadc954a9cf9e7e830e3822ff9095bd973628e74fa14e5397365740fcb5d76d393f2e5b39fdc578b3d7f12601feb9a3b3e057e6bbe086
+DIST Django-3.1.12.checksum.txt 2558 BLAKE2B fe31c76517811b5a69bbab6a44966059b40e26e81134682a56753fb886abb1081ad998628fb45eb9959fa1b625c1ffc7128ed0153aadde23319ca28daedf71ca SHA512 6b5a243eee10a33721725be4f09b34395f0d7b34775c72b387d47445947de25f927b2b6d3bc6d76896096b8d06080ebd66ad3a667984087b7c3505a705ec8f76
+DIST Django-3.1.12.tar.gz 9676259 BLAKE2B 91781b77b63591a9fc1dffbe341b5400898ccce6267b18236f8680e86f02bb70cc4ab3297fb504e5a809947bd7e68795286b875f319a60ad501d38f4af1f17a7 SHA512 7b58d0bd6ccd6a3222bd58e87ee26646e75b807f284cb259baa5442514c249b3d7695ed0c61e5cc544e121d06a102c5ea1b40694d17e7d4dd3a8437891284c0a
 DIST Django-3.2.2.checksum.txt 2542 BLAKE2B 1a61ea4e8415d77b50d0dc227905596941a9cfed019c3442be1d7529d0b82204b08e15befdcccccd3a7a4625b762e99526b762053e9ec7c29068caa2dfe055a1 SHA512 eebb6e7172d85af3d6f65296d816f40cacd78c8270bd198d275c3c2844e9106ec517265490e7371d5df803d044ee1534a4eb836d2a279d395884c1ec7b9cb0f5
 DIST Django-3.2.2.tar.gz 9796920 BLAKE2B 09a720d169702f1d80b592e8a4c8e136b9b3c4539db44f8bcf3ef7d0e6bb678892b7ad4bbeac89fc887c9938cb35d8a9d3fee9a58e692f99c37e81f01615a6b4 SHA512 28d1d56cdf883f8fb5e438124be53dbefaa0045d1acf0b4b8b455a482422e2b88ffc5a3c8be2ee1b7d3c39fe29cfa854b44b438c3d43323483bd35e0d05f9e49
 DIST Django-3.2.3.checksum.txt 2543 BLAKE2B e15fd98b887e3e416d6636a84cfe08e23d920c3044c0382ff0821b47dced378fb89d05bd0e128b1237423be72ccdd1454f4a092b543f2325e1d3d1072e508ccf SHA512 7c898155e085f003dd9872cf266484d4d533d869df18aa5c431ca6bf9dee2682ef61921e3f31e43392c0539d2175a8000a37f371519ae485b38bda0eede54c67

diff --git a/dev-python/django/django-3.1.12.ebuild b/dev-python/django/django-3.1.12.ebuild
new file mode 100644
index 00000000000..e41026d4772
--- /dev/null
+++ b/dev-python/django/django-3.1.12.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( >=app-crypt/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}