[gentoo-commits] repo/gentoo:master commit in: dev-python/pyilmbase/

["Sam James" <sam@gentoo.org>]

commit:     ee2e85cf3fe33d4535b3b7149d5ff2f66c4a6aa1
Author:     Bernd Waibel <waebbl <AT> gmail <DOT> com>
AuthorDate: Mon Dec 21 23:36:27 2020 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Dec 27 21:40:15 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ee2e85cf

dev-python/pyilmbase: bump to 2.5.3

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Bernd Waibel <waebbl <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/18755
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/pyilmbase/Manifest               |  1 +
 dev-python/pyilmbase/pyilmbase-2.5.3.ebuild | 62 +++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/dev-python/pyilmbase/Manifest b/dev-python/pyilmbase/Manifest
index fd35c16a42c..6880958cedc 100644
--- a/dev-python/pyilmbase/Manifest
+++ b/dev-python/pyilmbase/Manifest
@@ -1 +1,2 @@
 DIST pyilmbase-2.5.2.tar.gz 27525326 BLAKE2B c48a61513457f2c04f3a512963ae27eaf154933ffe7c6ff3e2d71f27f246ae624a34dbe6f8ab500c51a56898ad0f61e6784f5cd3f9c3df591ce347b46ba4ac88 SHA512 62f98695cf56600303db9c2d13d34cacc1851a103d8ffb7e7ce8c6d9d14e6bf02804836c718ae03e8d685ef3dda0cf7b2130e2d363f8095b22a15bf30d706fab
+DIST pyilmbase-2.5.3.tar.gz 27534825 BLAKE2B 4647b4aac074b10c0d1fb35ddb6b5acefca81c0f2debde04987b5df4e290b14b6406fc922949449aaeea7cf4be371a25c93f8fcb9f67c63d65276340bd586a21 SHA512 6da03193d4fea1e97e35008f59304ab408c521ead8495ba411cde5c172cf953be97999971f57398b813d14f1af1d722539a6b74d5ee54b9e74769ea8258d36ba

diff --git a/dev-python/pyilmbase/pyilmbase-2.5.3.ebuild b/dev-python/pyilmbase/pyilmbase-2.5.3.ebuild
new file mode 100644
index 00000000000..d755ffeb135
--- /dev/null
+++ b/dev-python/pyilmbase/pyilmbase-2.5.3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+inherit cmake python-single-r1
+
+DESCRIPTION="IlmBase Python bindings"
+HOMEPAGE="https://www.openexr.com"
+SRC_URI="https://github.com/AcademySoftwareFoundation/openexr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/25"
+KEYWORDS="~amd64 ~x86"
+IUSE="exceptions +numpy test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	~media-libs/ilmbase-${PV}:=
+	sys-libs/zlib
+	$(python_gen_cond_dep '
+		>=dev-libs/boost-1.62.0-r1:=[python,${PYTHON_MULTI_USEDEP}]
+		numpy? ( >=dev-python/numpy-1.10.4[${PYTHON_MULTI_USEDEP}] )
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-admin/chrpath
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/openexr-${PV}/PyIlmBase"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.5.2-0001-Fix-pkgconfig-file-for-PyIlmBase-to-include-prefixes.patch
+)
+
+DOCS=( README.md )
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Python2=ON
+		-DPYILMBASE_INSTALL_PKG_CONFIG=ON
+		-DPYIMATH_ENABLE_EXCEPTIONS=$(usex exceptions)
+		-DPython3_EXECUTABLE="${PYTHON}"
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	if use numpy; then
+		python_domodule "${BUILD_DIR}/${EPYTHON/./_}/imathnumpy.so"
+		chmod +x "${D}/$(python_get_sitedir)/imathnumpy.so" || die
+		chrpath -d "${D}/$(python_get_sitedir)/imathnumpy.so" || die
+	fi
+}