[gentoo-commits] repo/proj/guru:master commit in: app-text/OCRmyPDF/

["Andrew Ammerlaan" <andrewammerlaan@riseup.net>]

commit:     26291fb21890a8e36dc276cde42a9971d1e89d54
Author:     Theo Anderson <telans <AT> posteo <DOT> de>
AuthorDate: Thu Dec 31 08:21:08 2020 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> riseup <DOT> net>
CommitDate: Thu Dec 31 08:21:08 2020 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=26291fb2

app-text/OCRmyPDF: bump to 11.4.3

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Theo Anderson <telans <AT> posteo.de>

 app-text/OCRmyPDF/Manifest               |  1 +
 app-text/OCRmyPDF/OCRmyPDF-11.4.3.ebuild | 67 ++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)

diff --git a/app-text/OCRmyPDF/Manifest b/app-text/OCRmyPDF/Manifest
index 3e241f2b..d190c20c 100644
--- a/app-text/OCRmyPDF/Manifest
+++ b/app-text/OCRmyPDF/Manifest
@@ -1,2 +1,3 @@
 DIST OCRmyPDF-11.4.0.tar.gz 7880918 BLAKE2B 2031a0d8f5676d84be7e4d52a2b8457143dfb85248bc925d452ebe652190da0f34a464478a9cda8ed0650eeb5db5019f83530ea0b74b57079e1cab0e43a20b16 SHA512 f6ed03eacf3dd0aa554841b70e6b2fbb8a7cc7854723a4fb0a52b7b3fcf26387f9bb60b9db57f67af53a979edc66666a3dadbdd10c20fbb375cfaf46339e6737
 DIST OCRmyPDF-11.4.1.tar.gz 7880882 BLAKE2B 80bcce4775e9192cc23f0b9ed0ba8fcbb4b585c628b796f69b60d2e84bcf8157812cf5fa769688af1e71626d41ba249d56ac5cc6bcf4f4fc3a60fa4b5809320b SHA512 bd27d66b24b63584d1945fd29b08e4d8dcffd989b7285ec0d94559514da676cbb7cd6910453d553f859d501ce5a10bb90554574f0e435bbf6d4037d89d0dd4aa
+DIST OCRmyPDF-11.4.3.tar.gz 7883284 BLAKE2B e127dbb60bf18c152f9725fa097897aa5392c8db71f5540f3410e07327b6a7de4536d38ff6bda25eb29e3ced768ab86a9e6a6b5510f09dfa031dba4e0953cc92 SHA512 d40587a1e38b9f3adabb3c144fae0436eeab01f9c01de87c47e5b2b7fe1c5df85b9ade60daadff6177574d9933c61dad9df9602a5f46880a077991e2a9ab8ca4

diff --git a/app-text/OCRmyPDF/OCRmyPDF-11.4.3.ebuild b/app-text/OCRmyPDF/OCRmyPDF-11.4.3.ebuild
new file mode 100644
index 00000000..09e6ae28
--- /dev/null
+++ b/app-text/OCRmyPDF/OCRmyPDF-11.4.3.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="OCRmyPDF adds an OCR text layer to scanned PDF files"
+HOMEPAGE="https://github.com/jbarlow83/OCRmyPDF"
+SRC_URI="https://github.com/jbarlow83/OCRmyPDF/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# This uses *a lot* of RAM, I have 32gb and these tests tried to use it all
+RESTRICT="test"
+IUSE="jbig2enc"
+
+RDEPEND="
+	app-text/ghostscript-gpl
+	app-text/tesseract
+	app-text/unpaper
+	dev-python/cffi[${PYTHON_USEDEP}]
+	dev-python/coloredlogs[${PYTHON_USEDEP}]
+	>=dev-python/pdfminer-six-20191110[${PYTHON_USEDEP}]
+	<=dev-python/pdfminer-six-20201018[${PYTHON_USEDEP}]
+	dev-python/pikepdf[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/reportlab[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+	jbig2enc? ( media-libs/jbig2enc )
+	media-gfx/img2pdf[${PYTHON_USEDEP}]
+	media-gfx/pngquant
+	media-libs/leptonica
+	virtual/python-cffi[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		~dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs --no-autodoc
+
+python_prepare_all() {
+	# do not depend on deprecated dep
+	sed -i -e '/pytest-runner/d' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	newbashcomp "${S}"/misc/completion/ocrmypdf.bash "${PN,,}"
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins "${S}"/misc/completion/ocrmypdf.fish
+}