[gentoo-commits] repo/gentoo:master commit in: games-roguelike/stone-soup/

["Erik Mackdanz" <stasibear@gentoo.org>]

commit:     ef2975f27a2959a3c0ca9da683693a2f95b68c16
Author:     Erik Mackdanz <stasibear <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 10 14:56:22 2020 +0000
Commit:     Erik Mackdanz <stasibear <AT> gentoo <DOT> org>
CommitDate: Sat Oct 10 14:56:22 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ef2975f2

games-roguelike/stone-soup: Bump to 0.25.1

Signed-off-by: Erik Mackdanz <stasibear <AT> gentoo.org>
Package-Manager: Portage-3.0.8, Repoman-3.0.1

 games-roguelike/stone-soup/Manifest                |   1 +
 .../stone-soup/stone-soup-0.25.1.ebuild            | 153 +++++++++++++++++++++
 2 files changed, 154 insertions(+)

diff --git a/games-roguelike/stone-soup/Manifest b/games-roguelike/stone-soup/Manifest
index 26b98ec5817..d0060514d4c 100644
--- a/games-roguelike/stone-soup/Manifest
+++ b/games-roguelike/stone-soup/Manifest
@@ -3,3 +3,4 @@ DIST stone-soup.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3f
 DIST stone_soup-0.23.2.tar.xz 30157732 BLAKE2B 5d264fa33abeb2254efbdef461774c987f65ef28160d43d90848b77d46a8f0e63c4e59a9cb7257257551a08c509e53758d72acbb0edf5a0e8b70e5d3ca09ea14 SHA512 61ccb0ac262a798e7c06fdb5e821c9885a690e082c33f6255358561929d6800b272106632279d27320e8ae240d903e2002f59d908d5db4841065a5cfa97bbee8
 DIST stone_soup-0.24.0.tar.xz 29746940 BLAKE2B 429fd9bb5a5bcd36d11f66ac93a96c4d378a50bb9197edcd92d9bd7d7c463ace60c5c59c4bb762fb61555e6612ecca2267b6d68b6bba8afa79861d7b8d4ea6a1 SHA512 d43d3c43551394c0730427a1adf561bc29ac679c13475292908f942aa8b6e077861245536ff3c932c7478f1ec1c72cf51c9aca8b8ce30f3a99c311c292765194
 DIST stone_soup-0.25.0.tar.xz 30247768 BLAKE2B 1e6595ae895beb8a4eede97002d5085e710de93726034a3ab9bd4d44fc9d03fc6cc22ff8878c2e6f825ffd0b28e73bbd1d9a087fc5eae9ffd2bc36403edf5b27 SHA512 387bce2c0491bf88c267af8e37afb1037dfc98d4ba4fb4dd3fe442f3446b6bf6f23c10f32483fb7d27e90c6045033bd70fb9e88e0bbe486489bc38ab71e62529
+DIST stone_soup-0.25.1.zip 95477710 BLAKE2B 0b38a6c7cb7c4c87acccb861b5aae665cd2b6b532f6e86d4a9fa594e0d363b86b4af1ea47275f7fd026ea69d85215be8cdf46258bd620e738b4850e5eceed006 SHA512 fa7e8be582c5c6615531884ade4c113542c06c164b6912095c1adf2f16a31cb2ecce057d74132b11b1b1c256a77433037948d4e54819739b7e222cc896cd5220

