[gentoo-commits] repo/gentoo:master commit in: dev-python/apsw/

["Michał Górny" <mgorny@gentoo.org>]

commit:     4bd082dcbaa5201a00383fd0e679f6b4c03f203d
Author:     Zamarin Arthur <arthurzam <AT> gmail <DOT> com>
AuthorDate: Sat May 22 17:53:15 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun May 30 16:59:26 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4bd082dc

dev-python/apsw: add 3.35.4_p1, bump to python 3.10

fix direct CC call
passes tests

Closes: https://bugs.gentoo.org/704606
Closes: https://bugs.gentoo.org/723726
Signed-off-by: Zamarin Arthur <arthurzam <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/20936
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/apsw/Manifest              |  1 +
 dev-python/apsw/apsw-3.35.4_p1.ebuild | 46 +++++++++++++++++++++++++++++++++++
 2 files changed, 47 insertions(+)

diff --git a/dev-python/apsw/Manifest b/dev-python/apsw/Manifest
index 69937f18959..a1fb0606925 100644
--- a/dev-python/apsw/Manifest
+++ b/dev-python/apsw/Manifest
@@ -1 +1,2 @@
 DIST apsw-3.32.2_p1.zip 679785 BLAKE2B fb58a60f95a677a805b0347a0d8876e49c657092deeadb60a057f4afc62031313faf5a86b600d1d306e42f305c9af599d2439a7051e400cbba2d9185c213d5d1 SHA512 718de699c43eec139747f63c3c26da206aa20f104ec1c478009d29cedff7a432138726131b2458ecd3a67675254af77e94e50e8e96a208600fe2a94aa9d924c7
+DIST apsw-3.35.4_p1.zip 685034 BLAKE2B 5845e5fcb286c587367955c33fbee9aa4b0687af666f1d50f35f5dec8e756a0fbcf0fdbd120dd3c7a78df1f05d8eae5a973a8a71fc8a6f4271fff7d83b399013 SHA512 f420560e5821bd6305705ee6c14174f1770f4811edcfe152cb1f2ceae4295f13c82552386a7ef42c5ce88165e88bd2080b4dc2809484598522914d99f2469135

diff --git a/dev-python/apsw/apsw-3.35.4_p1.ebuild b/dev-python/apsw/apsw-3.35.4_p1.ebuild
new file mode 100644
index 00000000000..9c4c56abd92
--- /dev/null
+++ b/dev-python/apsw/apsw-3.35.4_p1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit distutils-r1
+
+MY_PV=${PV/_p/-r}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="APSW - Another Python SQLite Wrapper"
+HOMEPAGE="https://github.com/rogerbinns/apsw/"
+SRC_URI="https://github.com/rogerbinns/apsw/releases/download/${MY_PV}/${MY_P}.zip -> ${P}.zip"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+IUSE="doc"
+
+RDEPEND=">=dev-db/sqlite-${PV%_p*}"
+DEPEND="${RDEPEND}"
+BDEPEND="app-arch/unzip"
+
+PATCHES=( "${FILESDIR}/${PN}-3.6.20.1-fix_tests.patch" )
+
+python_prepare_all() {
+	sed -e 's/"gcc/os.environ.get("CC", "gcc") + "/' -i setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile --enable=load_extension
+}
+
+python_test() {
+	esetup.py build_test_extension
+	"${EPYTHON}" tests.py -v || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/. )
+	distutils-r1_python_install_all
+}