[gentoo-commits] repo/gentoo:master commit in: dev-python/pywavelets/

["Dennis Lamm" <expeditioneer@gentoo.org>]

commit:     ab07f991e7b5c8924aac52852a0ce73638a6023b
Author:     Dennis Lamm <expeditioneer <AT> gentoo <DOT> org>
AuthorDate: Tue Jul 21 13:24:25 2020 +0000
Commit:     Dennis Lamm <expeditioneer <AT> gentoo <DOT> org>
CommitDate: Sun Sep 27 07:31:27 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ab07f991

dev-python/pywavelets: version bump to 1.1.1

Signed-off-by: Dennis Lamm <expeditioneer <AT> gentoo.org>

 dev-python/pywavelets/Manifest                |  1 +
 dev-python/pywavelets/pywavelets-1.1.1.ebuild | 52 +++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)

diff --git a/dev-python/pywavelets/Manifest b/dev-python/pywavelets/Manifest
index ffb45fc0730..7cfc84dd3d5 100644
--- a/dev-python/pywavelets/Manifest
+++ b/dev-python/pywavelets/Manifest
@@ -1 +1,2 @@
 DIST PyWavelets-0.5.2.tar.gz 4430706 BLAKE2B 0a96dde04c0d6b58304b2a6a1331036c33bf89be717127df97ea178d638d193b9ce8994d90e34b969a4a6228e7985c943529fb386a3bc938ce61a78925549bf2 SHA512 6685b348009076b39a46e5a480189c34e5bc791ac110f47a52a8dbe0cbed1f3dcb64402174480d525bcf3776d12185ac89fe36c839727a14ffbad1ed835824ad
+DIST PyWavelets-1.1.1.tar.gz 4578294 BLAKE2B 1d3c9118739f831a3a198ab4461daa337b7952e16693d8ab15498ac26897a813d0adc02ae339a6a3ebfd3810db13ed297714c36ba67af559835af58c2ab243e1 SHA512 3e70625dad27822165e79b7d240c34072684ba340e8d314a026d2e47e81b04945d9ed9c6a5f0730eab285d3d5ebb1b311aaec5d6d06bced1eea80000bef5e787

diff --git a/dev-python/pywavelets/pywavelets-1.1.1.ebuild b/dev-python/pywavelets/pywavelets-1.1.1.ebuild
new file mode 100644
index 00000000000..13958d97cf3
--- /dev/null
+++ b/dev-python/pywavelets/pywavelets-1.1.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..8} )
+
+inherit distutils-r1
+
+MY_PN="${PN/pyw/PyW}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Discrete Wavelet Transforms in Python"
+HOMEPAGE="https://pywavelets.readthedocs.io/en/latest/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples"
+
+RDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}] )
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+S="${WORKDIR}/${MY_P}"
+
+python_test() {
+	pytest -vv --pyargs ${BUILD_DIR}"/lib" || die "Tests fail with ${EPYTHON}"
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/build/html/. )
+	distutils-r1_python_install_all
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r demo/*
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}