[gentoo-commits] repo/gentoo:master commit in: net-im/libcommuni/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     077fe47e15b0d336b43c89f8ec4e46357862b15c
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 11 18:26:37 2020 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Tue Aug 11 18:30:42 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=077fe47e

net-im/libcommuni: drop old version

Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 net-im/libcommuni/Manifest                         |  1 -
 .../libcommuni-3.5.0_p20190110-r1.ebuild           | 88 ----------------------
 2 files changed, 89 deletions(-)

diff --git a/net-im/libcommuni/Manifest b/net-im/libcommuni/Manifest
index 35e9aa558c2..48032e6f51c 100644
--- a/net-im/libcommuni/Manifest
+++ b/net-im/libcommuni/Manifest
@@ -1,2 +1 @@
-DIST libcommuni-3.5.0_p20190110.tar.gz 471278 BLAKE2B 2836a5ae01b08aac624c899a40712a9c452fc5b8f242906063936e48bd59306758cc70ea07beaf8488d228d6029c8128e343bbd59b1bfeff9bb2dccda0153b59 SHA512 9da065ef6b0589f7406d8c66b46f9f8d3d16325b59b7281153233b1a8d2bf98cdd35ee4e416237ac760dfc07531578aa7432226932976b9bbf36209bed5db72c
 DIST libcommuni-3.5.0_p20200711.tar.gz 471839 BLAKE2B 37a02c473496a0fe9394a8b019678afa96b07b9272556fd538d42d9ec296b34ad4c76b3110ff96732bccbed59f2faeedf80bd7782e7a6e395252c6430cb88fa7 SHA512 578e2f70bdfa0e62eb3acac4e8deb2f6f0c1cd5f0a5e559dae79d2a808b27d3cf63ede146a65026e156d988097a5b7903793acadcd7e9ac567f65c59e6738ed3

diff --git a/net-im/libcommuni/libcommuni-3.5.0_p20190110-r1.ebuild b/net-im/libcommuni/libcommuni-3.5.0_p20190110-r1.ebuild
deleted file mode 100644
index 0e061171fd0..00000000000
--- a/net-im/libcommuni/libcommuni-3.5.0_p20190110-r1.ebuild
+++ /dev/null
@@ -1,88 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-EGIT_COMMIT="88bb0fcdaab5bdd1176a3b6b485a6415a137ec27"
-
-inherit qmake-utils
-
-DESCRIPTION="A cross-platform IRC framework written with Qt"
-HOMEPAGE="https://communi.github.io/"
-SRC_URI="https://github.com/communi/${PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="examples qml test +uchardet"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-qt/qtcore:5
-	dev-qt/qtdeclarative:5
-	examples? ( || (
-		dev-qt/qtgui:5[X(-)]
-		dev-qt/qtgui:5[xcb(-)]
-	) )
-	uchardet? ( app-i18n/uchardet )
-	!uchardet? ( dev-libs/icu:= )
-"
-
-DEPEND="
-	${RDEPEND}
-	test? ( dev-qt/qttest:5 )
-"
-
-S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
-
-src_prepare() {
-	default
-
-	# Currently the test tst_IrcLagTimer fails, so disabling
-	# See: https://github.com/communi/libcommuni/issues/63
-	sed -e '/irclagtimer/d' -i tests/auto/auto.pro || die
-}
-
-src_configure() {
-	local myqmakeargs=( libcommuni.pro
-		# Disables compile run-time benchmarks, as they don't make any sense
-		-config no_benchmarks
-		# Is needed for fixing the QA Notice: The following files contain insecure RUNPATHs
-		-config no_rpath
-		# Compile libcommuni always in Release mode, as Debug seems to do nothing
-		-config release
-		# Don't silence all compile messages
-		-config verbose
-		-config $(usex examples '' 'no_')examples
-		-config $(usex qml '' 'no_')install_imports
-		-config $(usex qml '' 'no_')install_qml
-		-config $(usex test '' 'no_')tests
-		-config $(usex uchardet 'no_' '')icu
-		-config $(usex uchardet '' 'no_')uchardet )
-
-	eqmake5 "${myqmakeargs[@]}"
-}
-
-src_test() {
-	# This is a hack to delete the existing LD_LIBRARY_PATH and set a new one,
-	# otherwise a test will fail, because it uses the system installed lib instead of the new compiled lib.
-	# The test will fail, when libcommuni is emerged with USE="uchardet" and
-	# libcommuni is already installed with USE="-uchardat", or the other way around.
-	find "${S}" -type f -name 'target_wrapper.sh' -exec sed -i -e "/.*LD_LIBRARY_PATH.*/d" {} \; || die
-	local -x LD_LIBRARY_PATH="${S}/lib"
-
-	default
-}
-
-src_install() {
-	emake install INSTALL_ROOT="${D}"
-
-	if use examples; then
-		local examples=( "bot" "client" "minimal" "qmlbot" "quick" )
-		for example in ${examples[@]}; do
-			newbin examples/"${example}"/"${example}" libcommuni."${example}"
-		done
-	fi
-
-	einstalldocs
-}