[gentoo-commits] repo/gentoo:master commit in: media-libs/lilv/

["Miroslav Šulc" <fordfrog@gentoo.org>]

commit:     b51bbea542fe18093e4b1747d163021d96508335
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Fri Oct  9 12:16:14 2020 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Fri Oct  9 12:16:34 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b51bbea5

media-libs/lilv: bump to 0.24.10

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-libs/lilv/Manifest            |  1 +
 media-libs/lilv/lilv-0.24.10.ebuild | 72 +++++++++++++++++++++++++++++++++++++
 2 files changed, 73 insertions(+)

diff --git a/media-libs/lilv/Manifest b/media-libs/lilv/Manifest
index e44f214ef04..632aed8455a 100644
--- a/media-libs/lilv/Manifest
+++ b/media-libs/lilv/Manifest
@@ -1 +1,2 @@
+DIST lilv-0.24.10.tar.bz2 443795 BLAKE2B a316c0aae8f93a6104ad46e9e93cd3948b4596920a9bb7f1ab5bfe596428aa43e45413f79cd9e7c094ca3239e4811bd391015f17be5c059a54b0a050aff1e964 SHA512 1dfd4fef19537686b63a4e7df45e3b1a7c4a658acc21d5646daba4d3bd5676513857b3f437b89f1a06232516433ef155772d19625c33d49d13ada37a965982cf
 DIST lilv-0.24.8.tar.bz2 545545 BLAKE2B 606beb68d6e277dfea85e3d2e27b58adf22f0a47a91583e4f1cd85649f237e75fac9b397eb07be69b5a278d02346d58bdf35c4c8fb248e4899a4fc9b05288c23 SHA512 f2b2638372a8280041f6e88e2077f2109f89dad6feedb9d07a88c6b5a05c37b62112f5d03282da4335ddd0d14339cfb49ad96a3df3de310265a40c24718be192

diff --git a/media-libs/lilv/lilv-0.24.10.ebuild b/media-libs/lilv/lilv-0.24.10.ebuild
new file mode 100644
index 00000000000..5e26bcb9168
--- /dev/null
+++ b/media-libs/lilv/lilv-0.24.10.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit python-any-r1 waf-utils bash-completion-r1 multilib-build multilib-minimal
+
+DESCRIPTION="Library to make the use of LV2 plugins as simple as possible for applications"
+HOMEPAGE="http://drobilla.net/software/lilv/"
+SRC_URI="http://download.drobilla.net/${P}.tar.bz2"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc +dyn-manifest static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/serd[${MULTILIB_USEDEP}]
+	dev-libs/sord[${MULTILIB_USEDEP}]
+	media-libs/libsndfile
+	media-libs/lv2[${MULTILIB_USEDEP}]
+	media-libs/sratom[${MULTILIB_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-python/unittest2 )
+"
+
+src_prepare() {
+	default
+	sed -i -e 's/^.*run_ldconfig/#\0/' wscript || die
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	waf-utils_src_configure \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--no-bash-completion \
+		$(multilib_native_usex doc --docs "") \
+		$(usex test --test "") \
+		$(usex static-libs --static "") \
+		$(usex dyn-manifest --dyn-manifest "")
+}
+
+multilib_src_compile() {
+	./waf build || die
+}
+
+multilib_src_test() {
+	./waf test || die
+}
+
+multilib_src_install() {
+	waf-utils_src_install
+}
+
+multilib_src_install_all() {
+	sed -i "/lv2jack/d" utils/lilv.bash_completion
+	newbashcomp utils/lilv.bash_completion lv2info
+
+	dodir /etc/env.d
+	echo "LV2_PATH=${EPREFIX}/usr/$(get_libdir)/lv2" > "${ED}/etc/env.d/60lv2"
+
+	python_optimize
+}