[gentoo-commits] proj/kde:master commit in: kde-plasma/libksysguard/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     ce52ae9101892943565d2246b363af432e4143e1
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Fri Jan 22 23:31:52 2021 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Jan 22 23:58:45 2021 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=ce52ae91

kde-plasma/libksysguard: 5.20.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../libksysguard/libksysguard-5.20.90.ebuild       | 69 ++++++++++++++++++++++
 1 file changed, 69 insertions(+)

diff --git a/kde-plasma/libksysguard/libksysguard-5.20.90.ebuild b/kde-plasma/libksysguard/libksysguard-5.20.90.ebuild
new file mode 100644
index 0000000000..8fe421d7b8
--- /dev/null
+++ b/kde-plasma/libksysguard/libksysguard-5.20.90.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_DESIGNERPLUGIN="true"
+ECM_TEST="true"
+KFMIN=5.78.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org
+
+DESCRIPTION="Task management and system monitoring library"
+LICENSE="LGPL-2+"
+SLOT="5/9"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="webengine X"
+
+RDEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/kpackage-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	sys-libs/zlib
+	webengine? (
+		>=dev-qt/qtwebchannel-${QTMIN}:5
+		>=dev-qt/qtwebengine-${QTMIN}:5
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libXres
+	)
+"
+DEPEND="${RDEPEND}
+	!<kde-plasma/plasma-workspace-5.18.80:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	X? ( x11-base/xorg-proto )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.16.0-no-detailed-mem-message.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package webengine Qt5WebChannel)
+		$(cmake_use_find_package webengine Qt5WebEngineWidgets)
+		$(cmake_use_find_package X X11)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	LC_NUMERIC="C" ecm_src_test # bug 695514
+}