[gentoo-commits] repo/gentoo:master commit in: media-libs/freealut/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     6ef6aae12087451860ee999370539b889c876696
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 22 18:24:51 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jul 22 21:18:53 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6ef6aae1

media-libs/freealut: EAPI-7 bump, drop unused eclasses, static-libs--

Use https.
Add missing || die.

Package-Manager: Portage-3.0.0, Repoman-2.3.23
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-libs/freealut/freealut-1.1.0-r4.ebuild | 39 ++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

diff --git a/media-libs/freealut/freealut-1.1.0-r4.ebuild b/media-libs/freealut/freealut-1.1.0-r4.ebuild
new file mode 100644
index 00000000000..fff1f528d5e
--- /dev/null
+++ b/media-libs/freealut/freealut-1.1.0-r4.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="The OpenAL Utility Toolkit"
+HOMEPAGE="https://www.openal.org/"
+SRC_URI="http://connect.creativelabs.com/openal/Downloads/ALUT/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="
+	>=media-libs/openal-1.15.1[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# Link against openal and pthread
+	sed -e 's/libalut_la_LIBADD = .*/& -lopenal -lpthread/' \
+		-i src/Makefile.am || die
+	AT_M4DIR="admin/autotools/m4" eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf --disable-static
+}
+
+multilib_src_install_all() {
+	local HTML_DOCS=( doc/. )
+	einstalldocs
+	find "${D}" -name '*.la' -type f -delete || die
+}