From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1187637-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id EAA43138359
for <garchives@archives.gentoo.org>; Wed, 15 Jul 2020 17:38:23 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 21FA1E0826;
Wed, 15 Jul 2020 17:38:23 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id E5FB4E0826
for <gentoo-commits@lists.gentoo.org>; Wed, 15 Jul 2020 17:38:22 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id A55F234F141
for <gentoo-commits@lists.gentoo.org>; Wed, 15 Jul 2020 17:38:21 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 5F333291
for <gentoo-commits@lists.gentoo.org>; Wed, 15 Jul 2020 17:38:20 +0000 (UTC)
From: "Georgy Yakovlev" <gyakovlev@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Georgy Yakovlev" <gyakovlev@gentoo.org>
Message-ID: <1594834644.c162820ded53e5b991df234b58526ebb6d56a0a8.gyakovlev@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-java/openjdk-jre-bin/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-java/openjdk-jre-bin/Manifest dev-java/openjdk-jre-bin/openjdk-jre-bin-11.0.8_p10-r1.ebuild
X-VCS-Directories: dev-java/openjdk-jre-bin/
X-VCS-Committer: gyakovlev
X-VCS-Committer-Name: Georgy Yakovlev
X-VCS-Revision: c162820ded53e5b991df234b58526ebb6d56a0a8
X-VCS-Branch: master
Date: Wed, 15 Jul 2020 17:38:20 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 468d908a-a057-4720-857f-7021e14476e3
X-Archives-Hash: 7455b803da9f1b62e4bb6982e78b2889
commit: c162820ded53e5b991df234b58526ebb6d56a0a8
Author: Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 15 17:37:24 2020 +0000
Commit: Georgy Yakovlev <gyakovlev <AT> gentoo <DOT> org>
CommitDate: Wed Jul 15 17:37:24 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c162820d
dev-java/openjdk-jre-bin: bump to 11.0.8_p10
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Georgy Yakovlev <gyakovlev <AT> gentoo.org>
dev-java/openjdk-jre-bin/Manifest | 1 +
.../openjdk-jre-bin-11.0.8_p10-r1.ebuild | 100 +++++++++++++++++++++
2 files changed, 101 insertions(+)
diff --git a/dev-java/openjdk-jre-bin/Manifest b/dev-java/openjdk-jre-bin/Manifest
index 46d9e603e24..0a730ccd5ff 100644
--- a/dev-java/openjdk-jre-bin/Manifest
+++ b/dev-java/openjdk-jre-bin/Manifest
@@ -1,2 +1,3 @@
DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.7_10.tar.gz 42917723 BLAKE2B c5635b3727e10462396891cab89e257ded57c59f56e9bcb84a3d040ce8a27d7d67d6b78e5f55b63806dd93f6151b767df42e4428d12e763f9722196ca0736a08 SHA512 a776dd9168e3c2635a8492405d58628713e646292d7ee16454681d46866e7ea41afa712227e94ed2e8ce52c727e445f4631db63a02408aa817f1c79af8057dbe
+DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.8_10.tar.gz 42904191 BLAKE2B cfd04b2a422e95465cd2938449f7632d29fe655eadadf5745045db6eb74625dffa0e02d8713a93e0bc8fa7da6dc57116fbbd9217a9b30723becd5b9eaceefccd SHA512 55ab4c6122422f4765542df747bce5c65bc78e0e5f4fff4b7efc95342d81eb34d72dbdc13c820781c626f92a2c3687161d0c7edfbe4f83c455c75fcecf8ae3d0
DIST OpenJDK8U-jre_x64_linux_hotspot_8u252b09.tar.gz 41104123 BLAKE2B 52a9f288054c4a96ed5d70c2c9c6cf14ceb32262ec3a38f547286518ccc14a4695d330adc19e272436c0a7154771cddd9b0672b05beb6d5013c44c69be0ad25a SHA512 b1b0627e8495b11e0ef3e4ecb387d92537bb97b3f3045213658d48b6f2dffa0bc975b1bc92e84c487152b43d1f0ee0449730bf84dd62d98d13354bf73d3a0a20
diff --git a/dev-java/openjdk-jre-bin/openjdk-jre-bin-11.0.8_p10-r1.ebuild b/dev-java/openjdk-jre-bin/openjdk-jre-bin-11.0.8_p10-r1.ebuild
new file mode 100644
index 00000000000..23e7a0fbadc
--- /dev/null
+++ b/dev-java/openjdk-jre-bin/openjdk-jre-bin-11.0.8_p10-r1.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit java-vm-2
+
+abi_uri() {
+ echo "${2-$1}? (
+ https://github.com/AdoptOpenJDK/openjdk${SLOT}-binaries/releases/download/jdk-${MY_PV}/OpenJDK${SLOT}U-jre_${1}_linux_hotspot_${MY_PV//+/_}.tar.gz
+ )"
+}
+
+MY_PV=${PV/_p/+}
+SLOT=${MY_PV%%[.+]*}
+
+SRC_URI="
+ $(abi_uri x64 amd64)
+"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by AdoptOpenJDK"
+HOMEPAGE="https://adoptopenjdk.net"
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+IUSE="alsa cups +gentoo-vm headless-awt nsplugin selinux webstart"
+
+RDEPEND="
+ media-libs/fontconfig:1.0
+ media-libs/freetype:2
+ >net-libs/libnet-1.1
+ >=sys-apps/baselayout-java-0.1.0-r1
+ >=sys-libs/glibc-2.2.5:*
+ sys-libs/zlib
+ alsa? ( media-libs/alsa-lib )
+ cups? ( net-print/cups )
+ selinux? ( sec-policy/selinux-java )
+ !headless-awt? (
+ x11-libs/libX11
+ x11-libs/libXext
+ x11-libs/libXi
+ x11-libs/libXrender
+ x11-libs/libXtst
+ )"
+
+PDEPEND="webstart? ( >=dev-java/icedtea-web-1.6.1:0 )
+ nsplugin? ( >=dev-java/icedtea-web-1.6.1:0[nsplugin] )"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk-${MY_PV}-jre"
+
+src_install() {
+ local dest="/opt/${P}"
+ local ddest="${ED%/}/${dest#/}"
+
+ # Not sure why they bundle this as it's commonly available and they
+ # only do so on x86_64. It's needed by libfontmanager.so. IcedTea
+ # also has an explicit dependency while Oracle seemingly dlopens it.
+ rm -vf lib/libfreetype.so || die
+
+ # Oracle and IcedTea have libjsoundalsa.so depending on
+ # libasound.so.2 but AdoptOpenJDK only has libjsound.so. Weird.
+ if ! use alsa ; then
+ rm -v lib/libjsound.* || die
+ fi
+
+ if use headless-awt ; then
+ rm -v lib/lib*{[jx]awt,splashscreen}* || die
+ fi
+
+ rm -v lib/security/cacerts || die
+ dosym ../../../../etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+ dodir "${dest}"
+ cp -pPR * "${ddest}" || die
+
+ # provide stable symlink
+ dosym "${P}" "/opt/${PN}-${SLOT}"
+
+ use gentoo-vm && java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+ java-vm_set-pax-markings "${ddest}"
+ java-vm_revdep-mask
+ java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+ java-vm-2_pkg_postinst
+
+ if use gentoo-vm ; then
+ ewarn "WARNING! You have enabled the gentoo-vm USE flag, making this JRE"
+ ewarn "recognised by the system. This will almost certainly break things."
+ else
+ ewarn "The experimental gentoo-vm USE flag has not been enabled so this JRE"
+ ewarn "will not be recognised by the system. For example, simply calling"
+ ewarn "\"java\" will launch a different JVM. This is necessary until Gentoo"
+ ewarn "fully supports Java 11. This JRE must therefore be invoked using its"
+ ewarn "absolute location under ${EPREFIX}/opt/${P}."
+ fi
+}