[gentoo-commits] repo/gentoo:master commit in: sci-libs/lrslib/

["David Seifert" <soap@gentoo.org>]

commit:     27562468d1d9d10a37e3a791b698055504909626
Author:     Jakov Smolic <jakov.smolic <AT> sartura <DOT> hr>
AuthorDate: Tue Jan 12 10:48:45 2021 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Tue Jan 12 10:48:45 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=27562468

sci-libs/lrslib: Bump to 071

Closes: https://github.com/gentoo/gentoo/pull/18951
Closes: https://bugs.gentoo.org/707612
Signed-off-by: Jakov Smolic <jakov.smolic <AT> sartura.hr>
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 sci-libs/lrslib/Manifest          |  1 +
 sci-libs/lrslib/lrslib-071.ebuild | 51 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+)

diff --git a/sci-libs/lrslib/Manifest b/sci-libs/lrslib/Manifest
index e6fd1344b66..65d38903cb3 100644
--- a/sci-libs/lrslib/Manifest
+++ b/sci-libs/lrslib/Manifest
@@ -1 +1,2 @@
 DIST lrslib-062.tar.gz 292745 BLAKE2B 1a2c0e264d590c38d83ee35616b1ec36d8a093b5c7f08179019261d8b321d5b95d8889ca6555ae69853f919d6d66358a865a8a2002516dfd560bec6658f3913d SHA512 1d644a7798580457ff266730f42f6fac317ec8cdf2509ad6028e7a838e5c4c948bd0f9499b840c227bad4269f7144ff72b87fe3a19bdb9ad0925ebe4a7bc4f9f
+DIST lrslib-071.tar.gz 460165 BLAKE2B 67be1ffac1c09a94773c69fc2215db19623bc8bc78be74342a1eda497b70eed2d8cb8e9b34ce269177154a4aed6f7bde02f632a536999b24f3116b3e69be456e SHA512 451aa5dada106516aeed1688c1e939a2e216ac760addb483f9cc1d5d4ac62e88af2772a6fa589b217b544621d041d94386a79502483db2eeaf04e90c4a3fd78e

diff --git a/sci-libs/lrslib/lrslib-071.ebuild b/sci-libs/lrslib/lrslib-071.ebuild
new file mode 100644
index 00000000000..1d033c0eef9
--- /dev/null
+++ b/sci-libs/lrslib/lrslib-071.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Self-contained C implementation of the reverse search algorithm"
+HOMEPAGE="http://cgm.cs.mcgill.ca/~avis/C/lrs.html"
+SRC_URI="http://cgm.cs.mcgill.ca/~avis/C/lrslib/archive/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="gmp mpi"
+
+RDEPEND="
+	gmp? (
+		dev-libs/gmp:0=
+		mpi? ( virtual/mpi )
+	)"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	tc-export CC
+	sed -e "s/-O3/${CFLAGS}/g" \
+		-e 's/$(CC) -shared/$(CC) $(LDFLAGS) -shared/' \
+		-e "s,/usr/local,${EPREFIX}/usr,g" \
+		-e "s,/lib,/$(get_libdir),g" \
+		-i makefile || die
+}
+
+src_compile() {
+	if use gmp ; then
+		emake
+		emake all-shared
+		use mpi && emake mplrs
+	else
+		emake allmp
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" prefix="${EPREFIX}/usr" install-common
+	if use gmp; then
+		emake DESTDIR="${D}" prefix="${EPREFIX}/usr" install
+		use mpi && dobin mplrs
+	fi
+	dodoc README
+}