[gentoo-commits] repo/gentoo:master commit in: gnome-base/nautilus/

["Matt Turner" <mattst88@gentoo.org>]

commit:     3acf65592675cf58e11499ef3525018de4f310cd
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 30 20:03:24 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr 30 20:03:24 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3acf6559

gnome-base/nautilus: Version bump to 40.1

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-base/nautilus/Manifest             |   1 +
 gnome-base/nautilus/nautilus-40.1.ebuild | 106 +++++++++++++++++++++++++++++++
 2 files changed, 107 insertions(+)

diff --git a/gnome-base/nautilus/Manifest b/gnome-base/nautilus/Manifest
index 37d84ad9d48..3ebe03b9a15 100644
--- a/gnome-base/nautilus/Manifest
+++ b/gnome-base/nautilus/Manifest
@@ -1,3 +1,4 @@
 DIST nautilus-3.36.3.tar.xz 3201908 BLAKE2B ec7be7ad523e29c853a1a16dd6381257bd7f7af0004d4b84a9ef13539f5c8ea431c61f819eee6c0d396037846d390ae112b3fe2771276cde6128e7fad95eb4f4 SHA512 4dce01c20a34ed9bbff53a9886775af431754d02a4300e4647d87830502103e7436e53127b2e503af8e3a90785aa864514dbde22508ffb3e06eb43d4633fddde
 DIST nautilus-3.38.2.tar.xz 3221128 BLAKE2B c5d67072cefcd8dbbb0454ff6e867045a0edc72f0b4b1e01c910d4bdb1b755a56c3609f6e5d5f8ca8624a667d105a0962b6de701ceafa2108c1c94807c92e8c7 SHA512 b716140363e6c3ec30ef450958a4d6d812502e96569a9ce2567f56297fd0b3a7e779df6628d447b19dd20b8128a371a523aa5a6e34da40e9466d0b94341ca12c
 DIST nautilus-40.0.tar.xz 3250800 BLAKE2B e57381d7f9b9e6884e4f22f3c3d78c931d197b78f0f139457bf141ffdfebe646ddeb2d280a1d2b38124b8d8199323983ea48631d98843a49d125b7be49eb5989 SHA512 700a18b27da28608d247c046dcaddb3114cd0648e077ef0a0be3eba6f1e3623720224610aa92c1513a84a0ef91bae7b18e3624de9c2c1495544d260635688e5f
+DIST nautilus-40.1.tar.xz 3252276 BLAKE2B 6123fcc933f94ca405f7590ef446af0472f4ec10f5188ae3aaf9cb38a0cb1905a7cfbd69c47c5f1b3258bf915006184caeafa2e10035f0068e758a615c328609 SHA512 6421ce0c30c6f3a406a9c100b4a62e01276b10b6cdf05c9aa862a0ece89c7d231e8d3630aecfb8a1e6b40d62849c80c6c91b3f6b6663251466aa8865e60dbfc1

diff --git a/gnome-base/nautilus/nautilus-40.1.ebuild b/gnome-base/nautilus/nautilus-40.1.ebuild
new file mode 100644
index 00000000000..e98afa90e78
--- /dev/null
+++ b/gnome-base/nautilus/nautilus-40.1.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson readme.gentoo-r1 virtualx xdg
+
+DESCRIPTION="Default file manager for the GNOME desktop"
+HOMEPAGE="https://wiki.gnome.org/Apps/Nautilus"
+
+LICENSE="GPL-3+ LGPL-2.1+"
+SLOT="0"
+IUSE="gnome +gstreamer gtk-doc +introspection +previewer selinux sendto"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="
+	>=dev-libs/glib-2.67.1:2
+	>=media-libs/gexiv2-0.10.0
+	gstreamer? ( media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0 )
+	>=app-arch/gnome-autoar-0.3.0
+	>=gnome-base/gnome-desktop-3.0.0:3=
+	>=x11-libs/gtk+-3.22.27:3[X,introspection?]
+	>=gui-libs/libhandy-1.1.90:1
+	>=x11-libs/pango-1.28.3
+	selinux? ( >=sys-libs/libselinux-2.0 )
+	>=app-misc/tracker-3.0:3=
+	x11-libs/libX11
+	>=dev-libs/libxml2-2.7.8:2
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	gstreamer? ( !<media-video/totem-3.31.91[nautilus] )
+	>=app-misc/tracker-miners-3.0:3=
+" # uses org.freedesktop.Tracker.Miner.Files gsettings schema from tracker-miners
+BDEPEND="
+	>=dev-util/gdbus-codegen-2.51.2
+	dev-util/glib-utils
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.10
+		app-text/docbook-xml-dtd:4.1.2 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	x11-base/xorg-proto
+"
+PDEPEND="
+	gnome? ( x11-themes/adwaita-icon-theme )
+	previewer? ( >=gnome-extra/sushi-0.1.9 )
+	sendto? ( >=gnome-extra/nautilus-sendto-3.0.1 )
+	>=gnome-base/gvfs-1.14[gtk(+)]
+" # Need gvfs[gtk] for recent:/// support; always built (without USE=gtk) since gvfs-1.34
+
+PATCHES=(
+	"${FILESDIR}"/3.30.5-docs-build.patch # Always install pregenerated manpage, keeping docs option for gtk-doc
+	"${FILESDIR}"/3.32.3-optional-gstreamer.patch # Allow controlling audio-video-properties build
+)
+
+src_prepare() {
+	if use previewer; then
+		DOC_CONTENTS="nautilus uses gnome-extra/sushi to preview media files.
+			To activate the previewer, select a file and press space; to
+			close the previewer, press space again."
+	fi
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dextensions=true # image file properties, sendto support; also required for -Dgstreamer=true
+		$(meson_use gstreamer) # gstreamer audio-video-properties extension
+		$(meson_use introspection)
+		-Dlibportal=false
+		-Dpackagekit=false
+		$(meson_use selinux)
+		-Dprofiling=false
+		-Dtests=$(usex test all none)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	use previewer && readme.gentoo_create_doc
+	meson_src_install
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	if use previewer; then
+		readme.gentoo_print_elog
+	else
+		elog "To preview media files, emerge nautilus with USE=previewer"
+	fi
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}