[gentoo-commits] repo/gentoo:master commit in: dev-libs/openct/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     f0644b69eae65e47efcfd26d7f0bfdfe192ed6bd
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 11 19:46:25 2021 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Sun Apr 11 19:46:25 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f0644b69

dev-libs/openct: migrate to GLEP 81

Closes: https://bugs.gentoo.org/781290
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 dev-libs/openct/openct-0.6.20-r5.ebuild | 70 +++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)

diff --git a/dev-libs/openct/openct-0.6.20-r5.ebuild b/dev-libs/openct/openct-0.6.20-r5.ebuild
new file mode 100644
index 00000000000..12d4c000e8c
--- /dev/null
+++ b/dev-libs/openct/openct-0.6.20-r5.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic udev
+
+DESCRIPTION="library for accessing smart card terminals"
+HOMEPAGE="https://github.com/OpenSC/openct/wiki"
+
+SRC_URI="mirror://sourceforge/opensc/${PN}/${P}.tar.gz"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc debug pcsc-lite usb"
+
+DEPEND="
+	pcsc-lite? ( >=sys-apps/pcsc-lite-1.7.2-r1:= )
+	usb? ( virtual/libusb:0 )
+	dev-libs/libltdl:0=
+"
+RDEPEND="
+	${DEPEND}
+	acct-group/openct
+	acct-user/openctd
+"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+src_configure() {
+	use debug && append-cppflags -DDEBUG_IFDH
+
+	econf \
+		--localstatedir=/var \
+		--with-udev="$(get_udevdir)" \
+		--enable-non-privileged \
+		--with-daemon-user=openctd \
+		--with-daemon-groups=usb \
+		--enable-shared \
+		--disable-static \
+		$(use_enable doc) \
+		$(use_enable doc api-doc) \
+		$(use_enable pcsc-lite pcsc) \
+		$(use_with pcsc-lite bundle /usr/$(get_libdir)/readers/usb) \
+		$(use_enable usb)
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+	rm -f "${ED}"/usr/$(get_libdir)/openct-ifd.* || die
+
+	udev_newrules etc/openct.udev 70-openct.rules
+
+	newinitd "${FILESDIR}"/openct.initd openct
+}
+
+pkg_postinst() {
+	elog
+	elog "You need to edit /etc/openct.conf to enable serial readers."
+	elog
+	elog "You should add \"openct\" to your default runlevel. To do so"
+	elog "type \"rc-update add openct default\"."
+	elog
+	elog "You need to be a member of the (newly created) group openct to"
+	elog "access smart card readers connected to this system. Set users'"
+	elog "groups with usermod -G.  root always has access."
+	elog
+}