[gentoo-commits] repo/gentoo:master commit in: dev-util/devhelp/

["Matt Turner" <mattst88@gentoo.org>]

commit:     0c35c774d501e9674a60e30b45db4eab169349de
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sun Jan  3 16:50:40 2021 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Tue Jan  5 18:29:52 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0c35c774

dev-util/devhelp: Version bump to 3.38.1

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 dev-util/devhelp/Manifest              |  1 +
 dev-util/devhelp/devhelp-3.38.1.ebuild | 80 ++++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/dev-util/devhelp/Manifest b/dev-util/devhelp/Manifest
index 68b62d3dbad..2c3e666f0fc 100644
--- a/dev-util/devhelp/Manifest
+++ b/dev-util/devhelp/Manifest
@@ -1 +1,2 @@
 DIST devhelp-3.36.2.tar.xz 302996 BLAKE2B 61131c7bedfe6803c04315138b017145e7ad7cc2939022a4cfcd0c65f4f3144db705a4a918a4ecd6a6fcea2a5dce64a891d951ccfc21dec0421991455b81ad16 SHA512 8852546b8ff337c2448a88b931803029825e34a6cf906370c683ac004866a548c9de79c934fde36ec04584f0bdc59eee4184b9ed8a480303eb78b9c9d43eb55e
+DIST devhelp-3.38.1.tar.xz 313948 BLAKE2B bd070c98e92a8968ffbac7e634c19730e7c63ee18d180a5d9dda7d831b28deea49a7aa50b17ca9a8b5a411276ac055074cb76ef8cde5017ca395d49bf4aecdf6 SHA512 bcdd61cd822ae3fbe2c9542c09d058760fc1fa0bbbd55b1fc0853b4fdbf1c3856d4fed8f2263f94f41096cbdc0a76394773d43a9072d8aa89274fa61a3c2a430

diff --git a/dev-util/devhelp/devhelp-3.38.1.ebuild b/dev-util/devhelp/devhelp-3.38.1.ebuild
new file mode 100644
index 00000000000..1f28178306e
--- /dev/null
+++ b/dev-util/devhelp/devhelp-3.38.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="An API documentation browser for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Devhelp"
+
+LICENSE="GPL-3+ CC-BY-SA-4.0"
+SLOT="0/3-6" # subslot = 3-(libdevhelp-3 soname version)
+KEYWORDS="~amd64 ~arm ~ppc64 ~sparc ~x86"
+IUSE="gedit gtk-doc +introspection"
+REQUIRED_USE="gedit? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	>=dev-libs/glib-2.64:2
+	>=x11-libs/gtk+-3.22:3[introspection?]
+	>=net-libs/webkit-gtk-2.24:4[introspection?]
+	>=gui-libs/amtk-5.0:5
+	gnome-base/gsettings-desktop-schemas
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	gedit? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			app-editors/gedit[introspection(+),python,${PYTHON_SINGLE_USEDEP}]
+			dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+# libxml2 required for glib-compile-resources
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	dev-util/itstool
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.25
+		app-text/docbook-xml-dtd:4.3 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}"/3.30.1-optional-introspection.patch
+	"${FILESDIR}"/3.30.1-optional-gedit.patch
+)
+
+pkg_setup() {
+	use gedit && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dflatpak_build=false
+		$(meson_use gedit gedit_plugin)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	use gedit && python_optimize "${ED}"/usr/$(get_libdir)/gedit/plugins
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}