[gentoo-commits] repo/gentoo:master commit in: media-gfx/eog-plugins/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     80df8d52ceaa92892bf67301b7944c2e538409c0
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  2 21:19:57 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Aug  2 21:27:29 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=80df8d52

media-gfx/eog-plugins: bump to 3.26.5

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 media-gfx/eog-plugins/Manifest                  |  1 +
 media-gfx/eog-plugins/eog-plugins-3.26.5.ebuild | 66 +++++++++++++++++++++++++
 2 files changed, 67 insertions(+)

diff --git a/media-gfx/eog-plugins/Manifest b/media-gfx/eog-plugins/Manifest
index c4607457e73..3dbdf56a4bc 100644
--- a/media-gfx/eog-plugins/Manifest
+++ b/media-gfx/eog-plugins/Manifest
@@ -1 +1,2 @@
 DIST eog-plugins-3.26.4.tar.xz 477772 BLAKE2B 104ddf58d33e5513349839312fef820af20d7a3e64a3a8cbd7d964d8250564d6cd62c58cf95fb5359ab95eac8fe2b83ed051e6f3dc8144a8884ec72c74a12622 SHA512 95f2cf2c6ed84b4801517a708f18e1cd673f814d849029a41491f3719512d6a3a2cb5cb11898a7f972f8b674c682245c99964ba2da19b285ed175b720d5396e8
+DIST eog-plugins-3.26.5.tar.xz 478188 BLAKE2B 655eb9860435775862ba44bd26530edff778a3c8c574e9bf592800b4d57b4e5b0e52d36b7d71d6a6d615d47c320542105dcee9de89250901fcbfa6c255dcfddc SHA512 3b7979d241c2c0b522ffb6c30a6b8c90fed9e899cda8a73fb9d9a9392f474516f8c24fc75f3f35f920c8a6cf04b8bda611a8669839588936c48467813a6227a7

diff --git a/media-gfx/eog-plugins/eog-plugins-3.26.5.ebuild b/media-gfx/eog-plugins/eog-plugins-3.26.5.ebuild
new file mode 100644
index 00000000000..897a10d8bda
--- /dev/null
+++ b/media-gfx/eog-plugins/eog-plugins-3.26.5.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Eye of GNOME plugins"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome/Plugins"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+exif map picasa +python"
+REQUIRED_USE="
+	map? ( exif )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/libpeas-0.7.4:=
+	>=media-gfx/eog-3.15.90
+	>=x11-libs/gtk+-3.14:3
+	exif? ( >=media-libs/libexif-0.6.16 )
+	map? (
+		media-libs/libchamplain:0.12[gtk]
+		>=media-libs/clutter-1.9.4:1.0
+		>=media-libs/clutter-gtk-1.1.2:1.0 )
+	picasa? ( >=dev-libs/libgdata-0.9.1:= )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-libs/glib-2.32:2[dbus]
+		dev-libs/libpeas:=[gtk,python,${PYTHON_SINGLE_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+		')
+		gnome-base/gsettings-desktop-schemas
+		media-gfx/eog[introspection]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection] )
+"
+# libxml2 required for glib-compile-resources
+DEPEND="${RDEPEND}
+	dev-libs/libxml2:2
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local plugins="fit-to-width,send-by-mail,hide-titlebar,light-theme"
+	use exif && plugins="${plugins},exif-display"
+	use map && plugins="${plugins},map"
+	use picasa && plugins="${plugins},postasa"
+	use python && plugins="${plugins},slideshowshuffle,pythonconsole,fullscreenbg,export-to-folder,maximize-windows"
+	gnome2_src_configure \
+		$(use_enable python) \
+		--with-plugins=${plugins}
+}