From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1216849-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 47CE2138359
for <garchives@archives.gentoo.org>; Thu, 22 Oct 2020 07:16:00 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 5EEA6E08CA;
Thu, 22 Oct 2020 07:15:59 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 3AF25E08CA
for <gentoo-commits@lists.gentoo.org>; Thu, 22 Oct 2020 07:15:59 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id B80A533BEDD
for <gentoo-commits@lists.gentoo.org>; Thu, 22 Oct 2020 07:15:57 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 3488A3B3
for <gentoo-commits@lists.gentoo.org>; Thu, 22 Oct 2020 07:15:56 +0000 (UTC)
From: "Joonas Niilola" <juippis@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Joonas Niilola" <juippis@gentoo.org>
Message-ID: <1603350947.388383a270033c1f5fd6f519ad3e985e751d2c5e.juippis@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: app-emulation/lxc/
X-VCS-Repository: repo/gentoo
X-VCS-Files: app-emulation/lxc/Manifest app-emulation/lxc/lxc-4.0.5.ebuild app-emulation/lxc/metadata.xml
X-VCS-Directories: app-emulation/lxc/
X-VCS-Committer: juippis
X-VCS-Committer-Name: Joonas Niilola
X-VCS-Revision: 388383a270033c1f5fd6f519ad3e985e751d2c5e
X-VCS-Branch: master
Date: Thu, 22 Oct 2020 07:15:56 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 986211a2-5d98-4e99-a164-a2b980e7e768
X-Archives-Hash: bac2dc4b38879df08af8938cfad4f112
commit: 388383a270033c1f5fd6f519ad3e985e751d2c5e
Author: Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 22 07:12:43 2020 +0000
Commit: Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Thu Oct 22 07:15:47 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=388383a2
app-emulation/lxc: bump to 4.0.5
- added 'man' USE flag because app-text/docbook-sgml-utils pulls in tons of
dependencies,
- moved some dependencies, and added few under 'optfeature' - please see
https://wiki.gentoo.org/wiki//etc/portage/sets for an example of @optfeature
set handling.
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>
app-emulation/lxc/Manifest | 2 +
app-emulation/lxc/lxc-4.0.5.ebuild | 173 +++++++++++++++++++++++++++++++++++++
app-emulation/lxc/metadata.xml | 1 +
3 files changed, 176 insertions(+)
diff --git a/app-emulation/lxc/Manifest b/app-emulation/lxc/Manifest
index 1f1a926377b..c8fd8697461 100644
--- a/app-emulation/lxc/Manifest
+++ b/app-emulation/lxc/Manifest
@@ -1 +1,3 @@
DIST lxc-4.0.4.tar.gz 844684 BLAKE2B 438f9c79787cfab493a159a03dad214519b979c192264cb4acff21174f5642e2c10a899504ed2ac697906ca1ea9ad5cd92e01dbb8c6420651e7130b56022032a SHA512 5c5bb3c474b37284e862cbaf35daab01be7606992eb101cbea7097951ccee81dad8ab8d2624ba5f62279ece17889b1245fd6b2b63e8b17ed728560c5d40309b2
+DIST lxc-4.0.5.tar.gz 848325 BLAKE2B 3a54d68f1b91bab2f8d851bf867f08eeb691a2884753f02c99056d24051b919f9400e4ee0d1035e7743c80cda3c1923013d06a4999664a5737e1330423a15c61 SHA512 bd8907370830b5c3015451581216bd4e40996c2a3cb4ad1865aff2a8704b4a707f7c094bc49e3c6e276b34ea1edc7cc5b4fcf58a55be55854931b76b93d2f4b8
+DIST lxc-4.0.5.tar.gz.asc 833 BLAKE2B 8cc3f00e3a3359b525f7ead48f4cce7b386a75c04b43eefe0ec939786e368712c2674a17fe9e9ef58649147c7f2d5682f5a0c280ddc8ca8c34664069d5efd4b5 SHA512 9e67932fa424224d39ec6c5c32a6e6c3cdf305d3e4d7c8ddbb8ab86a38392c30b56a20b11e4f85e3645a97c106a13ef868a5d3c78ac57bc8cb44cee20e83a700
diff --git a/app-emulation/lxc/lxc-4.0.5.ebuild b/app-emulation/lxc/lxc-4.0.5.ebuild
new file mode 100644
index 00000000000..a8205ac9eb4
--- /dev/null
+++ b/app-emulation/lxc/lxc-4.0.5.ebuild
@@ -0,0 +1,173 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools bash-completion-r1 linux-info flag-o-matic optfeature pam readme.gentoo-r1 systemd verify-sig
+
+DESCRIPTION="LinuX Containers userspace utilities"
+HOMEPAGE="https://linuxcontainers.org/ https://github.com/lxc/lxc"
+SRC_URI="https://linuxcontainers.org/downloads/lxc/${P}.tar.gz
+ https://github.com/lxc/lxc/archive/${P}.tar.gz
+ verify-sig? ( https://linuxcontainers.org/downloads/lxc/${P}.tar.gz.asc )"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="apparmor +caps doc examples libressl man pam seccomp selinux +ssl +tools verify-sig"
+
+RDEPEND="app-misc/pax-utils
+ sys-apps/util-linux
+ sys-libs/libcap
+ virtual/awk
+ caps? ( sys-libs/libcap )
+ pam? ( sys-libs/pam )
+ seccomp? ( sys-libs/libseccomp )
+ selinux? ( sys-libs/libselinux )
+ ssl? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ )"
+DEPEND="${RDEPEND}
+ >=sys-kernel/linux-headers-4
+ apparmor? ( sys-apps/apparmor )"
+BDEPEND="doc? ( app-doc/doxygen )
+ man? ( app-text/docbook-sgml-utils )
+ verify-sig? ( app-crypt/openpgp-keys-linuxcontainers )"
+
+CONFIG_CHECK="~!NETPRIO_CGROUP
+ ~CGROUPS
+ ~CGROUP_CPUACCT
+ ~CGROUP_DEVICE
+ ~CGROUP_FREEZER
+
+ ~CGROUP_SCHED
+ ~CPUSETS
+ ~IPC_NS
+ ~MACVLAN
+
+ ~MEMCG
+ ~NAMESPACES
+ ~NET_NS
+ ~PID_NS
+
+ ~POSIX_MQUEUE
+ ~USER_NS
+ ~UTS_NS
+ ~VETH"
+
+ERROR_CGROUP_FREEZER="CONFIG_CGROUP_FREEZER: needed to freeze containers"
+ERROR_MACVLAN="CONFIG_MACVLAN: needed for internal (inter-container) networking"
+ERROR_MEMCG="CONFIG_MEMCG: needed for memory resource control in containers"
+ERROR_NET_NS="CONFIG_NET_NS: needed for unshared network"
+ERROR_POSIX_MQUEUE="CONFIG_POSIX_MQUEUE: needed for lxc-execute command"
+ERROR_UTS_NS="CONFIG_UTS_NS: needed to unshare hostnames and uname info"
+ERROR_VETH="CONFIG_VETH: needed for internal (host-to-container) networking"
+
+DOCS=( AUTHORS CONTRIBUTING MAINTAINERS NEWS README doc/FAQ.txt )
+
+pkg_setup() {
+ linux-info_pkg_setup
+}
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-3.0.0-bash-completion.patch
+ "${FILESDIR}"/${PN}-2.0.5-omit-sysconfig.patch # bug 558854
+)
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/linuxcontainers.asc
+
+src_prepare() {
+ default
+ eautoreconf
+}
+
+src_configure() {
+ append-flags -fno-strict-aliasing
+
+ local myeconfargs=(
+ --bindir=/usr/bin
+ --localstatedir=/var
+ --sbindir=/usr/bin
+
+ --with-config-path=/var/lib/lxc
+ --with-distro=gentoo
+ --with-init-script=systemd
+ --with-rootfs-path=/var/lib/lxc/rootfs
+ --with-runtime-path=/run
+ --with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+
+ --disable-asan
+ --disable-coverity-build
+ --disable-dlog
+ --disable-mutex-debugging
+ --disable-rpath
+ --disable-tests
+ --disable-ubsan
+ --disable-werror
+
+ --enable-bash
+ --enable-commands
+ --enable-memfd-rexec
+ --enable-thread-safety
+
+ $(use_enable apparmor)
+ $(use_enable caps capabilities)
+ $(use_enable doc api-docs)
+ $(use_enable examples)
+ $(use_enable man doc)
+ $(use_enable pam)
+ $(use_enable seccomp)
+ $(use_enable selinux)
+ $(use_enable ssl openssl)
+ $(use_enable tools)
+
+ $(use_with pam pamdir $(getpam_mod_dir))
+ )
+
+ econf "${myeconfargs[@]}"
+}
+
+src_install() {
+ default
+
+ mv "${ED}"/usr/share/bash-completion/completions/${PN} "${ED}"/$(get_bashcompdir)/${PN}-start || die
+ bashcomp_alias ${PN}-start \
+ ${PN}-{attach,cgroup,copy,console,create,destroy,device,execute,freeze,info,monitor,snapshot,stop,unfreeze,wait}
+
+ keepdir /etc/lxc /var/lib/lxc/rootfs /var/log/lxc
+ rmdir "${D}"/var/cache/lxc "${D}"/var/cache || die "rmdir failed"
+
+ find "${D}" -name '*.la' -delete -o -name '*.a' -delete || die
+
+ # Gentoo-specific additions!
+ newinitd "${FILESDIR}/${PN}.initd.8" ${PN}
+
+ # Remember to compare our systemd unit file with the upstream one
+ # config/init/systemd/lxc.service.in
+ systemd_newunit "${FILESDIR}"/${PN}_at.service.4.0.0 "lxc@.service"
+
+ DOC_CONTENTS="
+ For openrc, there is an init script provided with the package.
+ You should only need to symlink /etc/init.d/lxc to
+ /etc/init.d/lxc.configname to start the container defined in
+ /etc/lxc/configname.conf.
+
+ Correspondingly, for systemd a service file lxc@.service is installed.
+ Enable and start lxc@configname in order to start the container defined
+ in /etc/lxc/configname.conf."
+ DISABLE_AUTOFORMATTING=true
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ readme.gentoo_print_elog
+
+ elog "Please run 'lxc-checkconfig' to see optional kernel features."
+ elog
+ elog "Optional uninstalled dependencies:"
+ optfeature "automatic template scripts" app-emulation/lxc-templates
+ optfeature "Debian-based distribution container image support" dev-util/debootstrap
+ optfeature "snapshot & restore functionality" sys-process/criu
+}
diff --git a/app-emulation/lxc/metadata.xml b/app-emulation/lxc/metadata.xml
index 20b6c295215..3cd200c1cd2 100644
--- a/app-emulation/lxc/metadata.xml
+++ b/app-emulation/lxc/metadata.xml
@@ -11,6 +11,7 @@
</maintainer>
<use>
<flag name="apparmor">Enable AppArmor support</flag>
+ <flag name="man">Build manpages</flag>
<flag name="templates">Install old style templates through <pkg>app-emulation/lxc-templates</pkg></flag>
<flag name="tools">Build and install additional command line tools</flag>
</use>