[gentoo-commits] repo/gentoo:master commit in: media-libs/opencolorio/

["Sam James" <sam@gentoo.org>]

commit:     a0f8069f8082e032d77bf4e1a7417ad7acadaa6f
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 23 21:56:28 2020 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Dec 23 21:56:28 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a0f8069f

media-libs/opencolorio: cleanup old

Closes: https://bugs.gentoo.org/754909
Package-Manager: Portage-3.0.12-prefix, Repoman-3.0.2
Signed-off-by: Sam James <sam <AT> gentoo.org>

 media-libs/opencolorio/Manifest                    |  1 -
 media-libs/opencolorio/opencolorio-1.1.0-r4.ebuild | 94 ----------------------
 2 files changed, 95 deletions(-)

diff --git a/media-libs/opencolorio/Manifest b/media-libs/opencolorio/Manifest
index 251465032f2..c7ac45d7ec9 100644
--- a/media-libs/opencolorio/Manifest
+++ b/media-libs/opencolorio/Manifest
@@ -1,2 +1 @@
-DIST opencolorio-1.1.0.tar.gz 13826812 BLAKE2B 555a5ac393170503c944c3471ea482b1a22be7c98ee7b81af37f52db185c8b61c5318102c139a8711f4828d306b6c4322f5d839c4df08ce41ebbb9dcb2bda152 SHA512 909874a9f91a8d229622810fc70233680c6e75203bd8555179322de2873da00bf302432e19f189b787ffcda3157ddec1e4601c97f75a36e16f644fe7d42f6998
 DIST opencolorio-1.1.1.tar.gz 13828483 BLAKE2B f5642f08db84f2b8da44d0dbf58313c78263496fc6f1f209b93fd303bbf9477033317b44eb8bb2b13a70afa19422f4fa312d52a3fa6598031a2aa50b33bbfccf SHA512 bed722f9ddce1887d28aacef2882debccd7c3f3c0c708d2723fea58a097de9f02721af9e85453e089ffda5406aef593ab6536c6886307823c132aa787e492e33

diff --git a/media-libs/opencolorio/opencolorio-1.1.0-r4.ebuild b/media-libs/opencolorio/opencolorio-1.1.0-r4.ebuild
deleted file mode 100644
index 1bb1af8e32c..00000000000
--- a/media-libs/opencolorio/opencolorio-1.1.0-r4.ebuild
+++ /dev/null
@@ -1,94 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{6,7} )
-
-inherit cmake flag-o-matic python-single-r1
-
-DESCRIPTION="A color management framework for visual effects and animation"
-HOMEPAGE="https://opencolorio.org/"
-
-SRC_URI="https://github.com/imageworks/OpenColorIO/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="cpu_flags_x86_sse2 doc opengl python static-libs test"
-REQUIRED_USE="
-	doc? ( python )
-	python? ( ${PYTHON_REQUIRED_USE} )"
-
-RDEPEND="
-	opengl? (
-		media-libs/lcms:2
-		media-libs/openimageio
-		media-libs/glew:=
-		media-libs/freeglut
-		virtual/opengl
-	)
-	python? ( ${PYTHON_DEPS} )
-	>=dev-cpp/yaml-cpp-0.5
-	dev-libs/tinyxml
-"
-
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	doc? (
-		$(python_gen_cond_dep '
-			dev-python/sphinx[${PYTHON_MULTI_USEDEP}]
-		')
-	)
-"
-
-# Restricting tests, bugs #439790 and #447908
-RESTRICT="test"
-
-PATCHES=(
-	"${FILESDIR}/${P}-fix-compile-error-with-Lut1DOp.cpp.patch"
-	"${FILESDIR}/${P}-use-GNUInstallDirs-and-fix-cmake-install-location.patch"
-	"${FILESDIR}/${P}-remove-building-of-bundled-programs.patch"
-	"${FILESDIR}/${P}-yaml-cpp-0.6.patch"
-	"${FILESDIR}/${P}-remove-Werror.patch"
-)
-
-S="${WORKDIR}/OpenColorIO-${PV}"
-
-pkg_setup() {
-	use python && python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	cmake_src_prepare
-
-	use python && python_fix_shebang .
-}
-
-src_configure() {
-	# Missing features:
-	# - Truelight and Nuke are not in portage for now, so their support are disabled
-	# - Java bindings was not tested, so disabled
-	# Notes:
-	# - OpenImageIO is required for building ociodisplay and ocioconvert (USE opengl)
-	# - OpenGL, GLUT and GLEW is required for building ociodisplay (USE opengl)
-	local mycmakeargs=(
-		-DOCIO_BUILD_JNIGLUE=OFF
-		-DOCIO_BUILD_NUKE=OFF
-		-DOCIO_BUILD_SHARED=ON
-		-DOCIO_BUILD_STATIC=$(usex static-libs)
-		-DOCIO_STATIC_JNIGLUE=OFF
-		-DOCIO_BUILD_TRUELIGHT=OFF
-		-DUSE_EXTERNAL_LCMS=ON
-		-DUSE_EXTERNAL_TINYXML=ON
-		-DUSE_EXTERNAL_YAML=ON
-		-DOCIO_BUILD_DOCS=$(usex doc)
-		-DOCIO_BUILD_APPS=$(usex opengl)
-		-DOCIO_BUILD_PYGLUE=$(usex python)
-		-DOCIO_USE_SSE=$(usex cpu_flags_x86_sse2)
-		-DOCIO_BUILD_TESTS=$(usex test)
-	)
-	use doc && mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_LATEX=ON ) # broken
-	cmake_src_configure
-}