diff --git a/games-roguelike/stone-soup/stone-soup-0.25.1.ebuild b/games-roguelike/stone-soup/stone-soup-0.25.1.ebuild
new file mode 100644
index 00000000000..58ccb08b806
--- /dev/null
+++ b/games-roguelike/stone-soup/stone-soup-0.25.1.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# TODO
+# - attempt +test, linked bug claims to be fixed
+
+EAPI=7
+VIRTUALX_REQUIRED="manual"
+inherit desktop eutils xdg-utils toolchain-funcs
+
+MY_P="stone_soup-${PV}"
+DESCRIPTION="Role-playing roguelike game of exploration and treasure-hunting in dungeons"
+HOMEPAGE="http://crawl.develz.org/wordpress/"
+SRC_URI="
+	https://github.com/crawl/crawl/releases/download/${PV}/${PN/-/_}-${PV}.zip
+	https://dev.gentoo.org/~hasufell/distfiles/${PN}.png
+	https://dev.gentoo.org/~hasufell/distfiles/${PN}.svg
+"
+
+# 3-clause BSD: mt19937ar.cc, MSVC/stdint.h
+# 2-clause BSD: all contributions by Steve Noonan and Jesse Luehrs
+# Public Domain|CC0: most of tiles
+# MIT: json.cc/json.h, some .js files in webserver/static/scripts/contrib/
+LICENSE="GPL-2 BSD BSD-2 public-domain CC0-1.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug ncurses sound test +tiles"
+# test is broken
+# see https://crawl.develz.org/mantis/view.php?id=6121
+RESTRICT="test"
+
+RDEPEND="
+	dev-db/sqlite:3
+	=dev-lang/lua-5.1*:0=
+	sys-libs/zlib
+	!ncurses? ( !tiles? ( sys-libs/ncurses:0 ) )
+	ncurses? ( sys-libs/ncurses:0 )
+	tiles? (
+		media-fonts/dejavu
+		media-libs/freetype:2
+		media-libs/libpng:0
+		sound? (
+			   media-libs/libsdl2[X,opengl,sound,video]
+			   media-libs/sdl2-mixer
+		)
+		!sound? ( media-libs/libsdl2[X,opengl,video] )
+		media-libs/sdl2-image[png]
+		virtual/glu
+		virtual/opengl
+	)"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-python/pyyaml
+	sys-devel/flex
+	tiles? (
+		sys-libs/ncurses:0
+	)
+	virtual/pkgconfig
+	virtual/yacc
+	"
+
+S=${WORKDIR}/${MY_P}/source
+S_TEST=${WORKDIR}/${MY_P}_test/source
+PATCHES=(
+	"${FILESDIR}"/gitless-1.patch
+	"${FILESDIR}"/rltiles-ldflags-libs.patch
+)
+
+pkg_setup() {
+
+	if use !ncurses && use !tiles ; then
+		ewarn "Neither ncurses nor tiles frontend"
+		ewarn "selected, choosing ncurses only."
+		ewarn "Note that you can also enable both."
+	fi
+
+	if use sound && use !tiles ; then
+		ewarn "Sound support is only available with tiles."
+	fi
+}
+
+src_compile() {
+
+	# Insurance that we're not using bundled lib sources
+	rm -rf contrib || die "Couldn't delete contrib directory"
+
+	export HOSTCXX=$(tc-getBUILD_CXX)
+
+	# leave DATADIR at the top
+	myemakeargs=(
+		$(usex debug "FULLDEBUG=y DEBUG=y" "")
+		BUILD_LUA=
+		AR="$(tc-getAR)"
+		CFOPTIMIZE=''
+		CFOTHERS="${CXXFLAGS}"
+		CONTRIBS=
+		DATADIR="/usr/share/${PN}"
+		GCC="$(tc-getCC)"
+		GXX="$(tc-getCXX)"
+		LDFLAGS="${LDFLAGS}"
+		MAKEOPTS="${MAKEOPTS}"
+		PKGCONFIG="$(tc-getPKG_CONFIG)"
+		RANLIB="$(tc-getRANLIB)"
+		SAVEDIR="~/.crawl"
+		SOUND=$(usex sound "y" "")
+		STRIP=touch
+		USE_LUAJIT=
+		V=1
+		prefix="/usr"
+	)
+
+	if use ncurses || (use !ncurses && use !tiles) ; then
+		emake "${myemakeargs[@]}"
+		# move it in case we build both variants
+		use tiles && { mv crawl "${WORKDIR}"/crawl-ncurses || die ;}
+	fi
+
+	if use tiles ; then
+		emake clean
+		emake "${myemakeargs[@]}" "TILES=y"
+	fi
+}
+
+src_install() {
+	emake "${myemakeargs[@]}" $(usex tiles "TILES=y" "") DESTDIR="${D}" prefix_fp="" bin_prefix="${D}/usr/bin" install
+	[[ -e "${WORKDIR}"/crawl-ncurses ]] && dobin "${WORKDIR}"/crawl-ncurses
+
+	# don't relocate docs, needed at runtime
+	rm -rf "${D}/usr/share/${PN}"/docs/license
+
+	doman "${WORKDIR}/${MY_P}"/docs/crawl.6
+
+	# icons and menu for graphical build
+	if use tiles ; then
+		doicon -s 48 "${DISTDIR}"/${PN}.png
+		doicon -s scalable "${DISTDIR}"/${PN}.svg
+		make_desktop_entry crawl
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if use tiles && use ncurses ; then
+		elog "Since you have enabled both tiles and ncurses frontends"
+		elog "the ncurses binary is called 'crawl-ncurses' and the"
+		elog "tiles binary is called 'crawl'."
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}