[gentoo-commits] repo/gentoo:master commit in: x11-libs/xapps/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     1b483b16a74bbca8e071d25dcf8ddfd7664960c8
Author:     Matthew S. Turnbull <sparky <AT> bluefang-logic <DOT> com>
AuthorDate: Fri Jan  8 02:54:06 2021 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sun Jan 24 17:30:53 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1b483b16

x11-libs/xapps: 2.0.6 version bump

Bug: https://bugs.gentoo.org/757708
Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Matthew S. Turnbull <sparky <AT> bluefang-logic.com>
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 x11-libs/xapps/Manifest           |  1 +
 x11-libs/xapps/xapps-2.0.6.ebuild | 90 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 91 insertions(+)

diff --git a/x11-libs/xapps/Manifest b/x11-libs/xapps/Manifest
index 509a222c6e5..997e3e27e15 100644
--- a/x11-libs/xapps/Manifest
+++ b/x11-libs/xapps/Manifest
@@ -1 +1,2 @@
 DIST xapps-1.8.9.tar.gz 187789 BLAKE2B 37b2d2677cb6483533d79853a83d77b30033313c06db89e93491076bb017122f77cd97b30d5ba64ce53fb41a37736791e97da785f516953b76b1d979d341e2fc SHA512 95dd1cbf84b59adf6682d9025e0cfa7a414c24d4f584cde87d0cc6ea82c06338de2c320dad8d997e105980782ec5cb23f0def6f6d60ea84be7d74c90d7cd692c
+DIST xapps-2.0.6.tar.gz 231023 BLAKE2B bc3907966c132c683e75769f8f45839d45229c77933ef861f58b03a21cca15a4f3dd610acb6a19fc16d35ddb189340cdef80704e78c89a3e49659a2f82be121e SHA512 bac6e105e2b1e237958fb610a9bd697a023c10a45131da7dee984532986022895414d81849f53bc0007c319c2139c6d39474e2e7fd9ce4e53365517f4ba4f012

diff --git a/x11-libs/xapps/xapps-2.0.6.ebuild b/x11-libs/xapps/xapps-2.0.6.ebuild
new file mode 100644
index 00000000000..c46c8304e80
--- /dev/null
+++ b/x11-libs/xapps/xapps-2.0.6.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2-utils vala meson python-r1 xdg-utils
+
+DESCRIPTION="Cross-desktop libraries and common resources"
+HOMEPAGE="https://github.com/linuxmint/xapp/"
+LICENSE="GPL-3"
+
+SRC_URI="https://github.com/linuxmint/xapp/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/xapp-${PV}"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+SLOT="0"
+IUSE="gtk-doc introspection static-libs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.44.0:2
+	dev-libs/gobject-introspection:0=
+	dev-libs/libdbusmenu[gtk3]
+	gnome-base/libgnomekbd
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.22.0:2[introspection?]
+	>=x11-libs/gtk+-3.16.0:3[introspection?]
+	x11-libs/libxkbfile
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.40.6
+	sys-devel/gettext
+
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	xdg_environment_reset
+	vala_src_prepare
+	default
+
+	# don't install distro specific tools
+	sed -i "/subdir('scripts')/d" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dpy-overrides-dir="/pygobject"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# copy pygobject files to each active python target
+	# work-around for "py-overrides-dir" only supporting a single target
+	install_pygobject_override() {
+		PYTHON_GI_OVERRIDESDIR=$("${EPYTHON}" -c 'import gi;print(gi._overridesdir)' || die)
+		einfo "gobject overrides directory: ${PYTHON_GI_OVERRIDESDIR}"
+		mkdir -p "${ED}/${PYTHON_GI_OVERRIDESDIR}/" || die
+		cp -r "${D}"/pygobject/* "${ED}/${PYTHON_GI_OVERRIDESDIR}/" || die
+		python_optimize "${ED}/${PYTHON_GI_OVERRIDESDIR}/"
+	}
+	python_foreach_impl install_pygobject_override
+	rm -r "${D}/pygobject" || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	gnome2_schemas_update
+}