[gentoo-commits] repo/gentoo:master commit in: sys-power/nvclock/, sys-power/nvclock/files/

[gentoo-commits] repo/gentoo:master commit in: sys-power/nvclock/, sys-power/nvclock/files/

[Matt Turner]

commit:     2b08833a57d24810b49d4a728f899d42643f8cc1
Author:     Aisha Tammy <gentoo <AT> aisha <DOT> cc>
AuthorDate: Sat Feb 13 15:49:18 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Mar 24 16:07:00 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2b08833a

sys-power/nvclock: revbump for d-m-i

Signed-off-by: Aisha Tammy <gentoo <AT> aisha.cc>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 sys-power/nvclock/files/nvclock_initd-r1          | 12 ++++
 sys-power/nvclock/nvclock-0.8_p20110102-r3.ebuild | 67 +++++++++++++++++++++++
 2 files changed, 79 insertions(+)

diff --git a/sys-power/nvclock/files/nvclock_initd-r1 b/sys-power/nvclock/files/nvclock_initd-r1
new file mode 100644
index 00000000000..9b4ede7d88f
--- /dev/null
+++ b/sys-power/nvclock/files/nvclock_initd-r1
@@ -0,0 +1,12 @@
+#!/sbin/openrc-run
+
+depend() {
+	need display-manager
+}
+
+start() {
+	ebegin "Setting nvidia card overclock speed"
+	nvclock ${CLOCKOPTS} >/dev/null
+	eend $?
+}
+

diff --git a/sys-power/nvclock/nvclock-0.8_p20110102-r3.ebuild b/sys-power/nvclock/nvclock-0.8_p20110102-r3.ebuild
new file mode 100644
index 00000000000..89cc3dc7aff
--- /dev/null
+++ b/sys-power/nvclock/nvclock-0.8_p20110102-r3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="NVIDIA Overclocking Utility"
+HOMEPAGE="http://www.linuxhardware.org/nvclock/"
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="gtk nvcontrol"
+
+RDEPEND="
+	gtk? (
+		x11-libs/gtk+:2
+		x11-libs/libX11
+	)
+	nvcontrol? (
+		x11-libs/libX11
+		x11-libs/libXext
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-r1-make.patch
+	"${FILESDIR}"/${P}-usleep.patch
+	"${FILESDIR}"/${P}-desktop.patch
+	"${FILESDIR}"/${P}-buffers.patch
+	"${FILESDIR}"/${P}-fno-common.patch
+)
+
+src_prepare() {
+	default
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+src_configure() {
+	# only <Qt-4 supported
+	econf \
+		--disable-qt \
+		$(use_enable gtk) \
+		$(use_enable nvcontrol)
+}
+
+src_compile() {
+	emake -C src/ nvclock smartdimmer
+	use gtk && emake -C src/gtk/
+}
+
+src_install() {
+	dodir /usr/bin
+	default
+
+	newinitd "${FILESDIR}"/nvclock_initd-r1 nvclock
+	newconfd "${FILESDIR}"/nvclock_confd nvclock
+}
+
+pkg_postinst() {
+	elog "To enable card overclocking at startup, edit your /etc/conf.d/nvclock"
+	elog "accordingly and then run: rc-update add nvclock default"
+}