[gentoo-commits] repo/gentoo:master commit in: dev-perl/PerlIO-Layers/

["Kent Fredric" <kentnl@gentoo.org>]

commit:     a4bedefae73b77c6a9fce9a4295687f91492ae0b
Author:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
AuthorDate: Sat Aug 29 01:11:07 2020 +0000
Commit:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
CommitDate: Sat Aug 29 01:11:07 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a4bedefa

dev-perl/PerlIO-Layers: -r bump for EAPI7 + toolchain love

- EAPI7
- Remove unwanted tests
- Ensure not to break when LD is not a CCLD
- Ensure passing cflags to compiler

Package-Manager: Portage-3.0.4, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl <AT> gentoo.org>

 .../PerlIO-Layers/PerlIO-Layers-0.11.0-r1.ebuild   | 45 ++++++++++++++++++++++
 1 file changed, 45 insertions(+)

diff --git a/dev-perl/PerlIO-Layers/PerlIO-Layers-0.11.0-r1.ebuild b/dev-perl/PerlIO-Layers/PerlIO-Layers-0.11.0-r1.ebuild
new file mode 100644
index 00000000000..43c24007553
--- /dev/null
+++ b/dev-perl/PerlIO-Layers/PerlIO-Layers-0.11.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=LEONT
+DIST_VERSION=0.011
+
+inherit perl-module
+
+DESCRIPTION="Querying your filehandle's capabilities"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# needs List::Util
+RDEPEND="
+	virtual/perl-Carp
+	>=virtual/perl-Exporter-5.570.0
+	virtual/perl-Scalar-List-Utils
+	virtual/perl-XSLoader
+"
+DEPEND="dev-perl/Module-Build"
+BDEPEND="${RDEPEND}
+	>=dev-perl/Module-Build-0.360.100
+	test? (
+		virtual/perl-Data-Dumper
+		virtual/perl-File-Spec
+		>=virtual/perl-Test-Simple-0.820.0
+	)
+"
+PERL_RM_FILES=(
+	t/release-pod-coverage.t
+	t/release-pod-syntax.t
+)
+src_configure() {
+	unset LD
+	[[ -n "${CCLD}" ]] && export LD="${CCLD}"
+	perl-module_src_configure
+}
+src_compile() {
+	./Build --config optimize="${CFLAGS}" build || die
+}