From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1283383-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 504FA1382C5
for <garchives@archives.gentoo.org>; Mon, 17 May 2021 22:25:07 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 9DB3CE0821;
Mon, 17 May 2021 22:25:06 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 775F2E0821
for <gentoo-commits@lists.gentoo.org>; Mon, 17 May 2021 22:25:06 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id BA57B335CC1
for <gentoo-commits@lists.gentoo.org>; Mon, 17 May 2021 22:25:04 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 746C5632
for <gentoo-commits@lists.gentoo.org>; Mon, 17 May 2021 22:25:03 +0000 (UTC)
From: "Sam James" <sam@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Sam James" <sam@gentoo.org>
Message-ID: <1621290291.9ca12402d402ccae0d6968c586c224847dd1b09d.sam@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: sci-geosciences/qgis/
X-VCS-Repository: repo/gentoo
X-VCS-Files: sci-geosciences/qgis/Manifest sci-geosciences/qgis/qgis-3.18.3.ebuild
X-VCS-Directories: sci-geosciences/qgis/
X-VCS-Committer: sam
X-VCS-Committer-Name: Sam James
X-VCS-Revision: 9ca12402d402ccae0d6968c586c224847dd1b09d
X-VCS-Branch: master
Date: Mon, 17 May 2021 22:25:03 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: aabf52a2-4d7d-49b0-8df9-ce48ab18effd
X-Archives-Hash: a4433a407fd15446771249ec3795d7c3
commit: 9ca12402d402ccae0d6968c586c224847dd1b09d
Author: Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Mon May 17 22:24:51 2021 +0000
Commit: Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon May 17 22:24:51 2021 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9ca12402
sci-geosciences/qgis: add 3.18.3
Signed-off-by: Sam James <sam <AT> gentoo.org>
sci-geosciences/qgis/Manifest | 1 +
sci-geosciences/qgis/qgis-3.18.3.ebuild | 207 ++++++++++++++++++++++++++++++++
2 files changed, 208 insertions(+)
diff --git a/sci-geosciences/qgis/Manifest b/sci-geosciences/qgis/Manifest
index d7a5855a3f6..be8c6dd9130 100644
--- a/sci-geosciences/qgis/Manifest
+++ b/sci-geosciences/qgis/Manifest
@@ -1,3 +1,4 @@
DIST qgis-3.16.2.tar.bz2 114086615 BLAKE2B 85196072b792b5731dcbc85cfaaae1768e91d16bfdaa2190cfb6063753953b6ab0e8b17b0d3f5334259dffd5b8fb5be6b54a28ca9856dc4fc4079dee483888f6 SHA512 93582e54ff403ea05672a81be9e866b8f1fa9335e467723a087615511b8403c4a1d8447d5a433d0799c382b6cc99fb2f18cc9c6685ed6dc83cabb4d13a00f033
DIST qgis-3.16.4.tar.bz2 115427023 BLAKE2B 1526350974b634d13f55b77e99ec54c8cd29eb523657657f72de0f9e9b2b47d931e503404b202fe2e181c8e1918888732cc4353091dd8dffcaefb6caa32ad47f SHA512 a58ef90089416ac08ba014f483cf7f6f929ef97306e213a5d1855fe551ecc42631926f8e015134ebcbc368f134c9f3ed8f2fda1846a409f249ed00b104036d25
+DIST qgis-3.18.3.tar.bz2 121178524 BLAKE2B 9f4c5bb4b4bf980c81b91a38716b280f48bf28d894550563607e202a7764f72c78b9520f060319c219e484254eaa31315fc232b459bec8cc6a1bc07b587babc6 SHA512 d2c08f1f0bdb2ba56a108dc9626122dfe90caae4f300ceb7be2d40112ee9bcc7f286f092f7f207812428aca926c7fe0dabe49039bba0f32f2f371d290536f0ef
DIST qgis_sample_data-2.8.14.tar.gz 22119181 BLAKE2B 2d0565e91ec8119382bc9ab8e262dc04227fe8289146794891759ff5a32012245270614ba1119a6329fc45cf56852830c2079589309aa3467873f71f5c608eac SHA512 6b2653d5b57ffc2c2317639dac212429840984ac917ca3e452b39aabb99ea106d1a77c1c1dd967244ef16ede9deae751b170affdf08b72239eafed5b8977da3d
diff --git a/sci-geosciences/qgis/qgis-3.18.3.ebuild b/sci-geosciences/qgis/qgis-3.18.3.ebuild
new file mode 100644
index 00000000000..80d2d316881
--- /dev/null
+++ b/sci-geosciences/qgis/qgis-3.18.3.ebuild
@@ -0,0 +1,207 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+PYTHON_REQ_USE="sqlite"
+
+if [[ ${PV} = *9999 ]]; then
+ EGIT_REPO_URI="https://github.com/${PN}/${PN^^}.git"
+ inherit git-r3
+else
+ SRC_URI="https://qgis.org/downloads/${P}.tar.bz2
+ examples? ( https://qgis.org/downloads/data/qgis_sample_data.tar.gz -> qgis_sample_data-2.8.14.tar.gz )"
+ KEYWORDS="~amd64 ~x86"
+fi
+inherit cmake desktop python-single-r1 qmake-utils xdg
+
+DESCRIPTION="User friendly Geographic Information System"
+HOMEPAGE="https://www.qgis.org/en/site/"
+
+LICENSE="GPL-2+ GPL-3+"
+SLOT="0"
+IUSE="3d examples georeferencer grass hdf5 mapserver netcdf opencl oracle polar postgres python qml serial"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} mapserver? ( python )"
+
+BDEPEND="${PYTHON_DEPS}
+ dev-qt/linguist-tools:5
+ sys-devel/bison
+ sys-devel/flex
+"
+COMMON_DEPEND="
+ >=app-crypt/qca-2.3.0:2[ssl]
+ >=dev-db/spatialite-4.2.0
+ dev-db/sqlite:3
+ dev-libs/expat
+ dev-libs/libzip:=
+ dev-libs/protobuf:=
+ dev-libs/qtkeychain:=
+ dev-qt/designer:5
+ dev-qt/qtconcurrent:5
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtnetwork:5[ssl]
+ dev-qt/qtpositioning:5
+ dev-qt/qtprintsupport:5
+ dev-qt/qtsql:5
+ dev-qt/qtsvg:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+ media-gfx/exiv2:=
+ >=sci-libs/gdal-3.0.4:=[geos]
+ sci-libs/geos
+ sci-libs/libspatialindex:=
+ >=sci-libs/proj-6.3.1:=
+ sys-libs/zlib
+ >=x11-libs/qscintilla-2.10.3:=
+ >=x11-libs/qwt-6.1.3-r2:6=[svg]
+ 3d? ( dev-qt/qt3d:5 )
+ georeferencer? ( sci-libs/gsl:= )
+ grass? ( =sci-geosciences/grass-7*:= )
+ hdf5? ( sci-libs/hdf5:= )
+ mapserver? ( dev-libs/fcgi )
+ netcdf? ( sci-libs/netcdf:= )
+ opencl? ( virtual/opencl )
+ oracle? (
+ dev-db/oracle-instantclient:=
+ sci-libs/gdal:=[oracle]
+ )
+ polar? ( >=x11-libs/qwtpolar-1.1.1-r2 )
+ postgres? ( dev-db/postgresql:= )
+ python? (
+ ${PYTHON_DEPS}
+ $(python_gen_cond_dep '
+ dev-python/httplib2[${PYTHON_MULTI_USEDEP}]
+ dev-python/jinja[${PYTHON_MULTI_USEDEP}]
+ dev-python/markupsafe[${PYTHON_MULTI_USEDEP}]
+ dev-python/owslib[${PYTHON_MULTI_USEDEP}]
+ dev-python/pygments[${PYTHON_MULTI_USEDEP}]
+ dev-python/PyQt5[designer,gui,network,printsupport,sql,svg,${PYTHON_MULTI_USEDEP}]
+ dev-python/python-dateutil[${PYTHON_MULTI_USEDEP}]
+ dev-python/pytz[${PYTHON_MULTI_USEDEP}]
+ dev-python/pyyaml[${PYTHON_MULTI_USEDEP}]
+ >=dev-python/qscintilla-python-2.10.3[${PYTHON_MULTI_USEDEP}]
+ dev-python/requests[${PYTHON_MULTI_USEDEP}]
+ dev-python/sip:=[${PYTHON_MULTI_USEDEP}]
+ dev-python/six[${PYTHON_MULTI_USEDEP}]
+ >=sci-libs/gdal-2.2.3[python,${PYTHON_MULTI_USEDEP}]
+ postgres? ( dev-python/psycopg:2[${PYTHON_MULTI_USEDEP}] )
+ ')
+ )
+ qml? ( dev-qt/qtdeclarative:5 )
+ serial? ( dev-qt/qtserialport:5 )
+"
+DEPEND="${COMMON_DEPEND}
+ dev-qt/qttest:5
+"
+RDEPEND="${COMMON_DEPEND}
+ sci-geosciences/gpsbabel
+"
+
+# Disabling test suite because upstream disallow running from install path
+RESTRICT="test"
+
+PATCHES=(
+ # git master
+ "${FILESDIR}/${PN}-3.16.0-cmake-lib-suffix.patch"
+ # TODO upstream
+ "${FILESDIR}/${PN}-3.16.1-featuresummary.patch"
+ "${FILESDIR}/${PN}-3.16.1-default-qmldir.patch"
+)
+
+pkg_setup() {
+ python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ cmake_src_prepare
+ sed -e "/QtWebKit.*.py/d" \
+ -i python/PyQt/CMakeLists.txt || die
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DQGIS_MANUAL_SUBDIR=share/man/
+ -DQGIS_LIB_SUBDIR=$(get_libdir)
+ -DQGIS_PLUGIN_SUBDIR=$(get_libdir)/qgis
+ -DQWT_INCLUDE_DIR=/usr/include/qwt6
+ -DQWT_LIBRARY=/usr/$(get_libdir)/libqwt6-qt5.so
+ -DPEDANTIC=OFF
+ -DUSE_CCACHE=OFF
+ -DWITH_ANALYSIS=ON
+ -DWITH_APIDOC=OFF
+ -DWITH_GUI=ON
+ -DWITH_INTERNAL_MDAL=ON # not packaged, bug 684538
+ -DWITH_QSPATIALITE=ON
+ -DENABLE_TESTS=OFF
+ -DWITH_3D=$(usex 3d)
+ -DWITH_GEOREFERENCER=$(usex georeferencer)
+ -DWITH_GRASS7=$(usex grass)
+ $(cmake_use_find_package hdf5 HDF5)
+ -DWITH_SERVER=$(usex mapserver)
+ $(cmake_use_find_package netcdf NetCDF)
+ -DUSE_OPENCL=$(usex opencl)
+ -DWITH_ORACLE=$(usex oracle)
+ -DWITH_QWTPOLAR=$(usex polar)
+ -DWITH_POSTGRESQL=$(usex postgres)
+ -DWITH_BINDINGS=$(usex python)
+ -DWITH_CUSTOM_WIDGETS=$(usex python)
+ -DWITH_QUICK=$(usex qml)
+ -DWITH_QT5SERIALPORT=$(usex serial)
+ -DWITH_QTWEBKIT=OFF
+ )
+
+ if use grass; then
+ mycmakeargs+=(
+ -DGRASS_PREFIX7=/usr/$(get_libdir)/grass78
+ )
+ fi
+
+ use python && mycmakeargs+=( -DBINDINGS_GLOBAL_INSTALL=ON ) ||
+ mycmakeargs+=( -DWITH_QGIS_PROCESS=OFF ) # FIXME upstream issue #39973
+
+ # bugs 612956, 648726
+ addpredict /dev/dri/renderD128
+ addpredict /dev/dri/renderD129
+
+ cmake_src_configure
+}
+
+src_install() {
+ cmake_src_install
+
+ insinto /usr/share/mime/packages
+ doins debian/qgis.xml
+
+ if use examples; then
+ docinto examples
+ dodoc -r "${WORKDIR}"/qgis_sample_data/.
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+
+ if use python; then
+ python_optimize
+ python_optimize "${ED}"/usr/share/qgis/python
+ fi
+
+ if use grass; then
+ python_fix_shebang "${ED}"/usr/share/qgis/grass/scripts
+ fi
+}
+
+pkg_postinst() {
+ if use postgres; then
+ elog "If you don't intend to use an external PostGIS server"
+ elog "you should install:"
+ elog " dev-db/postgis"
+ elif use python; then
+ elog "Support of PostgreSQL is disabled."
+ elog "But some installed python-plugins import the psycopg2 module."
+ elog "If you do not need these plugins just disable them"
+ elog "in the Plugins menu, else you need to set USE=\"postgres\""
+ fi
+
+ xdg_pkg_postinst
+}