From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1270833-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id 64D101382C5
	for <garchives@archives.gentoo.org>; Tue, 13 Apr 2021 23:07:04 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 6C30EE0A85;
	Tue, 13 Apr 2021 23:07:03 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id 3EA79E0A85
	for <gentoo-commits@lists.gentoo.org>; Tue, 13 Apr 2021 23:07:03 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id CDCD1335CD7
	for <gentoo-commits@lists.gentoo.org>; Tue, 13 Apr 2021 23:07:01 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 1046E4D2
	for <gentoo-commits@lists.gentoo.org>; Tue, 13 Apr 2021 23:07:00 +0000 (UTC)
From: "William Hubbs" <williamh@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "William Hubbs" <williamh@gentoo.org>
Message-ID: <1618355166.f319933e8f3f4f95b8a4d75da6ed6feaa7813b8d.williamh@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: sys-apps/openrc/
X-VCS-Repository: repo/gentoo
X-VCS-Files: sys-apps/openrc/Manifest sys-apps/openrc/openrc-0.43.2.ebuild
X-VCS-Directories: sys-apps/openrc/
X-VCS-Committer: williamh
X-VCS-Committer-Name: William Hubbs
X-VCS-Revision: f319933e8f3f4f95b8a4d75da6ed6feaa7813b8d
X-VCS-Branch: master
Date: Tue, 13 Apr 2021 23:07:00 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 0fbc4a8f-5f1f-434e-8629-426d3ad6cf6b
X-Archives-Hash: 1f980d7c34008ee59befd1423744270a

commit:     f319933e8f3f4f95b8a4d75da6ed6feaa7813b8d
Author:     William Hubbs <williamh <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 13 23:06:06 2021 +0000
Commit:     William Hubbs <williamh <AT> gentoo <DOT> org>
CommitDate: Tue Apr 13 23:06:06 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f319933e

sys-apps/openrc: 0.43.2 bump

Signed-off-by: William Hubbs <williamh <AT> gentoo.org>

 sys-apps/openrc/Manifest             |   1 +
 sys-apps/openrc/openrc-0.43.2.ebuild | 187 +++++++++++++++++++++++++++++++++++
 2 files changed, 188 insertions(+)

diff --git a/sys-apps/openrc/Manifest b/sys-apps/openrc/Manifest
index 3e2d570b72c..ae93422ada6 100644
--- a/sys-apps/openrc/Manifest
+++ b/sys-apps/openrc/Manifest
@@ -1,2 +1,3 @@
 DIST openrc-0.42.1.tar.gz 242848 BLAKE2B 381f52552c13afbbcf45456fe71078bacf9182adfd67c97394093986977f5e8262d8a3c64219501745575a5210f525afe9fccee72f7625485a9f575108baa369 SHA512 579b9bfbb151b945a364a2c12b037d2e15991820ca99a07ac18e9bdc50074e67fbf0dcf9865aa4deabe2bf82092e4623be51c9e0b4014384951e0a92ac1e7646
 DIST openrc-0.43.1.tar.gz 240008 BLAKE2B 0db27cca0a6e965c5333ee07a7f9f361dc7c32b82d413efa7ee472ecf253f82be03bb9006f7d9f2ff45af5b8de685b5700095175fde444bb8ba08b8d770f0500 SHA512 0c4590b6cc15872622824ac53d574d831f536ba983ab7171b227e22441651566d36cfd7e69b28223fa25aab9f3457fb889e6e3225069d08552d440df12e6af84
+DIST openrc-0.43.2.tar.gz 240267 BLAKE2B a279833861c2e060aa6a95997bf384407bce395589b3a29cc9ab30c3ec11584da8e16501dfaaebe72ba0342513efdca6fa402995c22ceeb78d5ddd9f1f0d2252 SHA512 ecf55ec003a597bb13f1726082f062f426d23ac98ac680a913486bf4fb340fa6a26678d3e9f5158874b9591266903c5627188aef734a7e946c5e22db3a1b70ce

diff --git a/sys-apps/openrc/openrc-0.43.2.ebuild b/sys-apps/openrc/openrc-0.43.2.ebuild
new file mode 100644
index 00000000000..f6eaa2172d2
--- /dev/null
+++ b/sys-apps/openrc/openrc-0.43.2.ebuild
@@ -0,0 +1,187 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic pam toolchain-funcs
+
+DESCRIPTION="OpenRC manages the services, startup and shutdown of a host"
+HOMEPAGE="https://github.com/openrc/openrc/"
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/OpenRC/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="audit bash debug ncurses pam newnet prefix +netifrc selinux sysv-utils unicode"
+
+COMMON_DEPEND="
+	ncurses? ( sys-libs/ncurses:0= )
+	pam? (
+		sys-auth/pambase
+		sys-libs/pam
+	)
+	audit? ( sys-process/audit )
+	sys-process/psmisc
+	!<sys-process/procps-3.3.9-r2
+	selinux? (
+		sys-apps/policycoreutils
+		>=sys-libs/libselinux-2.6
+	)
+	!<sys-apps/baselayout-2.1-r1
+	!<sys-fs/udev-init-scripts-27"
+DEPEND="${COMMON_DEPEND}
+	virtual/os-headers
+	ncurses? ( virtual/pkgconfig )"
+RDEPEND="${COMMON_DEPEND}
+	bash? ( app-shells/bash )
+	!prefix? (
+		sysv-utils? (
+			!sys-apps/systemd[sysv-utils(-)]
+			!sys-apps/sysvinit
+		)
+		!sysv-utils? ( >=sys-apps/sysvinit-2.86-r6[selinux?] )
+		virtual/tmpfiles
+	)
+	selinux? (
+		>=sec-policy/selinux-base-policy-2.20170204-r4
+		>=sec-policy/selinux-openrc-2.20170204-r4
+	)
+	!<app-shells/gentoo-bashcomp-20180302
+	!<app-shells/gentoo-zsh-completions-20180228
+"
+
+PDEPEND="netifrc? ( net-misc/netifrc )"
+
+src_prepare() {
+	default
+	if [[ ${PV} == "9999" ]] ; then
+		local ver="git-${EGIT_VERSION:0:6}"
+		sed -i "/^GITVER[[:space:]]*=/s:=.*:=${ver}:" mk/gitver.mk || die
+	fi
+}
+
+src_compile() {
+	MAKE_ARGS="${MAKE_ARGS}
+		LIBNAME=$(get_libdir)
+		LIBDIR=${EPREFIX}/$(get_libdir)
+		LIBEXECDIR=${EPREFIX}/lib/rc
+		MKBASHCOMP=yes
+		MKNET=$(usex newnet)
+		MKSELINUX=$(usex selinux)
+		MKSYSVINIT=$(usex sysv-utils)
+		MKAUDIT=$(usex audit)
+		MKPAM=$(usev pam)
+		MKSTATICLIBS=no
+		MKZSHCOMP=yes
+		OS=Linux
+		SH=$(usex bash /bin/bash /bin/sh)"
+
+	use prefix && MAKE_ARGS="${MAKE_ARGS} MKPREFIX=yes PREFIX=${EPREFIX}"
+export BRANDING="Gentoo Linux"
+	export DEBUG=$(usev debug)
+	export MKTERMCAP=$(usev ncurses)
+
+	tc-export CC AR RANLIB
+	emake ${MAKE_ARGS}
+}
+
+# set_config <file> <option name> <yes value> <no value> test
+# a value of "#" will just comment out the option
+set_config() {
+	local file="${ED}/$1" var=$2 val com
+	eval "${@:5}" && val=$3 || val=$4
+	[[ ${val} == "#" ]] && com="#" && val='\2'
+	sed -i -r -e "/^#?${var}=/{s:=([\"'])?([^ ]*)\1?:=\1${val}\1:;s:^#?:${com}:}" "${file}"
+}
+
+set_config_yes_no() {
+	set_config "$1" "$2" YES NO "${@:3}"
+}
+
+src_install() {
+	emake ${MAKE_ARGS} DESTDIR="${D}" install
+
+	keepdir /lib/rc/tmp
+
+	# Setup unicode defaults for silly unicode users
+	set_config_yes_no /etc/rc.conf unicode use unicode
+
+	# Cater to the norm
+	set_config_yes_no /etc/conf.d/keymaps windowkeys '(' use x86 '||' use amd64 ')'
+
+	# On HPPA, do not run consolefont by default (bug #222889)
+	if use hppa; then
+		rm -f "${ED}"/etc/runlevels/boot/consolefont
+	fi
+
+	# Support for logfile rotation
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/openrc.logrotate openrc
+
+	if use pam; then
+		# install gentoo pam.d files
+		newpamd "${FILESDIR}"/start-stop-daemon.pam start-stop-daemon
+		newpamd "${FILESDIR}"/start-stop-daemon.pam supervise-daemon
+	fi
+
+	# install documentation
+	dodoc ChangeLog *.md
+	if use newnet; then
+		dodoc README.newnet
+	fi
+}
+
+pkg_preinst() {
+	# avoid default thrashing in conf.d files when possible #295406
+	if [[ -e "${EROOT}"/etc/conf.d/hostname ]] ; then
+		(
+		unset hostname HOSTNAME
+		source "${EROOT}"/etc/conf.d/hostname
+		: ${hostname:=${HOSTNAME}}
+		[[ -n ${hostname} ]] && set_config /etc/conf.d/hostname hostname "${hostname}"
+		)
+	fi
+
+	# set default interactive shell to sulogin if it exists
+	set_config /etc/rc.conf rc_shell /sbin/sulogin "#" test -e /sbin/sulogin
+	return 0
+}
+
+pkg_postinst() {
+	if use hppa; then
+		elog "Setting the console font does not work on all HPPA consoles."
+		elog "You can still enable it by running:"
+		elog "# rc-update add consolefont boot"
+	fi
+
+	# Added for 0.35.
+	if [[ ! -h "${EROOT}"/lib ]]; then
+		if [[ -d "${EROOT}/$(get_libdir)"/rc ]]; then
+			cp -RPp "${EROOT}/$(get_libdir)/rc" "${EROOT}"/lib
+		fi
+	fi
+
+	if ! use newnet && ! use netifrc; then
+		ewarn "You have emerged OpenRc without network support. This"
+		ewarn "means you need to SET UP a network manager such as"
+		ewarn "	net-misc/netifrc, net-misc/dhcpcd, net-misc/connman,"
+		ewarn " net-misc/NetworkManager, or net-vpn/badvpn."
+		ewarn "Or, you have the option of emerging openrc with the newnet"
+		ewarn "use flag and configuring /etc/conf.d/network and"
+		ewarn "/etc/conf.d/staticroute if you only use static interfaces."
+		ewarn
+	fi
+
+	if use newnet && [ ! -e "${EROOT}"/etc/runlevels/boot/network ]; then
+		ewarn "Please add the network service to your boot runlevel"
+		ewarn "as soon as possible. Not doing so could leave you with a system"
+		ewarn "without networking."
+		ewarn
+	fi
+}