[gentoo-commits] repo/gentoo:master commit in: dev-python/graph-tool/

["David Seifert" <soap@gentoo.org>]

commit:     5d2387c8ea09ebf006221dfe62691df14d7deb0f
Author:     David Seifert <soap <AT> gentoo <DOT> org>
AuthorDate: Mon Sep 21 23:16:01 2020 +0000
Commit:     David Seifert <soap <AT> gentoo <DOT> org>
CommitDate: Mon Sep 21 23:16:01 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5d2387c8

dev-python/graph-tool: Version bump to 2.35

Closes: https://bugs.gentoo.org/741990
Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: David Seifert <soap <AT> gentoo.org>

 dev-python/graph-tool/Manifest               |  1 +
 dev-python/graph-tool/graph-tool-2.35.ebuild | 84 ++++++++++++++++++++++++++++
 2 files changed, 85 insertions(+)

diff --git a/dev-python/graph-tool/Manifest b/dev-python/graph-tool/Manifest
index 0b8f164706a..8e035770c3f 100644
--- a/dev-python/graph-tool/Manifest
+++ b/dev-python/graph-tool/Manifest
@@ -1 +1,2 @@
 DIST graph-tool-2.29.tar.bz2 15068583 BLAKE2B 28eb191d0f9c049eb5e5cd70ff30508bc6347566e757f11dc21cc7775c40ee1a86490516f6616e0dc7086983e510785c695db4ace64aa2c83b67c3ca1f534ad6 SHA512 f7a40f0ff5cb5ce3fdf39cf38744a91f7936e8d1dc487f0428c9f29893ad9d5163d5b76d7c07e3651ecb7035bea4166ca8e169934be54247f3285f4e0fe7269a
+DIST graph-tool-2.35.tar.bz2 15153787 BLAKE2B 31f815f564510bb9628f43e8afab1a561222d23aabc3417ce474f0db69625954fc46119f61e8d7764d49a291e16e3b32f2e4249304f934c08d17af3e47a39ce8 SHA512 eadb122b75ff95fde165bfe1be8387deb08b48d041236aff11a0b8414d1a5027931a5e4b3216348edb61c53187b191a5e78af4eabb1ce679dd8736651f142bec

diff --git a/dev-python/graph-tool/graph-tool-2.35.ebuild b/dev-python/graph-tool/graph-tool-2.35.ebuild
new file mode 100644
index 00000000000..20fbfe4e557
--- /dev/null
+++ b/dev-python/graph-tool/graph-tool-2.35.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit check-reqs python-r1 toolchain-funcs
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://git.skewed.de/count0/graph-tool.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://downloads.skewed.de/${PN}/${P}.tar.bz2"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="An efficient python module for manipulation and statistical analysis of graphs"
+HOMEPAGE="https://graph-tool.skewed.de/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+cairo openmp"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/boost-1.70:=[context,python,${PYTHON_USEDEP}]
+	dev-libs/expat:=
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	sci-mathematics/cgal:=
+	cairo? (
+		dev-cpp/cairomm
+		dev-python/pycairo[${PYTHON_USEDEP}]
+	)
+	dev-python/matplotlib[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-cpp/sparsehash"
+BDEPEND="virtual/pkgconfig"
+
+# bug 453544
+CHECKREQS_DISK_BUILD="6G"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	check-reqs_pkg_pretend
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	configure() {
+		econf \
+			--disable-static \
+			$(use_enable openmp) \
+			$(use_enable cairo) \
+			--with-boost-python="boost_${EPYTHON/./}"
+	}
+	python_foreach_impl run_in_build_dir configure
+}
+
+src_compile() {
+	# most machines don't have enough ram for parallel builds
+	python_foreach_impl run_in_build_dir emake -j1
+}
+
+src_install() {
+	python_install() {
+		default
+		python_optimize
+	}
+	python_foreach_impl run_in_build_dir python_install
+
+	find "${ED}" -name '*.la' -delete || die
+}