[gentoo-commits] repo/gentoo:master commit in: dev-ruby/sassc/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     e0ce2477f053db0c4d0dd9f73156a45702979b6a
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Tue Mar  9 09:00:09 2021 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Tue Mar  9 09:00:30 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e0ce2477

dev-ruby/sassc: fix library loading on prefix

Closes: https://bugs.gentoo.org/768042
Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-ruby/sassc/sassc-2.2.1-r1.ebuild | 48 ++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/dev-ruby/sassc/sassc-2.2.1-r1.ebuild b/dev-ruby/sassc/sassc-2.2.1-r1.ebuild
new file mode 100644
index 00000000000..8dd3c00b8f4
--- /dev/null
+++ b/dev-ruby/sassc/sassc-2.2.1-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+USE_RUBY="ruby25 ruby26 ruby27"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_DOCDIR="doc"
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Use libsass with Ruby"
+HOMEPAGE="https://github.com/sass/sassc-ruby"
+LICENSE="MIT"
+
+KEYWORDS="~amd64 ~arm64"
+SLOT="2"
+IUSE=""
+
+RDEPEND+=">=dev-libs/libsass-3.6.1"
+
+ruby_add_rdepend "
+	>=dev-ruby/ffi-1.9.6
+"
+
+ruby_add_bdepend "test? (
+	dev-ruby/test_construct
+	dev-ruby/minitest-around
+)"
+
+all_ruby_prepare() {
+	# Use unbundled libsass
+	rm -rf ext || die
+
+	sed -i -e '/ffi_lib/ s:__dir__:"'${EROOT}'/usr/lib64":' \
+		lib/sassc/native.rb || die
+
+	# Avoid version-specific test so newer libsass versions can be used.
+	sed -i -e '/test_it_reports_the_libsass_version/,/end/ s:^:#:' test/native_test.rb || die
+
+	sed -i -e '/pry/ s:^:#:' test/test_helper.rb || die
+}
+
+each_ruby_test() {
+	${RUBY} -Ilib:.:test -e 'Dir["test/**/*_test.rb"].each{|f| require f}' || die
+}