From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1276933-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id A28941382C5
	for <garchives@archives.gentoo.org>; Sat,  1 May 2021 07:45:09 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id CF4E1E0D14;
	Sat,  1 May 2021 07:45:08 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id AA805E0D14
	for <gentoo-commits@lists.gentoo.org>; Sat,  1 May 2021 07:45:08 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 6F422335C5A
	for <gentoo-commits@lists.gentoo.org>; Sat,  1 May 2021 07:45:07 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id E896D733
	for <gentoo-commits@lists.gentoo.org>; Sat,  1 May 2021 07:45:05 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1619855091.165fbb2100c0f4d36d81a72145e249d09bd304b0.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/ipython/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-python/ipython/Manifest dev-python/ipython/ipython-7.23.0.ebuild
X-VCS-Directories: dev-python/ipython/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: 165fbb2100c0f4d36d81a72145e249d09bd304b0
X-VCS-Branch: master
Date: Sat,  1 May 2021 07:45:05 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: c0f0e62b-212e-4c47-850f-a2497ba0fe6e
X-Archives-Hash: 27060802d317742a11ca7128561971d8

commit:     165fbb2100c0f4d36d81a72145e249d09bd304b0
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat May  1 06:16:10 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat May  1 07:44:51 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=165fbb21

dev-python/ipython: Bump to 7.23.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/ipython/Manifest              |   1 +
 dev-python/ipython/ipython-7.23.0.ebuild | 139 +++++++++++++++++++++++++++++++
 2 files changed, 140 insertions(+)

diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index c28ab91001f..4f469b8eba4 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,2 +1,3 @@
 DIST ipython-7.21.0.tar.gz 5141725 BLAKE2B dae44d481e959ef7d002bdb51d0ab1e2f3eca3449071a2e4161aa735c06fef8a948d80bafd3f2bdd066208437b5ed36615cad5885af453771a32a313fba907eb SHA512 200e41d4e06343b6320f3d106925f6c995f39cf88d01250f53885d4e94d0fd9454a6be4cd7c69410f7dced94b05634f6d2269f9737cc563accf85206d4d7fff8
 DIST ipython-7.22.0.tar.gz 5143229 BLAKE2B be78fc7089d620cb9ad437ed8154b37ac8c7cd68ca18a2569cfcf7ea9af968c58eeee18c8d18a1f26459ccef73e59083ac27055c19e4df254836e484ce0a9908 SHA512 2647dcd5e0d9b6afc8d990d2c099ad7ed581b5eff6d657630929e0d0d9f8965e7c7924c51a10a797e7d7406212d7a06c941c163e6f6046aa62130049a9bbc0d0
+DIST ipython-7.23.0.tar.gz 5143701 BLAKE2B 6672ea3a5bbc9afa38c73acef87a8c8f6d1830e3b949543537b522b809b68b80e5369566c8bee68139f9c3213fbe4c07ad36377a686fe2d26d7bbafd5e54fc4a SHA512 b00b71dbb2851f03f72b6c0e93920afc52cdb3cd5b8f27ba8cca4cb062a0f313db359ba83ba3a9608bca22744efab24c27350e06c5884946709b7fd29536820f

diff --git a/dev-python/ipython/ipython-7.23.0.ebuild b/dev-python/ipython/ipython-7.23.0.ebuild
new file mode 100644
index 00000000000..2f2dc34fb24
--- /dev/null
+++ b/dev-python/ipython/ipython-7.23.0.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE='readline,sqlite,threads(+)'
+
+inherit distutils-r1 optfeature virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/backcall[${PYTHON_USEDEP}]
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	dev-python/pickleshare[${PYTHON_USEDEP}]
+	>=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}]
+	<dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	matplotlib? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	)
+"
+
+BDEPEND="
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.16[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )"
+PDEPEND="
+	notebook? (
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+	)
+	qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch )
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# Remove out of date insource files
+	rm IPython/extensions/cythonmagic.py || die
+	rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line_profiler
+	optfeature "%mprun magic command" dev-python/memory_profiler
+
+	if use nbconvert; then
+		if ! has_version app-text/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}