From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1289025-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id B170413835A
for <garchives@archives.gentoo.org>; Tue, 1 Jun 2021 20:35:44 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id C0A65E0839;
Tue, 1 Jun 2021 20:35:43 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 9D31FE0833
for <gentoo-commits@lists.gentoo.org>; Tue, 1 Jun 2021 20:35:43 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 8B30D340FB1
for <gentoo-commits@lists.gentoo.org>; Tue, 1 Jun 2021 20:35:42 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id D15CB4A0
for <gentoo-commits@lists.gentoo.org>; Tue, 1 Jun 2021 20:35:40 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1622579729.d8bf2b3ce58d7fa5b6b74c25c04fcfc9dace2260.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-wireless/blueman/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-wireless/blueman/Manifest net-wireless/blueman/blueman-2.2.1.ebuild
X-VCS-Directories: net-wireless/blueman/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: d8bf2b3ce58d7fa5b6b74c25c04fcfc9dace2260
X-VCS-Branch: master
Date: Tue, 1 Jun 2021 20:35:40 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: bf7069ae-1cb0-4188-a2da-62f2699533d1
X-Archives-Hash: 635385602b2a5160b057f53841e468e2
commit: d8bf2b3ce58d7fa5b6b74c25c04fcfc9dace2260
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Jun 1 09:31:58 2021 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Jun 1 20:35:29 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d8bf2b3c
net-wireless/blueman: Bump to 2.2.1
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
net-wireless/blueman/Manifest | 1 +
net-wireless/blueman/blueman-2.2.1.ebuild | 131 ++++++++++++++++++++++++++++++
2 files changed, 132 insertions(+)
diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index 7c13bbcf6d8..c9cafe4c742 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1 +1,2 @@
DIST blueman-2.1.4.tar.xz 983816 BLAKE2B de8d475b0aec5b037df43fdb76ebbf4fdb05367f166c14cda818badf49376f2a91de246f991167a57ecaa82a84ac84b4e91f600237c35d86e27431a760192996 SHA512 b8b54942092c1984cfac0cf73e2ac23f7693cb3ee0aa4cfaab1fa0282de4afd539f6860d5541523b542956b2efa31da3ec012dcc39d92fd699d0b8479df641ff
+DIST blueman-2.2.1.tar.xz 1570992 BLAKE2B b6d2296b68990c25e6d8077b513ebd3915152522fdf66bb5d887a90cf98e8835d993caf89a93089947ff1f6470075b9b6643ee0169ba86e46d190c09fbc6942a SHA512 7668a68470e7b5ab8e5cd774c89a7ae347de4193e293b5f2a467407fcb625e07a482f986fd7b672b763c297a0c0692c1da53dcc4ae75ec7fa118b180be623104
diff --git a/net-wireless/blueman/blueman-2.2.1.ebuild b/net-wireless/blueman/blueman-2.2.1.ebuild
new file mode 100644
index 00000000000..5d3ff61c631
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.2.1.ebuild
@@ -0,0 +1,131 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{7..9} )
+inherit autotools gnome2-utils linux-info python-single-r1 systemd xdg-utils
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman"
+
+if [[ ${PV} == "9999" ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/blueman-project/blueman.git"
+else
+ SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV/_/.}/${P/_/.}.tar.xz"
+ S=${WORKDIR}/${P/_/.}
+ KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+# icons are GPL-2
+# source files are mixed GPL-3+ and GPL-2+
+LICENSE="GPL-3+ GPL-2"
+SLOT="0"
+IUSE="appindicator network nls policykit pulseaudio"
+
+DEPEND="
+ $(python_gen_cond_dep '
+ dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+ ')
+ >=net-wireless/bluez-5:=
+ ${PYTHON_DEPS}"
+BDEPEND="
+ $(python_gen_cond_dep '
+ dev-python/cython[${PYTHON_MULTI_USEDEP}]
+ ')
+ virtual/pkgconfig
+ nls? ( dev-util/intltool sys-devel/gettext )"
+RDEPEND="${DEPEND}
+ $(python_gen_cond_dep '
+ dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+ ')
+ sys-apps/dbus
+ x11-libs/gtk+:3[introspection]
+ x11-libs/libnotify[introspection]
+ || (
+ x11-themes/adwaita-icon-theme
+ x11-themes/faenza-icon-theme
+ x11-themes/mate-icon-theme
+ )
+ appindicator? ( dev-libs/libappindicator:3[introspection] )
+ network? (
+ net-firewall/iptables
+ || (
+ sys-apps/net-tools
+ sys-apps/iproute2
+ )
+ || (
+ net-dns/dnsmasq
+ net-misc/dhcp
+ >=net-misc/networkmanager-0.8
+ )
+ )
+ policykit? ( sys-auth/polkit )
+ pulseaudio? (
+ || (
+ media-sound/pulseaudio[bluetooth]
+ media-sound/pulseaudio-modules-bt
+ )
+ )
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_pretend() {
+ if use network; then
+ local CONFIG_CHECK="~BRIDGE ~IP_NF_IPTABLES
+ ~IP_NF_NAT ~IP_NF_TARGET_MASQUERADE"
+ check_extra_config
+ fi
+}
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+ # replace py-compile to fix py3
+ [[ ${PV} == 9999 ]] && eautoreconf || eautomake
+}
+
+src_configure() {
+ local myconf=(
+ --disable-runtime-deps-check
+ --disable-static
+ --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
+ --with-systemduserunitdir="$(systemd_get_userunitdir)"
+ --with-dhcp-config="/etc/dhcp/dhcpd.conf"
+ $(use_enable appindicator)
+ $(use_enable policykit polkit)
+ $(use_enable nls)
+ $(use_enable pulseaudio)
+ # thunar integration is a single data file with no extra deps
+ # so install it unconditionally
+ --enable-thunar-sendto
+ )
+ econf "${myconf[@]}"
+}
+
+src_install() {
+ default
+
+ if use policykit; then
+ # Allow users in plugdev group to modify connections
+ insinto /usr/share/polkit-1/rules.d
+ doins "${FILESDIR}/01-org.blueman.rules"
+ fi
+
+ find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}
+
+pkg_postrm() {
+ xdg_icon_cache_update
+ gnome2_schemas_update
+}