From: "Andrew Ammerlaan" <andrewammerlaan@riseup.net>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] proj/sci:master commit in: dev-python/pyct/, dev-python/pyviz_comms/, ...
Date: Sat, 13 Mar 2021 11:14:53 +0000 (UTC) [thread overview]
Message-ID: <1615633412.9e2b84ab3d6f8daa80a2c98981b8188ce750b6ec.andrewammerlaan@gentoo> (raw)
commit: 9e2b84ab3d6f8daa80a2c98981b8188ce750b6ec
Author: leycec <leycec <AT> gmail <DOT> com>
AuthorDate: Thu Mar 11 04:40:19 2021 +0000
Commit: Andrew Ammerlaan <andrewammerlaan <AT> riseup <DOT> net>
CommitDate: Sat Mar 13 11:03:32 2021 +0000
URL: https://gitweb.gentoo.org/proj/sci.git/commit/?id=9e2b84ab
dev-python: add holoviz packages
add dev-python/{colorcet,holoviews,panel,param,pyct,pyviz_comms}
Signed-off-by: Cecil Curry <leycec <AT> gmail.com>
Closes: https://github.com/gentoo/sci/pull/1063
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> riseup.net>
dev-python/colorcet/colorcet-2.0.6.ebuild | 27 ++++++++++
dev-python/colorcet/metadata.xml | 13 +++++
dev-python/holoviews/holoviews-1.14.2.ebuild | 31 +++++++++++
dev-python/holoviews/metadata.xml | 13 +++++
dev-python/panel/metadata.xml | 13 +++++
dev-python/panel/panel-0.11.0.ebuild | 61 ++++++++++++++++++++++
dev-python/param/metadata.xml | 13 +++++
dev-python/param/param-1.10.1.ebuild | 16 ++++++
dev-python/pyct/metadata.xml | 13 +++++
dev-python/pyct/pyct-0.4.8.ebuild | 24 +++++++++
dev-python/pyviz_comms/metadata.xml | 13 +++++
dev-python/pyviz_comms/pyviz_comms-2.0.1.ebuild | 18 +++++++
.../default/linux/amd64/17.0/x32/package.mask | 3 ++
13 files changed, 258 insertions(+)
diff --git a/dev-python/colorcet/colorcet-2.0.6.ebuild b/dev-python/colorcet/colorcet-2.0.6.ebuild
new file mode 100644
index 000000000..c8024aa51
--- /dev/null
+++ b/dev-python/colorcet/colorcet-2.0.6.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Portage incorrectly claims "DISTUTILS_USE_SETUPTOOLS value is probably
+# incorrect" for this package. It isn't. This package imports from neither
+# "distutils", "packaging", "pkg_resources", nor "setuptools" at runtime.
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of perceptually uniform colormaps"
+HOMEPAGE="https://holoviz.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+ >=dev-python/param-1.7.0[${PYTHON_USEDEP}]
+ >=dev-python/pyct-0.4.4[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests pytest
diff --git a/dev-python/colorcet/metadata.xml b/dev-python/colorcet/metadata.xml
new file mode 100644
index 000000000..5874f13b2
--- /dev/null
+++ b/dev-python/colorcet/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+ <email>sci@gentoo.org</email>
+ <name>Gentoo Science Project</name>
+ </maintainer>
+ <stabilize-allarches/>
+ <upstream>
+ <remote-id type="pypi">colorcet</remote-id>
+ <remote-id type="github">holoviz/colorcet</remote-id>
+ </upstream>
+</pkgmetadata>
diff --git a/dev-python/holoviews/holoviews-1.14.2.ebuild b/dev-python/holoviews/holoviews-1.14.2.ebuild
new file mode 100644
index 000000000..505133d78
--- /dev/null
+++ b/dev-python/holoviews/holoviews-1.14.2.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+# HoloViews imports from "distutils" at runtime.
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Make data analysis and visualization seamless and simple"
+HOMEPAGE="https://holoviews.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+ >=dev-python/param-1.9.3[${PYTHON_USEDEP}]
+ >=dev-python/pyct-0.4.4[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+ dev-python/colorcet[${PYTHON_USEDEP}]
+ dev-python/pandas[${PYTHON_USEDEP}]
+ >=dev-python/numpy-1.0.0[${PYTHON_USEDEP}]
+ >=dev-python/panel-0.8.0[${PYTHON_USEDEP}]
+ >=dev-python/pyviz_comms-0.7.4[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/holoviews/metadata.xml b/dev-python/holoviews/metadata.xml
new file mode 100644
index 000000000..e2afe391a
--- /dev/null
+++ b/dev-python/holoviews/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+ <email>sci@gentoo.org</email>
+ <name>Gentoo Science Project</name>
+ </maintainer>
+ <stabilize-allarches/>
+ <upstream>
+ <remote-id type="pypi">holoviews</remote-id>
+ <remote-id type="github">holoviz/holoviews</remote-id>
+ </upstream>
+</pkgmetadata>
diff --git a/dev-python/panel/metadata.xml b/dev-python/panel/metadata.xml
new file mode 100644
index 000000000..892a7d01f
--- /dev/null
+++ b/dev-python/panel/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+ <email>sci@gentoo.org</email>
+ <name>Gentoo Science Project</name>
+ </maintainer>
+ <stabilize-allarches/>
+ <upstream>
+ <remote-id type="pypi">panel</remote-id>
+ <remote-id type="github">holoviz/panel</remote-id>
+ </upstream>
+</pkgmetadata>
diff --git a/dev-python/panel/panel-0.11.0.ebuild b/dev-python/panel/panel-0.11.0.ebuild
new file mode 100644
index 000000000..594377dcd
--- /dev/null
+++ b/dev-python/panel/panel-0.11.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+# Panel imports from "distutils" at runtime.
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="High-level app and dashboarding solution for Python"
+HOMEPAGE="https://panel.holoviz.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# "setup.py" imports from Bokeh to rebuild Node.js packages, but we patch that
+# away below. Our patched Panel thus requires Bokeh only at runtime.
+DEPEND="
+ >=dev-python/param-1.10.0[${PYTHON_USEDEP}]
+ >=dev-python/pyct-0.4.4[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+ dev-python/markdown[${PYTHON_USEDEP}]
+ dev-python/requests[${PYTHON_USEDEP}]
+ dev-python/tqdm[${PYTHON_USEDEP}]
+ >=dev-python/bokeh-2.3.0[${PYTHON_USEDEP}]
+ >=dev-python/pyviz_comms-0.7.4[${PYTHON_USEDEP}]
+ >=net-libs/nodejs-15.11.0
+"
+
+src_prepare() {
+ # Install Jupyter configuration files to "/etc" rather than "/usr/etc".
+ sed -i -e 's~"etc/jupyter~"/etc/jupyter~' setup.py || die
+
+ # Prevent Panel from violating network sandboxing. By default, "setup.py"
+ # invokes "npm" to rebuild Node.js packages bundled with Panel when these
+ # packages were built by Panel developers with a different version of Bokeh
+ # than that installed on the local system. Since disabling this
+ # functionality invites backend and frontend complications, we encourage
+ # server administrators to manually perform this functionality below.
+ sed -i -e '/^\s*_build_paneljs()$/d' setup.py || die
+
+ default_src_prepare
+}
+
+pkg_postinst() {
+ panel_pkg_postinst() {
+ PANEL_DIR="$(${EPYTHON} -c 'import os, panel; print(os.path.dirname(panel.__file__))')"
+ elog "Node.js packages bundled with Panel under ${EPYTHON} may be"
+ elog "desynchronized from Bokeh and require manual rebuilding with:"
+ elog " sudo ${EPYTHON} -m panel build \"${PANEL_DIR}\""
+ elog
+ }
+
+ python_foreach_impl panel_pkg_postinst
+}
diff --git a/dev-python/param/metadata.xml b/dev-python/param/metadata.xml
new file mode 100644
index 000000000..a853e1f59
--- /dev/null
+++ b/dev-python/param/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+ <email>sci@gentoo.org</email>
+ <name>Gentoo Science Project</name>
+ </maintainer>
+ <stabilize-allarches/>
+ <upstream>
+ <remote-id type="pypi">param</remote-id>
+ <remote-id type="github">holoviz/param</remote-id>
+ </upstream>
+</pkgmetadata>
diff --git a/dev-python/param/param-1.10.1.ebuild b/dev-python/param/param-1.10.1.ebuild
new file mode 100644
index 000000000..b6c5e2753
--- /dev/null
+++ b/dev-python/param/param-1.10.1.ebuild
@@ -0,0 +1,16 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Make Python code clearer and more reliable by declaring Parameters"
+HOMEPAGE="http://param.holoviz.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
diff --git a/dev-python/pyct/metadata.xml b/dev-python/pyct/metadata.xml
new file mode 100644
index 000000000..23a8fe7c2
--- /dev/null
+++ b/dev-python/pyct/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+ <email>sci@gentoo.org</email>
+ <name>Gentoo Science Project</name>
+ </maintainer>
+ <stabilize-allarches/>
+ <upstream>
+ <remote-id type="pypi">pyct</remote-id>
+ <remote-id type="github">pyviz-dev/pyct</remote-id>
+ </upstream>
+</pkgmetadata>
diff --git a/dev-python/pyct/pyct-0.4.8.ebuild b/dev-python/pyct/pyct-0.4.8.ebuild
new file mode 100644
index 000000000..f40dc6d49
--- /dev/null
+++ b/dev-python/pyct/pyct-0.4.8.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} pypy3 )
+
+# HoloViews imports from "distutils" at runtime.
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Python packaging Common Tasks"
+HOMEPAGE="https://holoviz.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND=">=dev-python/param-1.7.0[${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}"
+
+distutils_enable_tests pytest
diff --git a/dev-python/pyviz_comms/metadata.xml b/dev-python/pyviz_comms/metadata.xml
new file mode 100644
index 000000000..8127bb8b0
--- /dev/null
+++ b/dev-python/pyviz_comms/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+ <email>sci@gentoo.org</email>
+ <name>Gentoo Science Project</name>
+ </maintainer>
+ <stabilize-allarches/>
+ <upstream>
+ <remote-id type="pypi">pyviz_comms</remote-id>
+ <remote-id type="github">holoviz/pyviz_comms</remote-id>
+ </upstream>
+</pkgmetadata>
diff --git a/dev-python/pyviz_comms/pyviz_comms-2.0.1.ebuild b/dev-python/pyviz_comms/pyviz_comms-2.0.1.ebuild
new file mode 100644
index 000000000..df1d2bfe2
--- /dev/null
+++ b/dev-python/pyviz_comms/pyviz_comms-2.0.1.ebuild
@@ -0,0 +1,18 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Bidirectional communication for the HoloViz ecosystem"
+HOMEPAGE="https://holoviz.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="dev-python/param[${PYTHON_USEDEP}]"
diff --git a/profiles/profiles/default/linux/amd64/17.0/x32/package.mask b/profiles/profiles/default/linux/amd64/17.0/x32/package.mask
new file mode 100644
index 000000000..4f9228f91
--- /dev/null
+++ b/profiles/profiles/default/linux/amd64/17.0/x32/package.mask
@@ -0,0 +1,3 @@
+# Cecil Curry <leycec@gmail.com> (2021-10-07)
+# Panel requires Node.js, which fails to support the x32 ABI.
+dev-python/panel
reply other threads:[~2021-03-13 11:14 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1615633412.9e2b84ab3d6f8daa80a2c98981b8188ce750b6ec.andrewammerlaan@gentoo \
--to=andrewammerlaan@riseup.net \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox