[gentoo-commits] repo/gentoo:master commit in: sys-apps/usbutils/

["Robin H. Johnson" <robbat2@gentoo.org>]

commit:     fda317e2aaafc14c9af4ba6e309945c494e53a7a
Author:     Robin H. Johnson <robbat2 <AT> gentoo <DOT> org>
AuthorDate: Sat Dec  5 05:44:25 2020 +0000
Commit:     Robin H. Johnson <robbat2 <AT> gentoo <DOT> org>
CommitDate: Sat Dec  5 05:44:25 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fda317e2

sys-apps/usbutils: add usbreset tool

Thanks: Luke-Jr <luke-jr+gentoobugs <AT> utopios.org>
Closes: https://bugs.gentoo.org/758443
Signed-off-by: Robin H. Johnson <robbat2 <AT> gentoo.org>

 sys-apps/usbutils/usbutils-013-r1.ebuild | 53 ++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/sys-apps/usbutils/usbutils-013-r1.ebuild b/sys-apps/usbutils/usbutils-013-r1.ebuild
new file mode 100644
index 00000000000..648f5b9094c
--- /dev/null
+++ b/sys-apps/usbutils/usbutils-013-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="USB enumeration utilities"
+HOMEPAGE="https://www.kernel.org/pub/linux/utils/usb/usbutils/
+	https://git.kernel.org/pub/scm/linux/kernel/git/gregkh/usbutils.git/"
+SRC_URI="https://www.kernel.org/pub/linux/utils/usb/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="python"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="virtual/libusb:1=
+	virtual/libudev:="
+BDEPEND="
+	app-arch/xz-utils
+	virtual/pkgconfig"
+RDEPEND="${DEPEND}
+	sys-apps/hwids
+	python? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+	use python && python_fix_shebang lsusb.py.in
+}
+
+src_configure() {
+	local myeconfargs=(
+		--datarootdir="${EPREFIX}/usr/share"
+		--datadir="${EPREFIX}/usr/share/misc"
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	newdoc usbhid-dump/NEWS NEWS.usbhid-dump
+	dobin usbreset # noinst_PROGRAMS, but installed by other distros
+
+	use python || rm -f "${ED}"/usr/bin/lsusb.py
+}