From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1270123-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
	(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
	(No client certificate requested)
	by finch.gentoo.org (Postfix) with ESMTPS id EFE1113835A
	for <garchives@archives.gentoo.org>; Mon, 12 Apr 2021 13:49:11 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
	by pigeon.gentoo.org (Postfix) with SMTP id 00963E086B;
	Mon, 12 Apr 2021 13:49:11 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by pigeon.gentoo.org (Postfix) with ESMTPS id C9780E0869
	for <gentoo-commits@lists.gentoo.org>; Mon, 12 Apr 2021 13:49:10 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
	(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
	(No client certificate requested)
	by smtp.gentoo.org (Postfix) with ESMTPS id 81A3F340C9C
	for <gentoo-commits@lists.gentoo.org>; Mon, 12 Apr 2021 13:49:09 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
	by oystercatcher.gentoo.org (Postfix) with ESMTP id 0FC325B8
	for <gentoo-commits@lists.gentoo.org>; Mon, 12 Apr 2021 13:49:08 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1618235345.5b9448f968815531de9baa4e8452a0ed2376f22d.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/pypy3/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-python/pypy3/Manifest dev-python/pypy3/pypy3-7.3.3_p37_p3.ebuild
X-VCS-Directories: dev-python/pypy3/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: 5b9448f968815531de9baa4e8452a0ed2376f22d
X-VCS-Branch: master
Date: Mon, 12 Apr 2021 13:49:08 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 399fd17f-54c1-4f09-91af-a35ad16dabb1
X-Archives-Hash: 90a6c020a48c672b0c979c4d1c91044c

commit:     5b9448f968815531de9baa4e8452a0ed2376f22d
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 12 13:40:16 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Apr 12 13:49:05 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5b9448f9

dev-python/pypy3: Backport more secfixes to 7.3.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pypy3/Manifest                  |   1 +
 dev-python/pypy3/pypy3-7.3.3_p37_p3.ebuild | 177 +++++++++++++++++++++++++++++
 2 files changed, 178 insertions(+)

diff --git a/dev-python/pypy3/Manifest b/dev-python/pypy3/Manifest
index 99927378bfc..f2511695079 100644
--- a/dev-python/pypy3/Manifest
+++ b/dev-python/pypy3/Manifest
@@ -1,4 +1,5 @@
 DIST pypy3.7-gentoo-patches-7.3.3_p1.tar.xz 13816 BLAKE2B 135a029e2d881ed5e43869fde391571285454b8612f2857fb5fe7aaf5b126f84d01293bd31e7a7746ad03fce1e14ace6a6f9cc2634269ec431b4aabfe70f9b4c SHA512 acf4938bc171e757196cf138358a298880792367ca5fff6b462d6971c8597e064777f99b687cb25003c6f25762a901ed482eebd791fdb008fa729ca9c9c300e8
+DIST pypy3.7-gentoo-patches-7.3.3_p3.tar.xz 17356 BLAKE2B 3418e4d600cdff96c228890dbfe0c63927ff4971be72eb951fb5fbc6ae803f4d26490f4a444dc788b165fa69ec77526413417ec5a697906a3089122f78351a8b SHA512 738d14e5ca693738150a3b9c1152a9b7a9c38dc77540fc7dd14f6d3a556a4b8716785f8f858ddd6b75545dadc623f0fccc57c84a869064ac423bee3acb1dceb6
 DIST pypy3.7-gentoo-patches-7.3.4.tar.xz 8464 BLAKE2B 6d458a41e87eabeb2920b28752fe5cc49bbfc9c5f03d2fc1321362fbd02e9dfb3b41c99cb765b7f2644b9c49c5c60f879ad1c60a66bc991462edb50215b1802d SHA512 1282cf2fa9054209ceb5a91e0b4adcd86de33a326230fabe154b572d5e798d81e93d136e815f1c2816fbfdd5071fcfc175585d4fa5ae93145938bb4cf1d2baa7
 DIST pypy3.7-gentoo-patches-7.3.4_p1.tar.xz 8868 BLAKE2B 5f897f920079dc86d6300ecaf6c9a43c30173b99e90d585151d3efec8718109e9165947ce772f48b6b15ff5c22c3f04f27aec088b34fd2c5c387f0b59728b333 SHA512 aa59f8eaecb1115fe391fe27ecd2c38a6c4213ea6e6de4954bd8a420ce5eb224c225b0ef1df19aef029546b05fa517a4965c9c24d98bc1be46c7eb024415a348
 DIST pypy3.7-v7.3.3-src.tar.bz2 24633503 BLAKE2B 0fb9fbb8866cf661c5b1d8d029fb2bc50737fae097875d0dac86c9ec21dc907093173b350a4f89d2c5a1fbed4c92ca4919f047536b828d4ee35583d615e7ddce SHA512 c98955e72dc0bd0452e4e16e0fe0ab318a34d6d57217ea33349e98ed047597ba97be7d15b41edd4dc85028fcca0a6257a4bb98fe96ce876e41a04df012261f4a

diff --git a/dev-python/pypy3/pypy3-7.3.3_p37_p3.ebuild b/dev-python/pypy3/pypy3-7.3.3_p37_p3.ebuild
new file mode 100644
index 00000000000..e74561b1000
--- /dev/null
+++ b/dev-python/pypy3/pypy3-7.3.3_p37_p3.ebuild
@@ -0,0 +1,177 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+inherit pax-utils python-any-r1 toolchain-funcs
+
+PYPY_PV=${PV%_p37*}
+MY_P=pypy3.7-v${PYPY_PV/_/}
+PATCHSET="pypy3.7-gentoo-patches-${PV/_p37}"
+
+DESCRIPTION="A fast, compliant alternative implementation of the Python (3.7) language"
+HOMEPAGE="https://www.pypy.org/"
+SRC_URI="https://buildbot.pypy.org/pypy/${MY_P}-src.tar.bz2
+	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz"
+S="${WORKDIR}/${MY_P}-src"
+
+LICENSE="MIT"
+# pypy3 -c 'import sysconfig; print(sysconfig.get_config_var("SOABI"))'
+# also check pypy/interpreter/pycode.py -> pypy_incremental_magic
+SLOT="0/pypy37-pp73"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="bzip2 gdbm +jit libressl ncurses sqlite test tk"
+# pypy3.7 is in alpha state and a lot of tests are failing
+RESTRICT="test"
+
+RDEPEND="
+	|| (
+		>=dev-python/pypy3-exe-7.3.3_p37_p2:${PV%_p*}[bzip2?,ncurses?]
+		>=dev-python/pypy3-exe-bin-7.3.3_p37_p2:${PV%_p*}
+	)
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	gdbm? ( sys-libs/gdbm:0= )
+	sqlite? ( dev-db/sqlite:3= )
+	tk? (
+		dev-lang/tk:0=
+		dev-tcltk/tix:0=
+	)
+	!<dev-python/pypy3-bin-7.3.0:0"
+DEPEND="${RDEPEND}
+	test? (
+		${PYTHON_DEPS}
+		!!dev-python/pytest-forked
+	)"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+	default
+
+	sed -e "s^@EPREFIX@^${EPREFIX}^" \
+		-i lib-python/3/distutils/command/install.py || die
+
+	eapply_user
+}
+
+src_configure() {
+	tc-export CC
+}
+
+src_compile() {
+	# copy over to make sys.prefix happy
+	cp -p "${BROOT}"/usr/lib/pypy3.7/pypy3-c-${PYPY_PV} pypy3-c || die
+	cp -p "${BROOT}"/usr/lib/pypy3.7/include/${PYPY_PV}/* include/ || die
+	# (not installed by pypy)
+	rm pypy/module/cpyext/include/_numpypy/numpy/README || die
+	mv pypy/module/cpyext/include/* include/ || die
+	mv pypy/module/cpyext/parse/*.h include/ || die
+	pax-mark m pypy3-c
+
+	einfo "Generating caches and CFFI modules ..."
+
+	# Generate Grammar and PatternGrammar pickles.
+	./pypy3-c -c "import lib2to3.pygram, lib2to3.patcomp; lib2to3.patcomp.PatternCompiler()" \
+		|| die "Generation of Grammar and PatternGrammar pickles failed"
+
+	# Generate cffi modules
+	# Please keep in sync with pypy/tool/build_cffi_imports.py!
+#cffi_build_scripts = {
+#    "_blake2": "_blake2/_blake2_build.py",
+#    "_ssl": "_ssl_build.py",
+#    "sqlite3": "_sqlite3_build.py",
+#    "audioop": "_audioop_build.py",
+#    "tk": "_tkinter/tklib_build.py",
+#    "curses": "_curses_build.py" if sys.platform != "win32" else None,
+#    "syslog": "_syslog_build.py" if sys.platform != "win32" else None,
+#    "gdbm": "_gdbm_build.py"  if sys.platform != "win32" else None,
+#    "pwdgrp": "_pwdgrp_build.py" if sys.platform != "win32" else None,
+#    "resource": "_resource_build.py" if sys.platform != "win32" else None,
+#    "lzma": "_lzma_build.py",
+#    "_decimal": "_decimal_build.py",
+#    "_sha3": "_sha3/_sha3_build.py",
+	cffi_targets=( blake2/_blake2 sha3/_sha3 ssl
+		audioop syslog pwdgrp resource lzma decimal )
+	use gdbm && cffi_targets+=( gdbm )
+	use ncurses && cffi_targets+=( curses )
+	use sqlite && cffi_targets+=( sqlite3 )
+	use tk && cffi_targets+=( tkinter/tklib )
+
+	local t
+	# all modules except tkinter output to .
+	# tkinter outputs to the correct dir ...
+	cd lib_pypy || die
+	for t in "${cffi_targets[@]}"; do
+		# tkinter doesn't work via -m
+		../pypy3-c "_${t}_build.py" || die "Failed to build CFFI bindings for ${t}"
+	done
+
+	# Cleanup temporary objects
+	find -name "_cffi_*.[co]" -delete || die
+	find -type d -empty -delete || die
+}
+
+src_test() {
+	# (unset)
+	local -x PYTHONDONTWRITEBYTECODE=
+	local -x COLUMNS=80
+
+	# Test runner requires Python 2 too. However, it spawns PyPy3
+	# internally so that we end up testing the correct interpreter.
+	# (--deselect for failing doctests)
+	"${EPYTHON}" ./pypy/test_all.py --pypy=./pypy3-c -vv lib-python || die
+}
+
+src_install() {
+	local dest=/usr/lib/pypy3.7
+	einfo "Installing PyPy ..."
+	dosym pypy3-c-${PYPY_PV} "${dest}/pypy3-c"
+	insinto "${dest}"
+	# preserve mtimes to avoid obsoleting caches
+	insopts -p
+	doins -r include lib_pypy lib-python
+
+	# replace copied headers with symlinks
+	for x in "${BROOT}"/usr/lib/pypy3.7/include/${PYPY_PV}/*; do
+		dosym "${PYPY_PV}/${x##*/}" "${dest}/include/${x##*/}"
+	done
+
+	dosym ../lib/pypy3.7/pypy3-c /usr/bin/pypy3
+	dodoc README.rst
+
+	if ! use gdbm; then
+		rm -r "${ED}${dest}"/lib_pypy/_gdbm* || die
+	fi
+	if ! use sqlite; then
+		rm -r "${ED}${dest}"/lib-python/*3/sqlite3 \
+			"${ED}${dest}"/lib_pypy/_sqlite3* \
+			"${ED}${dest}"/lib-python/*3/test/test_sqlite.py || die
+	fi
+	if ! use tk; then
+		rm -r "${ED}${dest}"/lib-python/*3/{idlelib,tkinter} \
+			"${ED}${dest}"/lib_pypy/_tkinter \
+			"${ED}${dest}"/lib-python/*3/test/test_{tcl,tk,ttk*}.py || die
+	fi
+
+	local -x EPYTHON=pypy3
+	local -x PYTHON=${ED}${dest}/pypy3-c-${PYPY_PV}
+	# temporarily copy to build tree to facilitate module builds
+	cp -p "${BROOT}${dest}/pypy3-c-${PYPY_PV}" "${PYTHON}" || die
+
+	echo "EPYTHON='${EPYTHON}'" > epython.py || die
+	python_moduleinto /usr/lib/pypy3.7/site-packages
+	python_domodule epython.py
+
+	einfo "Byte-compiling Python standard library..."
+	python_optimize "${ED}${dest}"
+
+	# remove to avoid collisions
+	rm "${PYTHON}" || die
+}