[gentoo-commits] repo/gentoo:master commit in: dev-util/dput-ng/

["Ben Kohler" <bkohler@gentoo.org>]

commit:     e9da10babd47fccbc6ad05c463f6adbb62c774a6
Author:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
AuthorDate: Thu Mar 11 16:56:48 2021 +0000
Commit:     Ben Kohler <bkohler <AT> gentoo <DOT> org>
CommitDate: Thu Mar 11 17:03:15 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e9da10ba

dev-util/dput-ng: bump to 1.32

Closes: https://bugs.gentoo.org/771933
Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Ben Kohler <bkohler <AT> gentoo.org>

 dev-util/dput-ng/Manifest            |  1 +
 dev-util/dput-ng/dput-ng-1.32.ebuild | 89 ++++++++++++++++++++++++++++++++++++
 2 files changed, 90 insertions(+)

diff --git a/dev-util/dput-ng/Manifest b/dev-util/dput-ng/Manifest
index 8019c7511dc..627a37faa81 100644
--- a/dev-util/dput-ng/Manifest
+++ b/dev-util/dput-ng/Manifest
@@ -1 +1,2 @@
 DIST dput-ng_1.28.tar.xz 85276 BLAKE2B d205d15aad1b81dcf2cc0b765c9724b21add32df39102b63502d99e5da73aa95efdf66e94f6226105ab2ae97a4bf8c43963784f3ddf2d03217ab5023a7a98f22 SHA512 cfd4a6143b33f29eb32b88972a204ab7a6c2f062299c76167434322ae5d6d2cf8654c5b4d1e96db90dbffe372a04e2a7691694ecf46787c7743dd9ac2b7b317e
+DIST dput-ng_1.32.tar.xz 86280 BLAKE2B 7e195eab4f48d77968b866185e337f2b51113f7e11cfa4929d47e79082c2fa866af2c8394c50816b650f865db9ef244775618a05a6b398090366d342a45a3db7 SHA512 596247eecb2dce080cd6f3cd1ddb1364cfa00fc3048081149e4d6dc35822aee10fa10ec25ed91154b477a909cc29dcf17cb38ccefa649f40eb70c16e0a575b2e

diff --git a/dev-util/dput-ng/dput-ng-1.32.ebuild b/dev-util/dput-ng/dput-ng-1.32.ebuild
new file mode 100644
index 00000000000..62870638d55
--- /dev/null
+++ b/dev-util/dput-ng/dput-ng-1.32.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8,9} )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Next generation Debian package upload tool"
+HOMEPAGE="https://people.debian.org/~paultag/dput-ng/"
+SRC_URI="mirror://debian/pool/main/d/${PN}/${PN}_${PV}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/python-debian[${PYTHON_MULTI_USEDEP}]
+		dev-python/paramiko[${PYTHON_MULTI_USEDEP}]
+		dev-util/distro-info[python,${PYTHON_MULTI_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/nose[${PYTHON_MULTI_USEDEP}]
+			dev-python/python-debian[${PYTHON_MULTI_USEDEP}]
+		')
+		dev-util/debhelper
+	)"
+
+# Requires missing build-essential package
+RESTRICT="test"
+
+src_compile() {
+	distutils-r1_src_compile
+
+	mkdir man || die
+	for file in docs/man/*.man; do
+		a2x --doctype manpage --format manpage -D man \
+			"${file}" || die
+	done
+}
+
+src_install() {
+	local DPUT_BINARIES=( dcut dirt dput )
+	local DPUT_ETC=( metas profiles )
+	local DPUT_SHARE=(
+		codenames
+		commands
+		hooks
+		interfaces
+		schemas
+		uploaders
+	)
+
+	distutils-r1_src_install
+
+	for binary in ${DPUT_BINARIES[@]}; do
+		dobin bin/"${binary}"
+	done
+	python_fix_shebang "${D}"/usr/bin
+
+	insinto /etc/dput.d
+	for dir in ${DPUT_ETC[@]}; do
+		doins -r skel/"${dir}"
+	done
+
+	insinto /usr/share/"${PN}"
+	for dir in ${DPUT_SHARE[@]}; do
+		doins -r skel/"${dir}"
+	done
+
+	# doman incorrectly treats "cf" in dput.cf.5 as a lang code
+	doman -i18n="" man/*
+
+	newbashcomp debian/dcut-completion dcut
+	newbashcomp debian/dput-completion dput
+}
+
+python_test() {
+	# test_configs.py failing
+	# https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=824652
+	nosetests || die "Tests failed under ${EPYTHON}"
+}