[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-contacts/

["Matt Turner" <mattst88@gentoo.org>]

commit:     3d9b45920813ff875c7b0b6389f274a35690cd09
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 16 22:20:00 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Apr 16 22:26:39 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3d9b4592

gnome-extra/gnome-contacts: Version bump to 40.0

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gnome-extra/gnome-contacts/Manifest                |  1 +
 .../gnome-contacts/gnome-contacts-40.0.ebuild      | 76 ++++++++++++++++++++++
 2 files changed, 77 insertions(+)

diff --git a/gnome-extra/gnome-contacts/Manifest b/gnome-extra/gnome-contacts/Manifest
index c25b1a2a69e..3f067e88da4 100644
--- a/gnome-extra/gnome-contacts/Manifest
+++ b/gnome-extra/gnome-contacts/Manifest
@@ -1 +1,2 @@
 DIST gnome-contacts-3.38.1.tar.xz 657376 BLAKE2B 5c042566ad99be1bda454466dcc2a42d6494cfbfb5a9f60eb0fa718a8d9bcbb986798ec48a87d5d322989b22d0fac2eee69df852ae39ba8a228ad91f50247c30 SHA512 bc2ed06d491c4773b9cedb2c51dc390a95d0271cf22d54864f5da4d892f80efece3cbdc1b90b4497f730039c8c83065b2a0ca590cecec579f011dd324ff8f134
+DIST gnome-contacts-40.0.tar.xz 270412 BLAKE2B 4d7970ac5417dfbd9b0acf51efd8ce1310cee51f90de8d8afa0239d918269642869e35befb64cbfb5acf1bde17ac738192d5ef802d27df47936165b03ed20b51 SHA512 5f9bb7e805cc67a379fd1ab5945774f5067be64d6577bc9cf0514c4ca6b53937555dc96591244d8be418b2b07f7c5401e8186dca5baff3a2b6c5a2ae459a676f

diff --git a/gnome-extra/gnome-contacts/gnome-contacts-40.0.ebuild b/gnome-extra/gnome-contacts/gnome-contacts-40.0.ebuild
new file mode 100644
index 00000000000..7cf6f2b6d3a
--- /dev/null
+++ b/gnome-extra/gnome-contacts/gnome-contacts-40.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+VALA_MIN_API_VERSION="0.40"
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="GNOME contact management application"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Contacts"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="telepathy v4l"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~sparc ~x86"
+
+VALA_DEPEND="
+	$(vala_depend)
+	>=dev-libs/gobject-introspection-1.54
+	dev-libs/folks[vala(+)]
+	net-libs/gnome-online-accounts[vala]
+	gnome-extra/evolution-data-server[gtk,vala]
+	telepathy? ( net-libs/telepathy-glib[vala] )
+	>=gui-libs/libhandy-1.1.0:1[vala]
+"
+# Configure is wrong; it needs cheese-3.5.91, not 3.3.91
+RDEPEND="
+	>=gnome-extra/evolution-data-server-3.30:=[gnome-online-accounts]
+	>=dev-libs/folks-0.11.4:=[eds,telepathy?]
+	>=dev-libs/glib-2.58:2
+	>=dev-libs/libgee-0.10:0.8
+	>=gnome-base/gnome-desktop-3.0:3=
+	net-libs/gnome-online-accounts:=
+	>=x11-libs/gtk+-3.23.1:3
+	v4l? ( >=media-video/cheese-3.5.91:= )
+	telepathy? ( >=net-libs/telepathy-glib-0.22 )
+	>=gui-libs/libhandy-1.0.0:1
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	${VALA_DEPEND}
+	app-text/docbook-xml-dtd:4.2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature v4l cheese)
+		$(meson_use telepathy)
+		-Dmanpage=true
+		-Ddocs=false
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}