[gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/

public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2020-12-23 14:52 Marek Szuba
  0 siblings, 0 replies; 17+ messages in thread
From: Marek Szuba @ 2020-12-23 14:52 UTC (permalink / raw
  To: gentoo-commits

commit:     9779b52e313a262749f46dbb6522623218c26a38
Author:     Marek Szuba <marecki <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 23 12:21:51 2020 +0000
Commit:     Marek Szuba <marecki <AT> gentoo <DOT> org>
CommitDate: Wed Dec 23 14:52:03 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9779b52e

games-strategy/megaglest-3.11.1-r1: stick with older megaglest-data

Must use the one still installing data files into /usr/games.

Signed-off-by: Marek Szuba <marecki <AT> gentoo.org>

 games-strategy/megaglest/megaglest-3.11.1-r1.ebuild | 2 ++
 1 file changed, 2 insertions(+)

diff --git a/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild b/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
index ca99c5450f1..86e78fb0535 100644
--- a/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
+++ b/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
@@ -17,8 +17,10 @@ SLOT="0"
 KEYWORDS="~amd64 ~x86"
 IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 static +streflop +tools +unicode wxuniversal +model-viewer videos"
 
+# Newer versions of megaglest-data install directly into /usr
 RDEPEND="
 	~games-strategy/${PN}-data-${PV}
+	<games-strategy/${PN}-data-3.11.1-r1
 	>=dev-lang/lua-5.1:0
 	dev-libs/libxml2
 	media-libs/fontconfig


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2024-07-05 17:49 Pacho Ramos
  0 siblings, 0 replies; 17+ messages in thread
From: Pacho Ramos @ 2024-07-05 17:49 UTC (permalink / raw
  To: gentoo-commits

commit:     d919c9d9c6cb23b2aec783a9e098daef20d88c5a
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Fri Jul  5 17:24:31 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Fri Jul  5 17:48:53 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d919c9d9

games-strategy/megaglest: drop 3.13.0, 3.13.0-r1

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 .../megaglest/megaglest-3.13.0-r1.ebuild           | 173 ---------------------
 games-strategy/megaglest/megaglest-3.13.0.ebuild   | 144 -----------------
 2 files changed, 317 deletions(-)

diff --git a/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild b/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild
deleted file mode 100644
index 26f172483f1e..000000000000
--- a/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild
+++ /dev/null
@@ -1,173 +0,0 @@
-# Copyright 2010-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# Todo: google-breakpad?
-
-EAPI=8
-
-# src_install() currently requires this
-CMAKE_MAKEFILE_GENERATOR="emake"
-
-LUA_COMPAT=( lua5-{1..4} )
-
-# Only needed by certain features
-VIRTUALX_REQUIRED="manual"
-
-WX_GTK_VER="3.0-gtk3"
-inherit cmake desktop flag-o-matic lua-single readme.gentoo-r1 virtualx wxwidgets xdg-utils
-
-DESCRIPTION="Cross-platform 3D realtime strategy game"
-HOMEPAGE="https://megaglest.org/ https://github.com/MegaGlest/megaglest-source"
-SRC_URI="https://github.com/MegaGlest/megaglest-source/releases/download/${PV}/megaglest-source-${PV}.tar.xz
-	https://github.com/MegaGlest/megaglest-source/commit/789e1cdf.patch -> ${P}-789e1cdf.patch
-	https://github.com/MegaGlest/megaglest-source/commit/5801b1fa.patch -> ${P}-5801b1fa.patch
-	https://github.com/MegaGlest/megaglest-source/commit/412b37d0.patch -> ${P}-412b37d0.patch
-	https://github.com/MegaGlest/megaglest-source/commit/e09ba53c.patch -> ${P}-e09ba53c.patch
-	https://github.com/MegaGlest/megaglest-source/commit/fbd0cfb1.patch -> ${P}-fbd0cfb1.patch
-"
-
-LICENSE="GPL-3 BitstreamVera"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 +streflop +tools +unicode wxuniversal +model-viewer videos"
-
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-
-COMMON_DEPEND="
-	${LUA_DEPS}
-	dev-libs/libxml2
-	dev-libs/xerces-c[icu]
-	media-libs/fontconfig
-	media-libs/freetype
-	media-libs/ftgl
-	media-libs/glew:=
-	net-libs/libircclient
-	media-libs/libpng:0
-	media-libs/libsdl2[X,sound,joystick,opengl,video]
-	media-libs/libvorbis
-	media-libs/openal
-	net-libs/gnutls:=
-	net-libs/miniupnpc:=
-	net-misc/curl
-	sys-libs/zlib
-	virtual/opengl
-	virtual/glu
-	virtual/jpeg:0=
-	x11-libs/libX11
-	x11-libs/libXext
-	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
-	fribidi? ( dev-libs/fribidi )
-	model-viewer? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
-	videos? ( media-video/vlc )
-"
-DEPEND="${COMMON_DEPEND}"
-RDEPEND="
-	${COMMON_DEPEND}
-	~games-strategy/${PN}-data-${PV}
-"
-
-BDEPEND="sys-apps/help2man
-	virtual/pkgconfig
-	editor? ( ${VIRTUALX_DEPEND} )
-	model-viewer? ( ${VIRTUALX_DEPEND} )"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-3.11.1-cmake-lua.patch"
-
-	# From Fedora and Arch
-	"${FILESDIR}/${P}-underlink.patch"
-	"${FILESDIR}/${P}-fix-lua-version-ordering.patch"
-	"${FILESDIR}/${P}-multiple-definitions.patch"
-	"${FILESDIR}/${P}-GLEW_ERROR_NO_GLX_DISPLAY.patch"
-	"${FILESDIR}/${P}-help2man.patch"
-
-	# Fix build with wxWidgets 3.2
-	"${DISTDIR}/${P}-789e1cdf.patch"
-	"${DISTDIR}/${P}-5801b1fa.patch"
-	"${DISTDIR}/${P}-412b37d0.patch"
-	"${DISTDIR}/${P}-e09ba53c.patch"
-	"${FILESDIR}/${P}-fbd0cfb1.patch"
-)
-
-DISABLE_AUTOFORMATTING="yes"
-DOC_CONTENTS="DO NOT directly edit glest.ini and glestkeys.ini but rather glestuser.ini
-and glestuserkeys.ini in ~/.megaglest/ and create your user over-ride
-values in these files.
-
-If you have an older graphics card which only supports OpenGL 1.2, and the
-game crashes when you try to play, try starting with 'megaglest --disable-vbo'
-Some graphics cards may require setting Max Lights to 1.
-"
-
-src_prepare() {
-	cmake_src_prepare
-
-	if use editor || use model-viewer ; then
-		setup-wxwidgets
-	fi
-}
-
-src_configure() {
-	# -Werror=odr
-	# https://bugs.gentoo.org/926143
-	# https://github.com/MegaGlest/megaglest-source/issues/275
-	filter-lto
-
-	if use cpu_flags_x86_sse3; then
-		SSE=3
-	elif use cpu_flags_x86_sse2; then
-		SSE=2
-	elif use cpu_flags_x86_sse; then
-		SSE=1
-	else
-		SSE=0
-	fi
-
-	local mycmakeargs=(
-		-DWANT_GIT_STAMP=OFF
-		-DWANT_USE_FriBiDi="$(usex fribidi)"
-		-DBUILD_MEGAGLEST_MAP_EDITOR="$(usex editor)"
-		-DBUILD_MEGAGLEST_MODEL_IMPORT_EXPORT_TOOLS="$(usex tools)"
-		-DBUILD_MEGAGLEST_MODEL_VIEWER="$(usex model-viewer)"
-		-DWANT_USE_VLC="$(usex videos)"
-		-DFORCE_LUA_VERSION="$(lua_get_version)"
-		-DFORCE_MAX_SSE_LEVEL="${SSE}"
-		-DWANT_USE_FTGL=ON
-		-DWANT_STATIC_LIBS=OFF
-		-DWANT_USE_STREFLOP="$(usex streflop)"
-		-DwxWidgets_USE_STATIC=OFF
-		-DwxWidgets_USE_UNICODE="$(usex unicode)"
-		-DwxWidgets_USE_UNIVERSAL="$(usex wxuniversal)"
-
-		$(usex debug "-DBUILD_MEGAGLEST_UPNP_DEBUG=ON -DwxWidgets_USE_DEBUG=ON" "")
-	)
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile
-}
-
-src_install() {
-	# rebuilds some targets randomly without fast option
-	emake -C "${BUILD_DIR}" DESTDIR="${D}" "$@" install/fast
-
-	dodoc docs/{AUTHORS.source_code,CHANGELOG,README}.txt
-
-	use editor &&
-		make_desktop_entry ${PN}_editor "MegaGlest Map Editor"
-	use model-viewer &&
-		make_desktop_entry ${PN}_g3dviewer "MegaGlest Model Viewer"
-
-	readme.gentoo_create_doc
-	einstalldocs
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-	readme.gentoo_print_elog
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-}

diff --git a/games-strategy/megaglest/megaglest-3.13.0.ebuild b/games-strategy/megaglest/megaglest-3.13.0.ebuild
deleted file mode 100644
index 1a07d154d993..000000000000
--- a/games-strategy/megaglest/megaglest-3.13.0.ebuild
+++ /dev/null
@@ -1,144 +0,0 @@
-# Copyright 2010-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# Todo: google-breakpad?
-
-EAPI=7
-
-# src_install() currently requires this
-CMAKE_MAKEFILE_GENERATOR="emake"
-
-LUA_COMPAT=( lua5-{1..2} )
-
-# Only needed by certain features
-VIRTUALX_REQUIRED="manual"
-
-WX_GTK_VER="3.0-gtk3"
-inherit cmake desktop flag-o-matic lua-single virtualx wxwidgets xdg-utils
-
-DESCRIPTION="Cross-platform 3D realtime strategy game"
-HOMEPAGE="https://megaglest.org/ https://github.com/MegaGlest/megaglest-source"
-SRC_URI="https://github.com/MegaGlest/megaglest-source/releases/download/${PV}/megaglest-source-${PV}.tar.xz"
-
-LICENSE="GPL-3 BitstreamVera"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 +streflop +tools +unicode wxuniversal +model-viewer videos"
-
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-
-RDEPEND="
-	${LUA_DEPS}
-	~games-strategy/${PN}-data-${PV}
-	dev-libs/libxml2
-	dev-libs/xerces-c[icu]
-	media-libs/fontconfig
-	media-libs/freetype
-	media-libs/ftgl
-	media-libs/glew:=
-	net-libs/libircclient
-	media-libs/libpng:0
-	media-libs/libsdl2[X,sound,joystick,opengl,video]
-	media-libs/libvorbis
-	media-libs/openal
-	net-libs/gnutls:=
-	net-libs/miniupnpc:=
-	net-misc/curl
-	sys-libs/zlib
-	virtual/opengl
-	virtual/glu
-	virtual/jpeg:0=
-	x11-libs/libX11
-	x11-libs/libXext
-	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
-	fribidi? ( dev-libs/fribidi )
-	model-viewer? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
-	videos? ( media-video/vlc )
-"
-DEPEND="${RDEPEND}"
-
-BDEPEND="sys-apps/help2man
-	virtual/pkgconfig
-	editor? ( ${VIRTUALX_DEPEND} )
-	model-viewer? ( ${VIRTUALX_DEPEND} )"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-3.11.1-cmake-lua.patch"
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	if use editor || use model-viewer ; then
-		setup-wxwidgets
-	fi
-}
-
-src_configure() {
-	# See https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
-	append-cflags -fcommon
-
-	if use cpu_flags_x86_sse3; then
-		SSE=3
-	elif use cpu_flags_x86_sse2; then
-		SSE=2
-	elif use cpu_flags_x86_sse; then
-		SSE=1
-	else
-		SSE=0
-	fi
-
-	local mycmakeargs=(
-		-DWANT_USE_FriBiDi="$(usex fribidi)"
-		-DBUILD_MEGAGLEST_MAP_EDITOR="$(usex editor)"
-		-DBUILD_MEGAGLEST_MODEL_IMPORT_EXPORT_TOOLS="$(usex tools)"
-		-DBUILD_MEGAGLEST_MODEL_VIEWER="$(usex model-viewer)"
-		-DWANT_USE_VLC="$(usex videos)"
-		-DFORCE_LUA_VERSION="$(lua_get_version)"
-		-DFORCE_MAX_SSE_LEVEL="${SSE}"
-		-DWANT_USE_FTGL=ON
-		-DWANT_STATIC_LIBS=OFF
-		-DWANT_USE_STREFLOP="$(usex streflop)"
-		-DwxWidgets_USE_STATIC=OFF
-		-DwxWidgets_USE_UNICODE="$(usex unicode)"
-		-DwxWidgets_USE_UNIVERSAL="$(usex wxuniversal)"
-
-		$(usex debug "-DBUILD_MEGAGLEST_UPNP_DEBUG=ON -DwxWidgets_USE_DEBUG=ON" "")
-	)
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile
-}
-
-src_install() {
-	# rebuilds some targets randomly without fast option
-	emake -C "${BUILD_DIR}" DESTDIR="${D}" "$@" install/fast
-
-	dodoc docs/{AUTHORS.source_code,CHANGELOG,README}.txt
-
-	use editor &&
-		make_desktop_entry ${PN}_editor "MegaGlest Map Editor"
-	use model-viewer &&
-		make_desktop_entry ${PN}_g3dviewer "MegaGlest Model Viewer"
-}
-
-pkg_postinst() {
-	einfo
-	elog 'Note about Configuration:'
-	elog 'DO NOT directly edit glest.ini and glestkeys.ini but rather glestuser.ini'
-	elog 'and glestuserkeys.ini in ~/.megaglest/ and create your user over-ride'
-	elog 'values in these files.'
-	elog
-	elog 'If you have an older graphics card which only supports OpenGL 1.2, and the'
-	elog 'game crashes when you try to play, try starting with "megaglest --disable-vbo"'
-	elog 'Some graphics cards may require setting Max Lights to 1.'
-	einfo
-
-	xdg_icon_cache_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-}


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2024-04-18 17:12 Pacho Ramos
  0 siblings, 0 replies; 17+ messages in thread
From: Pacho Ramos @ 2024-04-18 17:12 UTC (permalink / raw
  To: gentoo-commits

commit:     0c71eb49d5095fb3b3e5580b3a0fcdaa415e4cd5
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 18 17:07:02 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu Apr 18 17:12:06 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0c71eb49

games-strategy/megaglest: use wxGTK 3.2

I added the patches long time ago but, in the final committed version, I
forgot to update the wxGTK version.

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 .../megaglest/megaglest-3.13.0-r2.ebuild           | 173 +++++++++++++++++++++
 1 file changed, 173 insertions(+)

diff --git a/games-strategy/megaglest/megaglest-3.13.0-r2.ebuild b/games-strategy/megaglest/megaglest-3.13.0-r2.ebuild
new file mode 100644
index 000000000000..a14ee88e3c35
--- /dev/null
+++ b/games-strategy/megaglest/megaglest-3.13.0-r2.ebuild
@@ -0,0 +1,173 @@
+# Copyright 2010-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Todo: google-breakpad?
+
+EAPI=8
+
+# src_install() currently requires this
+CMAKE_MAKEFILE_GENERATOR="emake"
+
+LUA_COMPAT=( lua5-{1..4} )
+
+# Only needed by certain features
+VIRTUALX_REQUIRED="manual"
+
+WX_GTK_VER="3.2-gtk3"
+inherit cmake desktop flag-o-matic lua-single readme.gentoo-r1 virtualx wxwidgets xdg-utils
+
+DESCRIPTION="Cross-platform 3D realtime strategy game"
+HOMEPAGE="https://megaglest.org/ https://github.com/MegaGlest/megaglest-source"
+SRC_URI="https://github.com/MegaGlest/megaglest-source/releases/download/${PV}/megaglest-source-${PV}.tar.xz
+	https://github.com/MegaGlest/megaglest-source/commit/789e1cdf.patch -> ${P}-789e1cdf.patch
+	https://github.com/MegaGlest/megaglest-source/commit/5801b1fa.patch -> ${P}-5801b1fa.patch
+	https://github.com/MegaGlest/megaglest-source/commit/412b37d0.patch -> ${P}-412b37d0.patch
+	https://github.com/MegaGlest/megaglest-source/commit/e09ba53c.patch -> ${P}-e09ba53c.patch
+	https://github.com/MegaGlest/megaglest-source/commit/fbd0cfb1.patch -> ${P}-fbd0cfb1.patch
+"
+
+LICENSE="GPL-3 BitstreamVera"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 +streflop +tools +unicode wxuniversal +model-viewer videos"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	${LUA_DEPS}
+	dev-libs/libxml2
+	dev-libs/xerces-c[icu]
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/ftgl
+	media-libs/glew:=
+	net-libs/libircclient
+	media-libs/libpng:0
+	media-libs/libsdl2[X,sound,joystick,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	net-libs/gnutls:=
+	net-libs/miniupnpc:=
+	net-misc/curl
+	sys-libs/zlib
+	virtual/opengl
+	virtual/glu
+	virtual/jpeg:0=
+	x11-libs/libX11
+	x11-libs/libXext
+	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
+	fribidi? ( dev-libs/fribidi )
+	model-viewer? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
+	videos? ( media-video/vlc )
+"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="
+	${COMMON_DEPEND}
+	~games-strategy/${PN}-data-${PV}
+"
+
+BDEPEND="sys-apps/help2man
+	virtual/pkgconfig
+	editor? ( ${VIRTUALX_DEPEND} )
+	model-viewer? ( ${VIRTUALX_DEPEND} )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.11.1-cmake-lua.patch"
+
+	# From Fedora and Arch
+	"${FILESDIR}/${P}-underlink.patch"
+	"${FILESDIR}/${P}-fix-lua-version-ordering.patch"
+	"${FILESDIR}/${P}-multiple-definitions.patch"
+	"${FILESDIR}/${P}-GLEW_ERROR_NO_GLX_DISPLAY.patch"
+	"${FILESDIR}/${P}-help2man.patch"
+
+	# Fix build with wxWidgets 3.2
+	"${DISTDIR}/${P}-789e1cdf.patch"
+	"${DISTDIR}/${P}-5801b1fa.patch"
+	"${DISTDIR}/${P}-412b37d0.patch"
+	"${DISTDIR}/${P}-e09ba53c.patch"
+	"${FILESDIR}/${P}-fbd0cfb1.patch"
+)
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="DO NOT directly edit glest.ini and glestkeys.ini but rather glestuser.ini
+and glestuserkeys.ini in ~/.megaglest/ and create your user over-ride
+values in these files.
+
+If you have an older graphics card which only supports OpenGL 1.2, and the
+game crashes when you try to play, try starting with 'megaglest --disable-vbo'
+Some graphics cards may require setting Max Lights to 1.
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	if use editor || use model-viewer ; then
+		setup-wxwidgets
+	fi
+}
+
+src_configure() {
+	# -Werror=odr
+	# https://bugs.gentoo.org/926143
+	# https://github.com/MegaGlest/megaglest-source/issues/275
+	filter-lto
+
+	if use cpu_flags_x86_sse3; then
+		SSE=3
+	elif use cpu_flags_x86_sse2; then
+		SSE=2
+	elif use cpu_flags_x86_sse; then
+		SSE=1
+	else
+		SSE=0
+	fi
+
+	local mycmakeargs=(
+		-DWANT_GIT_STAMP=OFF
+		-DWANT_USE_FriBiDi="$(usex fribidi)"
+		-DBUILD_MEGAGLEST_MAP_EDITOR="$(usex editor)"
+		-DBUILD_MEGAGLEST_MODEL_IMPORT_EXPORT_TOOLS="$(usex tools)"
+		-DBUILD_MEGAGLEST_MODEL_VIEWER="$(usex model-viewer)"
+		-DWANT_USE_VLC="$(usex videos)"
+		-DFORCE_LUA_VERSION="$(lua_get_version)"
+		-DFORCE_MAX_SSE_LEVEL="${SSE}"
+		-DWANT_USE_FTGL=ON
+		-DWANT_STATIC_LIBS=OFF
+		-DWANT_USE_STREFLOP="$(usex streflop)"
+		-DwxWidgets_USE_STATIC=OFF
+		-DwxWidgets_USE_UNICODE="$(usex unicode)"
+		-DwxWidgets_USE_UNIVERSAL="$(usex wxuniversal)"
+
+		$(usex debug "-DBUILD_MEGAGLEST_UPNP_DEBUG=ON -DwxWidgets_USE_DEBUG=ON" "")
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_install() {
+	# rebuilds some targets randomly without fast option
+	emake -C "${BUILD_DIR}" DESTDIR="${D}" "$@" install/fast
+
+	dodoc docs/{AUTHORS.source_code,CHANGELOG,README}.txt
+
+	use editor &&
+		make_desktop_entry ${PN}_editor "MegaGlest Map Editor"
+	use model-viewer &&
+		make_desktop_entry ${PN}_g3dviewer "MegaGlest Model Viewer"
+
+	readme.gentoo_create_doc
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2024-04-18 17:12 Pacho Ramos
  0 siblings, 0 replies; 17+ messages in thread
From: Pacho Ramos @ 2024-04-18 17:12 UTC (permalink / raw
  To: gentoo-commits

commit:     6915279510acf4322f0ab7a0c843c476e2294acc
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 18 17:10:04 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Thu Apr 18 17:12:06 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=69152795

games-strategy/megaglest: Update deprecated dependency.

Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 games-strategy/megaglest/megaglest-3.13.0-r2.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/games-strategy/megaglest/megaglest-3.13.0-r2.ebuild b/games-strategy/megaglest/megaglest-3.13.0-r2.ebuild
index a14ee88e3c35..f5fd5ca2f90c 100644
--- a/games-strategy/megaglest/megaglest-3.13.0-r2.ebuild
+++ b/games-strategy/megaglest/megaglest-3.13.0-r2.ebuild
@@ -52,7 +52,7 @@ COMMON_DEPEND="
 	sys-libs/zlib
 	virtual/opengl
 	virtual/glu
-	virtual/jpeg:0=
+	media-libs/libjpeg-turbo:0=
 	x11-libs/libX11
 	x11-libs/libXext
 	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2024-03-22  5:33 Sam James
  0 siblings, 0 replies; 17+ messages in thread
From: Sam James @ 2024-03-22  5:33 UTC (permalink / raw
  To: gentoo-commits

commit:     7cb6fe35cfba26df82753ba440d657a2e6676a85
Author:     Eli Schwartz <eschwartz93 <AT> gmail <DOT> com>
AuthorDate: Fri Mar 22 02:36:54 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Mar 22 05:31:53 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7cb6fe35

games-strategy/megaglest: mark as LTO-unsafe

Closes: https://bugs.gentoo.org/926143
Signed-off-by: Eli Schwartz <eschwartz93 <AT> gmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-strategy/megaglest/megaglest-3.13.0-r1.ebuild | 7 ++++++-
 1 file changed, 6 insertions(+), 1 deletion(-)

diff --git a/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild b/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild
index cc03ed6ad423..26f172483f1e 100644
--- a/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild
+++ b/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild
@@ -14,7 +14,7 @@ LUA_COMPAT=( lua5-{1..4} )
 VIRTUALX_REQUIRED="manual"
 
 WX_GTK_VER="3.0-gtk3"
-inherit cmake desktop lua-single readme.gentoo-r1 virtualx wxwidgets xdg-utils
+inherit cmake desktop flag-o-matic lua-single readme.gentoo-r1 virtualx wxwidgets xdg-utils
 
 DESCRIPTION="Cross-platform 3D realtime strategy game"
 HOMEPAGE="https://megaglest.org/ https://github.com/MegaGlest/megaglest-source"
@@ -108,6 +108,11 @@ src_prepare() {
 }
 
 src_configure() {
+	# -Werror=odr
+	# https://bugs.gentoo.org/926143
+	# https://github.com/MegaGlest/megaglest-source/issues/275
+	filter-lto
+
 	if use cpu_flags_x86_sse3; then
 		SSE=3
 	elif use cpu_flags_x86_sse2; then


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2024-03-22  5:33 Sam James
  0 siblings, 0 replies; 17+ messages in thread
From: Sam James @ 2024-03-22  5:33 UTC (permalink / raw
  To: gentoo-commits

commit:     953d07d1cb1ce319320ec961c56a2e5f470e6441
Author:     Eli Schwartz <eschwartz93 <AT> gmail <DOT> com>
AuthorDate: Fri Mar 22 02:31:27 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Fri Mar 22 05:31:52 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=953d07d1

games-strategy/megaglest: drop the data files to a runtime-only dep

When using --buildpkgonly, it is unnecessary to merge the data files as
a prerequisite.

Signed-off-by: Eli Schwartz <eschwartz93 <AT> gmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-strategy/megaglest/megaglest-3.13.0-r1.ebuild | 11 +++++++----
 1 file changed, 7 insertions(+), 4 deletions(-)

diff --git a/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild b/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild
index abc3ccab6973..cc03ed6ad423 100644
--- a/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild
+++ b/games-strategy/megaglest/megaglest-3.13.0-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2010-2023 Gentoo Authors
+# Copyright 2010-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 # Todo: google-breakpad?
@@ -33,9 +33,8 @@ IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_s
 
 REQUIRED_USE="${LUA_REQUIRED_USE}"
 
-RDEPEND="
+COMMON_DEPEND="
 	${LUA_DEPS}
-	~games-strategy/${PN}-data-${PV}
 	dev-libs/libxml2
 	dev-libs/xerces-c[icu]
 	media-libs/fontconfig
@@ -61,7 +60,11 @@ RDEPEND="
 	model-viewer? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
 	videos? ( media-video/vlc )
 "
-DEPEND="${RDEPEND}"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="
+	${COMMON_DEPEND}
+	~games-strategy/${PN}-data-${PV}
+"
 
 BDEPEND="sys-apps/help2man
 	virtual/pkgconfig


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2021-04-25 21:05 Sam James
  0 siblings, 0 replies; 17+ messages in thread
From: Sam James @ 2021-04-25 21:05 UTC (permalink / raw
  To: gentoo-commits

commit:     ce39fa182653617e0a05f0724a680e5ceca27f42
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 25 21:05:20 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Apr 25 21:05:20 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ce39fa18

games-strategy/megaglest: Keyword 3.13.0 arm64, #774351

Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-strategy/megaglest/megaglest-3.13.0.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/games-strategy/megaglest/megaglest-3.13.0.ebuild b/games-strategy/megaglest/megaglest-3.13.0.ebuild
index 212ab76aac3..1a07d154d99 100644
--- a/games-strategy/megaglest/megaglest-3.13.0.ebuild
+++ b/games-strategy/megaglest/megaglest-3.13.0.ebuild
@@ -22,7 +22,7 @@ SRC_URI="https://github.com/MegaGlest/megaglest-source/releases/download/${PV}/m
 
 LICENSE="GPL-3 BitstreamVera"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~arm64 ~x86"
 IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 +streflop +tools +unicode wxuniversal +model-viewer videos"
 
 REQUIRED_USE="${LUA_REQUIRED_USE}"


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2021-04-05 22:26 David Seifert
  0 siblings, 0 replies; 17+ messages in thread
From: David Seifert @ 2021-04-05 22:26 UTC (permalink / raw
  To: gentoo-commits

commit:     9a0982aeb18c625ba594534e73c2762c67e8db83
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Mon Apr  5 22:26:19 2021 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Mon Apr  5 22:26:19 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9a0982ae

games-strategy/megaglest: Set WX_GTK_VER before inherit

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 games-strategy/megaglest/megaglest-3.11.1-r100.ebuild | 6 +++---
 games-strategy/megaglest/megaglest-3.13.0.ebuild      | 6 +++---
 2 files changed, 6 insertions(+), 6 deletions(-)

diff --git a/games-strategy/megaglest/megaglest-3.11.1-r100.ebuild b/games-strategy/megaglest/megaglest-3.11.1-r100.ebuild
index d19c6ffd579..353d0ce3f9b 100644
--- a/games-strategy/megaglest/megaglest-3.11.1-r100.ebuild
+++ b/games-strategy/megaglest/megaglest-3.11.1-r100.ebuild
@@ -14,6 +14,7 @@ LUA_COMPAT=( lua5-{1..2} )
 # Only needed by certain features
 VIRTUALX_REQUIRED="manual"
 
+WX_GTK_VER="3.0"
 inherit cmake desktop flag-o-matic lua-single virtualx wxwidgets xdg-utils
 
 DESCRIPTION="Cross-platform 3D realtime strategy game"
@@ -43,9 +44,9 @@ RDEPEND="${LUA_DEPS}
 	virtual/glu
 	x11-libs/libX11
 	x11-libs/libXext
-	editor? ( x11-libs/wxGTK:3.0[X,opengl] )
+	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
 	fribidi? ( dev-libs/fribidi )
-	model-viewer? ( x11-libs/wxGTK:3.0[X] )
+	model-viewer? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
 	dev-libs/xerces-c[icu]
 	media-libs/ftgl
 	media-libs/glew:=
@@ -73,7 +74,6 @@ src_prepare() {
 	cmake_src_prepare
 
 	if use editor || use model-viewer ; then
-		WX_GTK_VER="3.0"
 		setup-wxwidgets
 	fi
 }

diff --git a/games-strategy/megaglest/megaglest-3.13.0.ebuild b/games-strategy/megaglest/megaglest-3.13.0.ebuild
index 9b8867d2938..212ab76aac3 100644
--- a/games-strategy/megaglest/megaglest-3.13.0.ebuild
+++ b/games-strategy/megaglest/megaglest-3.13.0.ebuild
@@ -13,6 +13,7 @@ LUA_COMPAT=( lua5-{1..2} )
 # Only needed by certain features
 VIRTUALX_REQUIRED="manual"
 
+WX_GTK_VER="3.0-gtk3"
 inherit cmake desktop flag-o-matic lua-single virtualx wxwidgets xdg-utils
 
 DESCRIPTION="Cross-platform 3D realtime strategy game"
@@ -49,9 +50,9 @@ RDEPEND="
 	virtual/jpeg:0=
 	x11-libs/libX11
 	x11-libs/libXext
-	editor? ( x11-libs/wxGTK:3.0-gtk3[X,opengl] )
+	editor? ( x11-libs/wxGTK:${WX_GTK_VER}[X,opengl] )
 	fribidi? ( dev-libs/fribidi )
-	model-viewer? ( x11-libs/wxGTK:3.0-gtk3[X] )
+	model-viewer? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )
 	videos? ( media-video/vlc )
 "
 DEPEND="${RDEPEND}"
@@ -69,7 +70,6 @@ src_prepare() {
 	cmake_src_prepare
 
 	if use editor || use model-viewer ; then
-		WX_GTK_VER="3.0"
 		setup-wxwidgets
 	fi
 }


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2021-01-17  7:49 Sam James
  0 siblings, 0 replies; 17+ messages in thread
From: Sam James @ 2021-01-17  7:49 UTC (permalink / raw
  To: gentoo-commits

commit:     874cad11760a1190e3a7b9de411f5018eb43113d
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 17 07:38:34 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jan 17 07:49:14 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=874cad11

games-strategy/megaglest: drop static

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Sam James <sam <AT> gentoo.org>

 .../megaglest/megaglest-3.11.1-r100.ebuild         | 39 ++++++++--------------
 1 file changed, 13 insertions(+), 26 deletions(-)

diff --git a/games-strategy/megaglest/megaglest-3.11.1-r100.ebuild b/games-strategy/megaglest/megaglest-3.11.1-r100.ebuild
index 796b7822f5e..d19c6ffd579 100644
--- a/games-strategy/megaglest/megaglest-3.11.1-r100.ebuild
+++ b/games-strategy/megaglest/megaglest-3.11.1-r100.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2010-2020 Gentoo Authors
+# Copyright 2010-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 # google-breakpad
@@ -23,7 +23,7 @@ SRC_URI="https://github.com/MegaGlest/megaglest-source/releases/download/${PV}/m
 LICENSE="GPL-3 BitstreamVera"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 static +streflop +tools +unicode wxuniversal +model-viewer videos"
+IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 +streflop +tools +unicode wxuniversal +model-viewer videos"
 
 REQUIRED_USE="${LUA_REQUIRED_USE}"
 
@@ -46,29 +46,16 @@ RDEPEND="${LUA_DEPS}
 	editor? ( x11-libs/wxGTK:3.0[X,opengl] )
 	fribidi? ( dev-libs/fribidi )
 	model-viewer? ( x11-libs/wxGTK:3.0[X] )
-	!static? (
-		dev-libs/xerces-c[icu]
-		media-libs/ftgl
-		media-libs/glew
-		media-libs/libpng:0
-		net-libs/libircclient
-		>=net-libs/miniupnpc-1.8
-		net-misc/curl
-		virtual/jpeg:0
-		)
+	dev-libs/xerces-c[icu]
+	media-libs/ftgl
+	media-libs/glew:=
+	media-libs/libpng:0
+	net-libs/libircclient
+	>=net-libs/miniupnpc-1.8:=
+	net-misc/curl
+	virtual/jpeg:0
 	videos? ( media-video/vlc )"
-DEPEND="${RDEPEND}
-	static? (
-		dev-libs/icu[static-libs]
-		dev-libs/xerces-c[icu,static-libs]
-		media-libs/ftgl[static-libs]
-		media-libs/glew[static-libs]
-		media-libs/libpng:0[static-libs]
-		net-libs/libircclient[static-libs]
-		net-libs/miniupnpc[static-libs]
-		net-misc/curl[static-libs]
-		virtual/jpeg:0[static-libs]
-	)"
+DEPEND="${RDEPEND}"
 BDEPEND="sys-apps/help2man
 	virtual/pkgconfig
 	editor? ( ${VIRTUALX_DEPEND} )
@@ -110,10 +97,10 @@ src_configure() {
 		-DFORCE_LUA_VERSION="$(lua_get_version)"
 		-DMAX_SSE_LEVEL_DESIRED="${SSE}"
 		-DUSE_FTGL=ON
-		-DWANT_STATIC_LIBS=$(usex static)
+		-DWANT_STATIC_LIBS=OFF
 		-DWANT_STREFLOP=$(usex streflop)
 		-DWITH_VLC=$(usex videos)
-		-DwxWidgets_USE_STATIC=$(usex static)
+		-DwxWidgets_USE_STATIC=OFF
 		-DwxWidgets_USE_UNICODE=$(usex unicode)
 		-DwxWidgets_USE_UNIVERSAL=$(usex wxuniversal)
 


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2021-01-17  4:34 Sam James
  0 siblings, 0 replies; 17+ messages in thread
From: Sam James @ 2021-01-17  4:34 UTC (permalink / raw
  To: gentoo-commits

commit:     5de23db822b8342275db15623f2cad609f82483d
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 17 04:32:49 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jan 17 04:34:31 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5de23db8

games-strategy/megaglest: update dependencies

* SDL 2
* Missing subslot deps

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-strategy/megaglest/megaglest-3.13.0.ebuild | 10 +++++-----
 1 file changed, 5 insertions(+), 5 deletions(-)

diff --git a/games-strategy/megaglest/megaglest-3.13.0.ebuild b/games-strategy/megaglest/megaglest-3.13.0.ebuild
index b0bbfd5aec6..9b8867d2938 100644
--- a/games-strategy/megaglest/megaglest-3.13.0.ebuild
+++ b/games-strategy/megaglest/megaglest-3.13.0.ebuild
@@ -34,19 +34,19 @@ RDEPEND="
 	media-libs/fontconfig
 	media-libs/freetype
 	media-libs/ftgl
-	media-libs/glew:0=
+	media-libs/glew:=
 	net-libs/libircclient
 	media-libs/libpng:0
-	media-libs/libsdl[X,sound,joystick,opengl,video]
+	media-libs/libsdl2[X,sound,joystick,opengl,video]
 	media-libs/libvorbis
 	media-libs/openal
-	net-libs/gnutls
-	net-libs/miniupnpc
+	net-libs/gnutls:=
+	net-libs/miniupnpc:=
 	net-misc/curl
 	sys-libs/zlib
 	virtual/opengl
 	virtual/glu
-	virtual/jpeg:0
+	virtual/jpeg:0=
 	x11-libs/libX11
 	x11-libs/libXext
 	editor? ( x11-libs/wxGTK:3.0-gtk3[X,opengl] )


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2021-01-17  4:34 Sam James
  0 siblings, 0 replies; 17+ messages in thread
From: Sam James @ 2021-01-17  4:34 UTC (permalink / raw
  To: gentoo-commits

commit:     17764a210caee03be1f3f4f96abde1b949d3b33d
Author:     Nils Freydank <holgersson <AT> posteo <DOT> de>
AuthorDate: Thu Jan 14 16:40:00 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jan 17 04:34:30 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=17764a21

games-strategy/megaglest: Drop old EAPI="5" version

Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Nils Freydank <holgersson <AT> posteo.de>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 .../megaglest/megaglest-3.11.1-r1.ebuild           | 167 ---------------------
 1 file changed, 167 deletions(-)

diff --git a/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild b/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
deleted file mode 100644
index 86e78fb0535..00000000000
--- a/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
+++ /dev/null
@@ -1,167 +0,0 @@
-# Copyright 2010-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-# google-breakpad
-# TODO: fribidi, libvorbis static
-
-EAPI=5
-VIRTUALX_REQUIRED="manual"
-inherit eutils flag-o-matic cmake-utils virtualx wxwidgets gnome2-utils games
-
-DESCRIPTION="Cross-platform 3D realtime strategy game"
-HOMEPAGE="https://megaglest.org/ https://github.com/MegaGlest/megaglest-source"
-SRC_URI="https://github.com/MegaGlest/megaglest-source/releases/download/${PV}/megaglest-source-${PV}.tar.xz"
-
-LICENSE="GPL-3 BitstreamVera"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 static +streflop +tools +unicode wxuniversal +model-viewer videos"
-
-# Newer versions of megaglest-data install directly into /usr
-RDEPEND="
-	~games-strategy/${PN}-data-${PV}
-	<games-strategy/${PN}-data-3.11.1-r1
-	>=dev-lang/lua-5.1:0
-	dev-libs/libxml2
-	media-libs/fontconfig
-	media-libs/freetype
-	media-libs/libsdl[X,sound,joystick,opengl,video]
-	media-libs/libvorbis
-	media-libs/openal
-	net-libs/gnutls
-	sys-libs/zlib
-	virtual/opengl
-	virtual/glu
-	x11-libs/libX11
-	x11-libs/libXext
-	editor? ( x11-libs/wxGTK:3.0[X,opengl] )
-	fribidi? ( dev-libs/fribidi )
-	model-viewer? ( x11-libs/wxGTK:3.0[X] )
-	!static? (
-		dev-libs/xerces-c[icu]
-		media-libs/ftgl
-		media-libs/glew
-		media-libs/libpng:0
-		net-libs/libircclient
-		>=net-libs/miniupnpc-1.8
-		net-misc/curl
-		virtual/jpeg:0
-		)
-	videos? ( media-video/vlc )"
-DEPEND="${RDEPEND}
-	sys-apps/help2man
-	virtual/pkgconfig
-	editor? ( ${VIRTUALX_DEPEND} )
-	model-viewer? ( ${VIRTUALX_DEPEND} )
-	static? (
-		dev-libs/icu[static-libs]
-		dev-libs/xerces-c[icu,static-libs]
-		media-libs/ftgl[static-libs]
-		media-libs/glew[static-libs]
-		media-libs/libpng:0[static-libs]
-		net-libs/libircclient[static-libs]
-		net-libs/miniupnpc[static-libs]
-		net-misc/curl[static-libs]
-		virtual/jpeg:0[static-libs]
-	)"
-
-src_prepare() {
-	if use editor || use model-viewer ; then
-		WX_GTK_VER="3.0"
-		need-wxwidgets unicode
-	fi
-
-	epatch "${FILESDIR}"/${P}-static-build.patch \
-		"${FILESDIR}"/${P}-cmake.patch \
-		"${FILESDIR}"/${P}-miniupnpc.patch \
-		"${FILESDIR}"/${P}-miniupnpc-api-version-16.patch
-}
-
-src_configure() {
-	if use cpu_flags_x86_sse3; then
-		SSE=3
-	elif use cpu_flags_x86_sse2; then
-		SSE=2
-	elif use cpu_flags_x86_sse; then
-		SSE=1
-	else
-		SSE=0
-	fi
-
-	local mycmakeargs=(
-		$(cmake-utils_use_enable fribidi FRIBIDI)
-		$(cmake-utils_use_build editor MEGAGLEST_MAP_EDITOR)
-		$(cmake-utils_use_build tools MEGAGLEST_MODEL_IMPORT_EXPORT_TOOLS)
-		$(cmake-utils_use_build model-viewer MEGAGLEST_MODEL_VIEWER)
-		$(cmake-utils_use_with videos VLC)
-		-DMAX_SSE_LEVEL_DESIRED="${SSE}"
-		-DMEGAGLEST_BIN_INSTALL_PATH="${GAMES_BINDIR}"
-		-DMEGAGLEST_DATA_INSTALL_PATH="${GAMES_DATADIR}/${PN}"
-		# icons are used at runtime, wrong default location share/pixmaps
-		-DMEGAGLEST_ICON_INSTALL_PATH="${GAMES_DATADIR}/${PN}"
-		-DUSE_FTGL=ON
-		$(cmake-utils_use_want static STATIC_LIBS)
-		$(cmake-utils_use_want streflop STREFLOP)
-		-DWANT_SVN_STAMP=off
-		$(cmake-utils_use static wxWidgets_USE_STATIC)
-		$(cmake-utils_use unicode wxWidgets_USE_UNICODE)
-		$(cmake-utils_use wxuniversal wxWidgets_USE_UNIVERSAL)
-
-		$(usex debug "-DBUILD_MEGAGLEST_UPNP_DEBUG=ON -DwxWidgets_USE_DEBUG=ON" "")
-	)
-
-	# support CMAKE_BUILD_TYPE=Gentoo
-	append-cppflags '-DCUSTOM_DATA_INSTALL_PATH=\\\"'${GAMES_DATADIR}/${PN}/'\\\"'
-
-	cmake-utils_src_configure
-}
-
-src_compile() {
-	if use editor || use model-viewer; then
-		# work around parallel make issues - bug #561380
-		MAKEOPTS="-j1 ${MAKEOPTS}" \
-			VIRTUALX_COMMAND="cmake-utils_src_compile" virtualmake
-	else
-		cmake-utils_src_compile
-	fi
-}
-
-src_install() {
-	# rebuilds some targets randomly without fast option
-	emake -C "${CMAKE_BUILD_DIR}" DESTDIR="${D}" "$@" install/fast
-
-	dodoc docs/{AUTHORS.source_code,CHANGELOG,README}.txt
-	doicon -s 48 ${PN}.png
-
-	use editor &&
-		make_desktop_entry ${PN}_editor "MegaGlest Map Editor"
-	use model-viewer &&
-		make_desktop_entry ${PN}_g3dviewer "MegaGlest Model Viewer"
-
-	prepgamesdirs
-}
-
-pkg_preinst() {
-	games_pkg_preinst
-	gnome2_icon_savelist
-}
-
-pkg_postinst() {
-	einfo
-	elog 'Note about Configuration:'
-	elog 'DO NOT directly edit glest.ini and glestkeys.ini but rather glestuser.ini'
-	elog 'and glestuserkeys.ini in ~/.megaglest/ and create your user over-ride'
-	elog 'values in these files.'
-	elog
-	elog 'If you have an older graphics card which only supports OpenGL 1.2, and the'
-	elog 'game crashes when you try to play, try starting with "megaglest --disable-vbo"'
-	elog 'Some graphics cards may require setting Max Lights to 1.'
-	einfo
-
-	games_pkg_postinst
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
-}


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2021-01-17  4:34 Sam James
  0 siblings, 0 replies; 17+ messages in thread
From: Sam James @ 2021-01-17  4:34 UTC (permalink / raw
  To: gentoo-commits

commit:     b84711c48c464f400ea607b84fff0b5931b91ea6
Author:     Nils Freydank <holgersson <AT> posteo <DOT> de>
AuthorDate: Thu Jan 14 16:40:04 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Jan 17 04:34:31 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b84711c4

games-strategy/megaglest: Bump to 3.13.0 and drop USE="static"

This bump is based on the efforts of marecki and polynomial-c - special thanks!

Thanks-To: Marek Szuba <marecki <AT> gentoo.org>
Thanks-To: Lars Wendler <polynomial-c <AT> gentoo.org>
Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Nils Freydank <holgersson <AT> posteo.de>
Closes: https://github.com/gentoo/gentoo/pull/19061
Signed-off-by: Sam James <sam <AT> gentoo.org>

 games-strategy/megaglest/Manifest                |   1 +
 games-strategy/megaglest/megaglest-3.13.0.ebuild | 144 +++++++++++++++++++++++
 2 files changed, 145 insertions(+)

diff --git a/games-strategy/megaglest/Manifest b/games-strategy/megaglest/Manifest
index f32e43070ea..eba04831a2e 100644
--- a/games-strategy/megaglest/Manifest
+++ b/games-strategy/megaglest/Manifest
@@ -1 +1,2 @@
 DIST megaglest-source-3.11.1.tar.xz 2863180 BLAKE2B 01923ad4b29cc7042f0a26ba44a6a023020cbe2071b26b40c3332d763430dd559eb9eb7041182e154a0f1832866c759e08f21a677fcb5f2dba134127b0624b30 SHA512 9e1d8eccff1889199ff0e4b0f1cc3d0193306cd9271a2c98f12a49d61a09789d0813d5f3dadfe7701d2446976992834c63287f0227d660dc9cc9d2ecef65e225
+DIST megaglest-source-3.13.0.tar.xz 1979440 BLAKE2B 9df70502e0dddc754897c989222d0bddbebbb781a16f49ffa2dd30ee1dbd3e88249ccd600fbde8dab712a1286e29651bebfc9add0d255b675e9eb0ca5ba60153 SHA512 5ae74efce55d7ec9f38d7701da9c865458e15223b5a3c5ac829e09dc81e63fbea2a235cae99450ea7333044c5166af82a762a29c5793c75711d1200688518b5c

diff --git a/games-strategy/megaglest/megaglest-3.13.0.ebuild b/games-strategy/megaglest/megaglest-3.13.0.ebuild
new file mode 100644
index 00000000000..b0bbfd5aec6
--- /dev/null
+++ b/games-strategy/megaglest/megaglest-3.13.0.ebuild
@@ -0,0 +1,144 @@
+# Copyright 2010-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Todo: google-breakpad?
+
+EAPI=7
+
+# src_install() currently requires this
+CMAKE_MAKEFILE_GENERATOR="emake"
+
+LUA_COMPAT=( lua5-{1..2} )
+
+# Only needed by certain features
+VIRTUALX_REQUIRED="manual"
+
+inherit cmake desktop flag-o-matic lua-single virtualx wxwidgets xdg-utils
+
+DESCRIPTION="Cross-platform 3D realtime strategy game"
+HOMEPAGE="https://megaglest.org/ https://github.com/MegaGlest/megaglest-source"
+SRC_URI="https://github.com/MegaGlest/megaglest-source/releases/download/${PV}/megaglest-source-${PV}.tar.xz"
+
+LICENSE="GPL-3 BitstreamVera"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 +streflop +tools +unicode wxuniversal +model-viewer videos"
+
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	${LUA_DEPS}
+	~games-strategy/${PN}-data-${PV}
+	dev-libs/libxml2
+	dev-libs/xerces-c[icu]
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/ftgl
+	media-libs/glew:0=
+	net-libs/libircclient
+	media-libs/libpng:0
+	media-libs/libsdl[X,sound,joystick,opengl,video]
+	media-libs/libvorbis
+	media-libs/openal
+	net-libs/gnutls
+	net-libs/miniupnpc
+	net-misc/curl
+	sys-libs/zlib
+	virtual/opengl
+	virtual/glu
+	virtual/jpeg:0
+	x11-libs/libX11
+	x11-libs/libXext
+	editor? ( x11-libs/wxGTK:3.0-gtk3[X,opengl] )
+	fribidi? ( dev-libs/fribidi )
+	model-viewer? ( x11-libs/wxGTK:3.0-gtk3[X] )
+	videos? ( media-video/vlc )
+"
+DEPEND="${RDEPEND}"
+
+BDEPEND="sys-apps/help2man
+	virtual/pkgconfig
+	editor? ( ${VIRTUALX_DEPEND} )
+	model-viewer? ( ${VIRTUALX_DEPEND} )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.11.1-cmake-lua.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	if use editor || use model-viewer ; then
+		WX_GTK_VER="3.0"
+		setup-wxwidgets
+	fi
+}
+
+src_configure() {
+	# See https://wiki.gentoo.org/wiki/Gcc_10_porting_notes/fno_common
+	append-cflags -fcommon
+
+	if use cpu_flags_x86_sse3; then
+		SSE=3
+	elif use cpu_flags_x86_sse2; then
+		SSE=2
+	elif use cpu_flags_x86_sse; then
+		SSE=1
+	else
+		SSE=0
+	fi
+
+	local mycmakeargs=(
+		-DWANT_USE_FriBiDi="$(usex fribidi)"
+		-DBUILD_MEGAGLEST_MAP_EDITOR="$(usex editor)"
+		-DBUILD_MEGAGLEST_MODEL_IMPORT_EXPORT_TOOLS="$(usex tools)"
+		-DBUILD_MEGAGLEST_MODEL_VIEWER="$(usex model-viewer)"
+		-DWANT_USE_VLC="$(usex videos)"
+		-DFORCE_LUA_VERSION="$(lua_get_version)"
+		-DFORCE_MAX_SSE_LEVEL="${SSE}"
+		-DWANT_USE_FTGL=ON
+		-DWANT_STATIC_LIBS=OFF
+		-DWANT_USE_STREFLOP="$(usex streflop)"
+		-DwxWidgets_USE_STATIC=OFF
+		-DwxWidgets_USE_UNICODE="$(usex unicode)"
+		-DwxWidgets_USE_UNIVERSAL="$(usex wxuniversal)"
+
+		$(usex debug "-DBUILD_MEGAGLEST_UPNP_DEBUG=ON -DwxWidgets_USE_DEBUG=ON" "")
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_install() {
+	# rebuilds some targets randomly without fast option
+	emake -C "${BUILD_DIR}" DESTDIR="${D}" "$@" install/fast
+
+	dodoc docs/{AUTHORS.source_code,CHANGELOG,README}.txt
+
+	use editor &&
+		make_desktop_entry ${PN}_editor "MegaGlest Map Editor"
+	use model-viewer &&
+		make_desktop_entry ${PN}_g3dviewer "MegaGlest Model Viewer"
+}
+
+pkg_postinst() {
+	einfo
+	elog 'Note about Configuration:'
+	elog 'DO NOT directly edit glest.ini and glestkeys.ini but rather glestuser.ini'
+	elog 'and glestuserkeys.ini in ~/.megaglest/ and create your user over-ride'
+	elog 'values in these files.'
+	elog
+	elog 'If you have an older graphics card which only supports OpenGL 1.2, and the'
+	elog 'game crashes when you try to play, try starting with "megaglest --disable-vbo"'
+	elog 'Some graphics cards may require setting Max Lights to 1.'
+	einfo
+
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2018-08-11  9:06 Andreas Sturmlechner
  0 siblings, 0 replies; 17+ messages in thread
From: Andreas Sturmlechner @ 2018-08-11  9:06 UTC (permalink / raw
  To: gentoo-commits

commit:     ea62506e91726ea61a997b578c57008fb81b30b6
Author:     Francesco Turco <fturco <AT> fastmail <DOT> fm>
AuthorDate: Fri Aug 10 21:30:07 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Aug 11 08:22:22 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ea62506e

games-strategy/megaglest: update links to changelog and bug tracker

 games-strategy/megaglest/metadata.xml | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/games-strategy/megaglest/metadata.xml b/games-strategy/megaglest/metadata.xml
index 192243d3ba3..36e65bdb8a1 100644
--- a/games-strategy/megaglest/metadata.xml
+++ b/games-strategy/megaglest/metadata.xml
@@ -6,9 +6,9 @@
 		<name>Gentoo Games Project</name>
 	</maintainer>
 	<upstream>
-		<changelog>http://megaglest.svn.sourceforge.net/viewvc/megaglest/trunk/docs/CHANGELOG.txt?revision=3397</changelog>
+		<changelog>https://github.com/MegaGlest/megaglest-source/blob/develop/docs/CHANGELOG.txt</changelog>
 		<doc lang="en">http://glest.wikia.com/wiki/MG</doc>
-		<bugs-to>https://sourceforge.net/tracker/?group_id=300350&amp;atid=1266776</bugs-to>
+		<bugs-to>https://github.com/MegaGlest/megaglest-source/issues</bugs-to>
 		<remote-id type="github">MegaGlest/megaglest-source</remote-id>
 	</upstream>
 	<use>


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2015-11-11  9:12 Agostino Sarubbo
  0 siblings, 0 replies; 17+ messages in thread
From: Agostino Sarubbo @ 2015-11-11  9:12 UTC (permalink / raw
  To: gentoo-commits

commit:     d160136085fdba26f803a426d97745ad1759b192
Author:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 11 09:11:46 2015 +0000
Commit:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
CommitDate: Wed Nov 11 09:11:46 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d1601360

games-strategy/megaglest: x86 stable wrt bug #564812

Package-Manager: portage-2.2.20.1
RepoMan-Options: --include-arches="x86"

 games-strategy/megaglest/megaglest-3.11.1-r1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild b/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
index 214ea19..d75e017 100644
--- a/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
+++ b/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
@@ -15,7 +15,7 @@ SRC_URI="https://github.com/MegaGlest/megaglest-source/releases/download/${PV}/m
 
 LICENSE="GPL-3 BitstreamVera"
 SLOT="0"
-KEYWORDS="amd64 ~x86"
+KEYWORDS="amd64 x86"
 IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 static +streflop +tools +unicode wxuniversal +model-viewer videos"
 
 RDEPEND="


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2015-11-09 10:31 Agostino Sarubbo
  0 siblings, 0 replies; 17+ messages in thread
From: Agostino Sarubbo @ 2015-11-09 10:31 UTC (permalink / raw
  To: gentoo-commits

commit:     501a0690bcbbb9b97607d2c0ac784515041e2180
Author:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
AuthorDate: Mon Nov  9 10:30:10 2015 +0000
Commit:     Agostino Sarubbo <ago <AT> gentoo <DOT> org>
CommitDate: Mon Nov  9 10:30:10 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=501a0690

games-strategy/megaglest: amd64 stable wrt bug #564812

Package-Manager: portage-2.2.20.1
RepoMan-Options: --include-arches="amd64"

 games-strategy/megaglest/megaglest-3.11.1-r1.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild b/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
index 0a54a79..214ea19 100644
--- a/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
+++ b/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
@@ -15,7 +15,7 @@ SRC_URI="https://github.com/MegaGlest/megaglest-source/releases/download/${PV}/m
 
 LICENSE="GPL-3 BitstreamVera"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 ~x86"
 IUSE="debug +editor fribidi cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse3 static +streflop +tools +unicode wxuniversal +model-viewer videos"
 
 RDEPEND="


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2015-11-03 16:27 Michael Sterrett
  0 siblings, 0 replies; 17+ messages in thread
From: Michael Sterrett @ 2015-11-03 16:27 UTC (permalink / raw
  To: gentoo-commits

commit:     dd8558332becd69ffcacc82b6119ddea5f611fa9
Author:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
AuthorDate: Tue Nov  3 16:27:04 2015 +0000
Commit:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
CommitDate: Tue Nov  3 16:27:04 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dd855833

rev bump to move wxGTK slot (bug #563952)

Package-Manager: portage-2.2.20.1

 .../{megaglest-3.11.1.ebuild => megaglest-3.11.1-r1.ebuild}         | 6 +++---
 1 file changed, 3 insertions(+), 3 deletions(-)

diff --git a/games-strategy/megaglest/megaglest-3.11.1.ebuild b/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
similarity index 97%
rename from games-strategy/megaglest/megaglest-3.11.1.ebuild
rename to games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
index a050264..0a54a79 100644
--- a/games-strategy/megaglest/megaglest-3.11.1.ebuild
+++ b/games-strategy/megaglest/megaglest-3.11.1-r1.ebuild
@@ -33,9 +33,9 @@ RDEPEND="
 	virtual/glu
 	x11-libs/libX11
 	x11-libs/libXext
-	editor? ( x11-libs/wxGTK:2.8[X,opengl] )
+	editor? ( x11-libs/wxGTK:3.0[X,opengl] )
 	fribidi? ( dev-libs/fribidi )
-	model-viewer? ( x11-libs/wxGTK:2.8[X] )
+	model-viewer? ( x11-libs/wxGTK:3.0[X] )
 	!static? (
 		dev-libs/xerces-c[icu]
 		media-libs/ftgl
@@ -66,7 +66,7 @@ DEPEND="${RDEPEND}
 
 src_prepare() {
 	if use editor || use model-viewer ; then
-		WX_GTK_VER="2.8"
+		WX_GTK_VER="3.0"
 		need-wxwidgets unicode
 	fi
 


^ permalink raw reply related	[flat|nested] 17+ messages in thread

* [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/
@ 2015-10-05  0:47 Michael Sterrett
  0 siblings, 0 replies; 17+ messages in thread
From: Michael Sterrett @ 2015-10-05  0:47 UTC (permalink / raw
  To: gentoo-commits

commit:     453d7043e683558978470e20d45a36a21f975ac4
Author:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
AuthorDate: Mon Oct  5 00:47:09 2015 +0000
Commit:     Michael Sterrett <mr_bones_ <AT> gentoo <DOT> org>
CommitDate: Mon Oct  5 00:47:24 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=453d7043

work around parallel make issues - bug #561380

Package-Manager: portage-2.2.20.1

 games-strategy/megaglest/megaglest-3.11.1.ebuild | 4 +++-
 1 file changed, 3 insertions(+), 1 deletion(-)

diff --git a/games-strategy/megaglest/megaglest-3.11.1.ebuild b/games-strategy/megaglest/megaglest-3.11.1.ebuild
index 3c74a8d..a050264 100644
--- a/games-strategy/megaglest/megaglest-3.11.1.ebuild
+++ b/games-strategy/megaglest/megaglest-3.11.1.ebuild
@@ -116,7 +116,9 @@ src_configure() {
 
 src_compile() {
 	if use editor || use model-viewer; then
-		VIRTUALX_COMMAND="cmake-utils_src_compile" virtualmake
+		# work around parallel make issues - bug #561380
+		MAKEOPTS="-j1 ${MAKEOPTS}" \
+			VIRTUALX_COMMAND="cmake-utils_src_compile" virtualmake
 	else
 		cmake-utils_src_compile
 	fi


^ permalink raw reply related	[flat|nested] 17+ messages in thread

end of thread, other threads:[~2024-07-05 17:49 UTC | newest]

Thread overview: 17+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2020-12-23 14:52 [gentoo-commits] repo/gentoo:master commit in: games-strategy/megaglest/ Marek Szuba
  -- strict thread matches above, loose matches on Subject: below --
2024-07-05 17:49 Pacho Ramos
2024-04-18 17:12 Pacho Ramos
2024-04-18 17:12 Pacho Ramos
2024-03-22  5:33 Sam James
2024-03-22  5:33 Sam James
2021-04-25 21:05 Sam James
2021-04-05 22:26 David Seifert
2021-01-17  7:49 Sam James
2021-01-17  4:34 Sam James
2021-01-17  4:34 Sam James
2021-01-17  4:34 Sam James
2018-08-11  9:06 Andreas Sturmlechner
2015-11-11  9:12 Agostino Sarubbo
2015-11-09 10:31 Agostino Sarubbo
2015-11-03 16:27 Michael Sterrett
2015-10-05  0:47 Michael Sterrett

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox